zsh/aliases/pacman.zsh

   1 if (( ! $+commands[pacman] )); then
   2     return 1
   3 fi
   4
   5 # Pacman - https://wiki.archlinux.org/index.php/Pacman_Tips
   6 alias pacupg='sudo pacman -Syu'        # Synchronize with repositories before upgrading packages that are out of date on the local system.
   7 alias pacin='sudo pacman -S'           # Install specific package(s) from the repositories
   8 alias pacu='sudo pacman -U'            # Install specific package not from the repositories but from a file
   9 alias pacre='sudo pacman -R'           # Remove the specified package(s), retaining its configuration(s) and required dependencies
  10 alias pacrem='sudo pacman -Rns'        # Remove the specified package(s) and unneeded dependencies
  11 alias pacrm='sudo pacman -Rnsc'        # Remove the specified package(s), its configuration(s) and unneeded dependencies
  12 alias pacsi='pacman -Sii'              # Display information about a given package in the repositories
  13 alias pacss='pacman -Ss'               # Search for package(s) in the repositories
  14 alias pacqi='pacman -Qii'              # Display information about a given package in the local database
  15 alias pacqs='pacman -Qs'               # Search for package(s) in the local database
  16 alias pacl='pacman -Ql'                # List all files owned by package(s)
  17 alias paco='pacman -Qo'                # List package owning the given file(s)
  18 alias pacdep='sudo pacman -D --asdeps'      # Mark package as dependency
  19 alias pacexp='sudo pacman -D --asexplicit'  # Mark package as explicit
  20 alias pacinsd='sudo pacman -S --asdeps'        # Install given package(s) as dependencies of another package
  21 alias pacmir='sudo pacman -Syy'                # Force refresh of all package lists after updating /etc/pacman.d/mirrorlist
  22
  23 [[ -x /usr/bin/packer ]] && alias aur='packer'
  24
  25 # https://bbs.archlinux.org/viewtopic.php?id=93683
  26 paclist() {
  27   pacman -Qei "$@" | awk 'BEGIN {FS=": "}/^Name/{printf("\033[1;36m%s\033[0m ",$2)}/^Description/{print $2}'
  28 }
  29
  30 pacclean() {
  31     local _pkgs=( $(pacman -Qeq) )
  32     for pkg in ${_pkgs[@]}; do
  33         # the file has been removed by a previous clean
  34         pacman -Qq $pkg 2>&1 1>/dev/null || continue
  35
  36         pacman -Qi $pkg | awk 'BEGIN {FS=": "}/^Name/{printf("\n\033[1;36m%s\033[0m ",$2)}/^Description/{print $2}/^(Required|Optional For)/'
  37
  38         local edrq=''
  39         while true; do
  40             echo -n "Explicit, Dependency, Remove, Quit? [Edrq] "
  41             read -sk edrq
  42             echo
  43             case $edrq in
  44                 [Qq]) return ;;
  45                 $'\n') ;&
  46                 [Ee]) break ;;
  47                 [Rr]) sudo pacman -Rnscu $pkg; break ;;
  48                 [Dd]) sudo pacman -D --asdeps $pkg; break ;;
  49             esac
  50         done
  51     done
  52 }
  53 # [l]ist [o]orphans
  54 alias paclo='pacman -Qdt'
  55 # [r]emove [o]orphans
  56 alias pacro='sudo pacman -Rnscu $(pacman -Qtdq)'
  57
  58 # Display information about given packages (merges output of -Sii and -Qii)
  59 paci() {
  60     for p in $@; do
  61         if [[ -n "$(pacman -Qq "$p" 2>/dev/null)" ]]; then
  62             diff -u100 <(pacman -Qii "$p") <(pacman -Sii "$p" | sed '/^$/,$ d') | sed -e '1,3 d' -e 's/[-+ ]//'
  63         else
  64             pacman -Sii "$p"
  65         fi
  66     done
  67 }
  68 # will only work after another pacman completion has been called first
  69 compdef '_pacman_completions_all_packages' paci=pacman
  70
  71 pacstat() {
  72   printf "Packages:\n"
  73   printf "%7d native\n"  $(LC_ALL=C pacman -Qn | wc -l)
  74   printf "%7d foreign\n" $(LC_ALL=C pacman -Qm | wc -l)
  75   printf "%7d total\n"   $(LC_ALL=C pacman -Q  | wc -l)
  76   printf "Repos:\n"
  77   LC_ALL=C pacman -Sl | sed -n '/\[installed\]/s/^\([^ ]*\).*/\1/p' | uniq -c
  78 }
  79
  80 pacdisowned() {
  81   tmp=${TMPDIR-/tmp}/pacman-disowned-$UID-$$
  82   db=$tmp/db
  83   fs=$tmp/fs
  84
  85   mkdir "$tmp"
  86   trap  'rm -rf "$tmp"' EXIT
  87
  88   pacman -Qlq | sort -u > "$db"
  89
  90   local -a d
  91   if [[ -z $@ ]]; then
  92     d=(/etc /usr)
  93   else
  94     d=($@)
  95   fi
  96   find ${d[@]} \
  97       ! \( -name lost+found \
  98         -o -path '*/local/*' \
  99         -o -path "*/share/mime/*" \
 100         \) \
 101         \( -type d -printf '%p/\n' -o -print \) | sort > "$fs"
 102
 103   comm -23 "$fs" "$db"
 104 }