vim/vimrc

   1 " force python3
   2 if has('python3') | endif
   3
   4 " space is leader
   5 let g:mapleader = " "
   6
   7 " runtimepath {{{1
   8 set runtimepath ^=$XDG_CONFIG_HOME/vim
   9 set runtimepath +=$XDG_CONFIG_HOME/vim/after
  10
  11 " plugins {{{1
  12 call plug#begin('$XDG_DATA_HOME/vim')
  13 " This does not update vim-plug, use PlugUpgrade instead
  14 Plug 'junegunn/vim-plug'
  15
  16 if !has("nvim")
  17   Plug 'bling/vim-airline' " {{{2
  18     let g:airline#extensions#whitespace#enabled = 1
  19     let g:airline#extensions#tabline#enabled = 1
  20     let g:airline#extensions#searchcount#enabled = 0
  21     let g:airline_powerline_fonts = 1
  22
  23     let g:asyncrun_status = "stopped"
  24     " let g:airline_section_error = airline#section#create_right(['%{g:asyncrun_status}'])
  25   "}}}
  26   Plug 'raimondi/delimitmate' " {{{2
  27     let delimitMate_expand_cr = 2
  28     let g:delimitMate_expand_space = 1
  29   "}}}
  30   Plug 'tpope/vim-surround' "{{{2
  31   "}}}
  32   " Plug 'valloric/youcompleteme' {{{2
  33   Plug 'valloric/youcompleteme',
  34         \{ 'do': './install.py --clangd-completer --clang-completer' }
  35     let g:ycm_clangd_binary_path = 'clangd'   " use clangd in path
  36     let g:ycm_clangd_args = ['--clang-tidy']
  37     let g:ycm_extra_conf_vim_data = ['getcwd()']
  38     let g:ycm_add_preview_to_completeopt = 1
  39     let g:ycm_complete_in_comments = 1
  40     let g:ycm_complete_in_strings  = 1
  41     let g:ycm_autoclose_preview_window_after_insertion = 0
  42
  43     let g:ycm_language_server =
  44           \ [
  45           \   {
  46           \     'name': 'haskell',
  47           \     'cmdline': [ 'haskell-language-server-wrapper', '--lsp' ],
  48           \     'filetypes': [ 'haskell', 'lhaskell'  ]
  49           \   },
  50           \ ]
  51   " }}}
  52   Plug 'svermeulen/vim-yoink' " {{{2
  53   ""}}}
  54   Plug 'arcticicestudio/nord-vim' " {{{2
  55     let g:nord_bold = 1
  56     let g:nord_italic = 1
  57     let g:nord_italic_comments = 1
  58     let g:nord_underline = 1
  59     let g:nord_uniform_status_lines = 0
  60     let g:nord_uniform_diff_background = 0
  61     let g:nord_cursor_line_number_background = 0
  62     let g:nord_bold_vertical_split_line = 0
  63   "}}}
  64   Plug 'sirver/ultisnips' " replaced by lua-snip {{{2
  65   Plug 'honza/vim-snippets'
  66     let g:UltiSnipsEditSplit = 'vertical'
  67     let g:UltiSnipsSnippetDirectories = [ expand("$XDG_CONFIG_HOME/vim/ultisnips") ]
  68     if has('fname_case')
  69       let g:UltiSnipsSnippetDirectories = ["UltiSnips", "ultisnips"]
  70     endif
  71     let g:UltiSnipsExpandTrigger       = "<tab>"
  72     let g:UltiSnipsJumpForwardTrigger  = "<tab>"
  73     let g:UltiSnipsJumpBackwardTrigger = "<s-tab>"
  74
  75     " UltiSnips completion function that tries to expand a snippet. If there's no
  76     " snippet for expanding, it checks for completion window and if it's shown,
  77     " selects first element. If there's no completion window it tries to jump to
  78     " next placeholder. If there's no placeholder it just returns TAB key
  79     " https://github.com/Valloric/YouCompleteMe/issues/36#issuecomment-15451411
  80     function! g:UltiSnips_Complete()
  81         call UltiSnips#ExpandSnippet()
  82         if g:ulti_expand_res == 0
  83             if pumvisible()
  84                 return "\<C-n>"
  85             else
  86                 call UltiSnips#JumpForwards()
  87                 if g:ulti_jump_forwards_res == 0
  88                   return "\<TAB>"
  89                 endif
  90             endif
  91         endif
  92         return ""
  93     endfunction
  94     au InsertEnter * exec "inoremap <silent> " . g:UltiSnipsExpandTrigger . " <C-R>=g:UltiSnips_Complete()<cr>"
  95     let g:UltiSnipsListSnippets="<c-e>"
  96   "}}}
  97   Plug 'vim-utils/vim-man'  " replaced by builtin {{{2
  98     let g:man_width = 80
  99   "}}}
 100   Plug 'airblade/vim-gitgutter' " replaced by gitsigns {{{
 101   " prefer other signs such as ycm diags
 102   let g:gitgutter_sign_priority = 1
 103   " don't clobber other signs
 104   let g:gitgutter_sign_allow_clobber = 0
 105   "}}}
 106   Plug 'justinmk/vim-sneak' " replaced by leap {{{2
 107   let g:sneak#streak = 1
 108   let g:sneak#target_labels = "aoeuisnthdpylrcgfqjkxzmwvz" " dvorak
 109   let g:sneak#use_ic_scs = 1  " follow 'ignorecase' and 'smartcase'
 110
 111   " sneaky f and t
 112   nmap f <Plug>Sneak_f
 113   nmap F <Plug>Sneak_F
 114   xmap f <Plug>Sneak_f
 115   xmap F <Plug>Sneak_F
 116   omap f <Plug>Sneak_f
 117   omap F <Plug>Sneak_F
 118   nmap t <Plug>Sneak_t
 119   nmap T <Plug>Sneak_T
 120   xmap t <Plug>Sneak_t
 121   xmap T <Plug>Sneak_T
 122   omap t <Plug>Sneak_t
 123   omap T <Plug>Sneak_T
 124   "}}}
 125   Plug 'shougo/unite.vim' " replaced by telescope {{{2
 126     function! UniteSetup()
 127       call unite#filters#matcher_default#use(['matcher_fuzzy'])
 128       call unite#custom#profile('default', 'context', {
 129             \ 'winheight': 20,
 130             \ 'direction': 'botright'
 131             \ })
 132
 133       nnoremap [unite] <Nop>
 134       nmap <leader>u [unite]
 135       nnoremap [unite]u :UniteResume<CR>
 136       nnoremap <silent> [u :UnitePrevious<CR>
 137       nnoremap <silent> ]u :UniteNext<CR>
 138
 139       " unite-grep {{{3
 140       " seems not respected
 141       let g:unite_source_grep_max_candidates = 2000
 142       if executable('ag')
 143         " Use ag in unite grep source.
 144         let g:unite_source_grep_command = 'ag'
 145         let g:unite_source_grep_default_opts = '--smart-case --vimgrep --ignore ''.hg'' --ignore ''.svn'' --ignore ''.git'' --ignore ''.bzr'''
 146         let g:unite_source_grep_recursive_opt = ''
 147       end
 148       nnoremap <silent> [unite]a :<C-u>Unite grep:.::\12\17<CR>
 149       nnoremap <silent> [unite]A :<C-u>Unite grep:.:-w:\12\17<CR>
 150       command! -nargs=+ Ag Unite grep:.::<args>
 151
 152       " unite-file_rec {{{3
 153       if executable('ag')
 154         " Use ag in unite rec source
 155         let g:unite_source_rec_async_command = ['ag', '--follow', '--nocolor', '--nogroup', '-g', '']
 156       end
 157       nnoremap <silent> [unite]f :<C-u>Unite -start-insert file_rec/async<CR>
 158
 159       " unite-buffer {{{3
 160       call unite#custom#default_action('buffer', 'open')
 161       nnoremap <silent> [unite]b :<C-u>Unite buffer:-<CR>
 162
 163       " unite-jumplist {{{3
 164       nnoremap <silent> [unite]j :<C-u>Unite output:jumps:<CR>
 165
 166       " unite-menu {{{3
 167       let g:unite_source_menu_menus = {}
 168       let g:unite_source_menu_menus.fugitive = { 'description' : 'fugitive menu'}
 169       let g:unite_source_menu_menus.fugitive.command_candidates = {
 170             \ 'Gstatus <Leader>gs' : 'Gstatus',
 171             \ 'Gcommit -v <Leader>gc' : 'Gcommit -v',
 172             \ 'Glog' : 'Glog',
 173             \}
 174
 175       nnoremap <silent> <leader>gg :<C-u>Unite menu:fugitive<CR>
 176
 177       let g:unite_source_history_yank_enable = 1
 178       nnoremap <silent> [unite]p :<C-u>Unite history/yank<CR>
 179     endfunction
 180     augroup unit_setup
 181       autocmd VimEnter * ++once call UniteSetup()
 182     augroup END
 183   "}}}2
 184   Plug 'shougo/vimproc.vim', {'do': 'make'} " {{{2
 185   "}}}2
 186   Plug 'tomtom/tcomment_vim' " replaced by comment.nvim {{{2
 187     let g:tcomment_textobject_inlinecomment = 'gic'
 188     let g:tcomment#filetype#guess = 0
 189     "let g:tcomment#options = {'whitespace' : 'no'}
 190   "}}}2
 191   " colorschemes
 192   Plug 'morhetz/gruvbox' " {{{2
 193     let g:gruvbox_contrast_dark  = 'hard'
 194     let g:gruvbox_contrast_light = 'soft'
 195   " }}}2
 196   " staging
 197   Plug 'puremourning/vimspector' " replaced by lsp {{{2
 198     let g:vimspector_enable_mappings = 'HUMAN'
 199   " }}}
 200   Plug 'vim-scripts/syntaxrange' " replaced by treesitter {{{2
 201   " }}}
 202 endif
 203
 204 Plug 'alepez/vim-gtest'
 205 Plug 'alx741/vinfo'
 206 Plug 'andrewradev/sideways.vim' " {{{2
 207 nnoremap <silent> ,h :SidewaysLeft<CR>:delmarks z<CR>
 208 nnoremap <silent> ,l :SidewaysRight<CR>:delmarks z<CR>
 209 "}}}
 210 Plug 'andrewradev/switch.vim'
 211 Plug 'chrisbra/checkattach'
 212 Plug 'derekwyatt/vim-fswitch'
 213 Plug 'elzr/vim-json'
 214 Plug 'firef0x/pkgbuild.vim'
 215 Plug 'junegunn/vim-easy-align'
 216 Plug 'kshenoy/vim-signature'
 217 " Plug 'majutsushi/tagbar' " TODO: delete? {{{2
 218 "   map <F5> :TagbarToggle<cr>
 219 "   let g:tagbar_sort = 0
 220 "   let g:tagbar_compact = 1
 221 "   let g:tagbar_autoshowtag = 1
 222 "   let g:tagbar_width = 25
 223 "   let g:tagbar_iconchars = ['+', '-']
 224 "}}}
 225 Plug 'octol/vim-cpp-enhanced-highlight'
 226 Plug 'sgeb/vim-diff-fold'
 227 Plug 'skywind3000/asyncrun.vim' " {{{2
 228 command! -bang -nargs=* -complete=file Make AsyncRun -save=2 -program=make @ <args>
 229 let g:asyncrun_open = 10
 230 "}}}
 231 Plug 'sjl/gundo.vim'
 232 " Plug 'thinca/vim-qfreplace' " TODO: delete?
 233 Plug 'tpope/vim-abolish'
 234 Plug 'tpope/vim-characterize'
 235 " Plug 'tpope/vim-endwise' " TODO: delete?
 236 Plug 'tpope/vim-eunuch'
 237 Plug 'tpope/vim-fugitive'
 238 Plug 'tpope/vim-repeat'
 239 Plug 'tpope/vim-scriptease'
 240 Plug 'tpope/vim-speeddating'
 241 Plug 'tpope/vim-unimpaired'
 242 Plug 'tweekmonster/spellrotate.vim'
 243 " Plug 'vim-scripts/mediawiki.vim' " TODO: delete?
 244 Plug 'vim-scripts/replacewithregister' " FIXME: is overridden by lsp
 245 Plug 'wincent/loupe'
 246
 247 " text objects
 248 Plug 'kana/vim-textobj-user'
 249 Plug 'julian/vim-textobj-variable-segment'
 250 Plug 'sgur/vim-textobj-parameter'
 251 Plug 'kana/vim-operator-user'
 252
 253 " staging
 254 " Check LucHermites plugins: https://github.com/LucHermitte/lh-cpp
 255 Plug 'imsnif/kdl.vim'
 256
 257 Plug 'ilyachur/cmake4vim'
 258 Plug 'ilyachur/gtest-vim'
 259
 260 Plug 'junegunn/vim-peekaboo' "{{{2
 261   " issue with having it at the bottom is that it doesn't leave much
 262   let g:peekaboo_window = 'bo 16new'
 263   let g:peekaboo_compact = 1
 264   let g:peekaboo_delay = 500
 265 "}}}
 266
 267 " Plug 'vim-scripts/ansiesc.vim' " TODO: delete? {{{2
 268 "   nmap corwp <Plug>RestoreWinPosn
 269 "   nmap coswp <Plug>SaveWinPosn
 270 " "}}}
 271
 272 Plug 'neovimhaskell/haskell-vim'  " {{{2
 273 let g:haskell_enable_quantification = 1   " to enable highlighting of `forall`
 274 let g:haskell_enable_recursivedo = 1      " to enable highlighting of `mdo` and `rec`
 275 let g:haskell_enable_arrowsyntax = 1      " to enable highlighting of `proc`
 276 let g:haskell_enable_pattern_synonyms = 1 " to enable highlighting of `pattern`
 277 let g:haskell_enable_typeroles = 1        " to enable highlighting of type roles
 278 let g:haskell_enable_static_pointers = 1  " to enable highlighting of `static`
 279 let g:haskell_backpack = 1                " to enable highlighting of backpack keywords
 280
 281 let g:haskell_indent_before_where = 2
 282 " }}}
 283
 284 Plug 'aklt/plantuml-syntax'
 285
 286 Plug 'mtth/scratch.vim'  " {{{2
 287   let g:scratch_no_mappings = 1
 288   let g:scratch_autohide = 0
 289 "}}}
 290
 291 " Plug 'jenterkin/vim-autosource'  " TODO: delete? {{{2
 292 "   let g:autosource_hashdir = $XDG_CACHE_HOME . '/vim/vim-autosource'
 293 "   let g:autosource_conf_names = ['.vimrc', '.vimrc.lua']
 294 " "}}}
 295
 296 call plug#end()
 297
 298 filetype plugin indent on
 299 syntax on
 300
 301 " colorscheme {{{1
 302 set background=dark
 303 let &t_8f = "\<Esc>[38;2;%lu;%lu;%lum"
 304 let &t_8b = "\<Esc>[48;2;%lu;%lu;%lum"
 305 set termguicolors
 306 if !has('nvim')
 307   colorscheme $THEME
 308 endif
 309 "TODO see how I can integrate this into a theme that customises upstream Nord
 310 hi debugPC term=reverse ctermbg=8
 311
 312 " options {{{1
 313 " moving around, searching and patterns {{{2
 314 set incsearch           " show match for partly typed search command
 315 set ignorecase          " ignore case when using a search pattern
 316 set smartcase           " override 'ignorecase' when pattern has upper case characters
 317 set hlsearch            " highlight all matches for the last used search pattern
 318
 319 set nostartofline       " don't move the cursor to the first non-blank char of a line
 320 set path+=.
 321 set path+=include/
 322 set path+=../include/
 323 set path+=/usr/include/c++/*
 324
 325 " displaying text {{{2
 326 set nowrap                      " long lines wrap
 327 set linebreak                   " wrap long lines at a character in 'breakat'
 328 set showbreak=↪                 " show these chars for wrapped lines
 329 set breakindent                 " preserve indentation in wrapped text
 330
 331 set list                        " show chars defined in 'listchars'
 332 set listchars=tab:❭\            " list of strings used for list mode
 333 set listchars+=extends:❯,precedes:❮
 334 set listchars+=nbsp:␣
 335 " Only shown when not in insert mode
 336 set listchars+=trail:·
 337 augroup trailing
 338     au!
 339     au FileType qf setlocal listchars-=trail:·
 340     au InsertEnter * set listchars-=trail:·
 341     au InsertLeave * set listchars+=trail:·
 342 augroup END
 343
 344 set scrolloff=5                 " number of screen lines to show around the cursor
 345 set sidescroll=1                " number of collumns to scroll
 346 set sidescrolloff=1             " don't scroll over the listchars
 347 set display+=lastline           " display as much as possible of last line
 348
 349 set fillchars=diff:⣿,vert:│
 350
 351 set nonumber                    " show the line number for each line
 352 set norelativenumber            " show the relative line number for each line
 353
 354 " syntax, highlighting and spelling {{{2
 355 set synmaxcol=800               " don't highlight long lines
 356
 357 set dictionary=spell            " list of dictionary files for keyword completion
 358
 359 set colorcolumn=+1
 360
 361 " multiple windows {{{2
 362 set laststatus=2                " 0, 1 or 2; when to use a status line for the last window
 363
 364 set previewheight=20            " default height for the preview window
 365
 366 set hidden
 367
 368 " set splitbelow                  " a new window is put below of the current one
 369 set splitright                  " a new window is put right of the current one
 370
 371 " terminal {{{2
 372 set ttyfast
 373
 374 " using the mouse {{{2
 375 set mouse=rnv                   " list of flags for using the mouse
 376 if !has('nvim')
 377   set ttymouse=xterm              " type of mouse
 378 endif
 379
 380 " messages and info {{{2
 381 set showcmd         " Show (partial) command in status line.
 382 set ruler           " show the cursor position all the time
 383 set confirm         " Ask what to do when closing unsaved documents
 384 set shortmess+=a    " all abbreviations
 385 set shortmess+=o    " overwrite file-written message
 386 set shortmess+=O    " file-read message overrides previous
 387 set shortmess+=t    " truncate file message at start
 388 set shortmess+=T    " truncate other messages in the middle
 389 set shortmess+=W    " don't give 'written' or '[w]' when writing a file
 390 set shortmess+=A    " ignore swapfile warning
 391 set shortmess+=I    " no splash screen
 392 set shortmess+=F    " don't give the file info when editing a file
 393 set shortmess+=c    " don't give |ins-completion-menu| messages
 394
 395 " editing text {{{2
 396 set backspace=indent,eol,start  " allow backspacing over everything in insert mode
 397
 398 set showmatch                   " Show matching brackets.
 399
 400 set nojoinspaces                " don't use two spaces after '.' when joining a line
 401 set formatoptions+=j    " Delete comment leader when joining lines
 402 set formatoptions+=c    " Autowrap comments using textwidth
 403 set formatoptions+=r    " Insert comment leader after hitting <Enter>
 404 set formatoptions+=n    " Recognize numbered lists
 405 set formatoptions+=q    " Allow formatting of comments with "gq".
 406 set formatoptions+=l    " do not wrap lines that have been longer when starting insert mode already
 407 set formatoptions+=t    " Auto-wrap text using textwidth
 408 set formatoptions-=o    " Do not insert comment leader after hitting o or O in normal mode
 409
 410 set nrformats-=octal    " don't inc/dec octal numbers with ^[AX]
 411 set nrformats+=unsigned " treat all numbers as unsigned
 412
 413 set complete=.       " scan the current buffer ( 'wrapscan' is ignored)
 414 set complete+=w      " scan buffers from other windows
 415 set complete+=b      " scan other loaded buffers that are in the buffer list
 416 set complete+=u      " scan the unloaded buffers that are in the buffer list
 417 set complete+=t      " scan tags
 418 set complete+=i      " scan current and included files
 419 set complete+=kspell " use the currently active spell checking |spell|
 420
 421 " whether to use a popup menu for Insert mode completion
 422 set completeopt=longest,menuone,preview
 423
 424 " tabs and indent {{{2
 425 set shiftwidth=4                " number of spaces used for each step of (auto)indent
 426 set smarttab                    " a <Tab> in an indent inserts 'shiftwidth' spaces
 427 set softtabstop=4               " if non-zero, number of spaces to insert for a <Tab>
 428 set shiftround                  " round to 'shiftwidth' for "<<" and ">>"
 429 set expandtab                   " expand <Tab> to spaces in Insert mode
 430 set autoindent
 431
 432 set pastetoggle=<F11>           " key sequence to toggle paste mode
 433
 434 " folding {{{2
 435 set foldmethod=marker           " folding type
 436 set foldlevelstart=0            " value for 'foldlevel' when starting to edit a file
 437
 438 " open folds when jumping to line
 439 set foldopen+=jump
 440
 441 set viewoptions=cursor          " save cursor position
 442 set viewoptions+=folds          " save folds
 443
 444 " diff mode {{{2
 445 set diffopt+=filler         " show filler lines
 446 set diffopt+=vertical       " always vertical split
 447 set diffopt+=context:10     " 10 lines context between changes
 448 set diffopt+=internal
 449 set diffopt+=algorithm:patience
 450
 451 " reading and writing files {{{2
 452 set modeline                    " read modelines
 453 set modelines=2                 " only check first/last 2 lines
 454
 455 set writebackup                 " write a backup file before overwriting a file
 456 set backup                      " keep a backup after owerwriting a file
 457 set backupdir=$XDG_CACHE_HOME/vim/backup//
 458
 459 set backupskip+=.netrc          " skip netrc
 460 set backupskip+=/dev/shm/pass*  " skip passwordstore files
 461
 462 set undofile                    " persistent undo history
 463 set undolevels=10000            " moar undos
 464 if !has('nvim')
 465   set undodir=$XDG_CACHE_HOME/vim/undo//
 466 endif
 467
 468 augroup undoskip
 469     au!
 470     au BufWritePre .netrc         setlocal noundofile
 471     au BufWritePre /dev/shm/pass* setlocal noundofile
 472     au BufWritePre /tmp/*         setlocal noundofile
 473 augroup END
 474
 475 set autowrite                   " automatically write a file when leaving a modified buffer
 476 set autoread                    " automatically read a file that has been modified
 477
 478 " the swap file {{{2
 479 set noswapfile
 480 set directory=$XDG_CACHE_HOME/vim/swap//
 481
 482 " command line editing {{{2
 483 set history=5000                " how many command lines are remembered
 484 set wildmenu                    " command-line completion shows a list of matches
 485 set wildmode=longest:full,full  " specifies how command line completion works
 486 set wildignorecase              " ignore case when completing file names
 487
 488 set wildignore+=.hg,.git,.svn                    " Version control
 489 set wildignore+=*.aux,*.out,*.toc                " LaTeX intermediate files
 490 set wildignore+=*.jpg,*.bmp,*.gif,*.png,*.jpeg   " binary images
 491 set wildignore+=*.o,*.obj,*.exe,*.dll,*.manifest " compiled object files
 492 set wildignore+=*.spl                            " compiled spelling word lists
 493 set wildignore+=*.sw?                            " Vim swap files
 494 set wildignore+=*.luac                           " Lua byte code
 495 set wildignore+=*.pyc                            " Python byte code
 496 set wildignore+=*.orig                           " Merge resolution files
 497
 498 " running make and jumping to errors {{{2
 499 set makeprg=make\ -w     " print changing directories
 500
 501 set grepformat=%f:%l:%c:%m
 502 set grepprg=ag\ --vimgrep\ $*
 503
 504 " language specific {{{2
 505 set isfname-==    " don't treat `=` as being part of filenames
 506
 507 " various {{{2
 508 set virtualedit+=block     " let cursor move past last char in <C-V> mode
 509 set virtualedit+=onemore   " allow the cursor to move just past the end of the line
 510 if !has('nvim')
 511   " viminfo defaults but save file in .cache
 512   set viminfo='100,<50,s10,h,n$XDG_CACHE_HOME/vim/viminfo
 513 else
 514   " shada is the replacement format for viminfo
 515   " this setting is probably not needed as it's most likely the default
 516   " the default path is in XDG_DATA_HOME, which is fine
 517   set shada='100,<50,s10,h
 518 endif
 519
 520 set viewdir=$XDG_CACHE_HOME/vim/view//
 521
 522 set sessionoptions+=unix,slash  " damn windows and it's silly ways
 523
 524 " autocmds {{{1
 525 " Resize splits when the window is resized {{{2
 526 augroup resize_splits
 527     au!
 528     autocmd VimResized * :tabdo wincmd =
 529 augroup END
 530
 531 " Only show cursorline in the current window and in normal mode {{{2
 532 augroup cline
 533     au!
 534     au WinLeave,InsertEnter * set nocursorline
 535     au WinEnter,InsertLeave * set cursorline
 536 augroup END
 537
 538 " Treat buffers from stdin (e.g.: echo foo | vim -) as scratch {{{2
 539 augroup ft_stdin
 540     au!
 541     au StdinReadPost * :set buftype=nofile
 542 augroup END
 543
 544 " Jump to last known cursor position {{{2
 545 augroup last_loc
 546     au!
 547     " blacklist certain filetype
 548     let blacklist = ['gitcommit']
 549     autocmd BufReadPost *
 550                 \ if index(blacklist, &ft) < 0 && line("'\"") > 1 && line("'\"") <= line("$") |
 551                 \   exe "normal! g`\"" |
 552                 \ endif
 553 augroup END
 554
 555 " Check for file modifications automatically {{{2
 556 " (current buffer only)
 557 " Use :NoAutoChecktime to disable it (uses b:autochecktime)
 558 fun! MyAutoCheckTime()
 559   " only check timestamp for normal files
 560   if &buftype != '' | return | endif
 561   if ! exists('b:autochecktime') || b:autochecktime
 562     checktime %
 563     let b:autochecktime = 1
 564   endif
 565 endfun
 566 augroup MyAutoChecktime
 567   au!
 568   au FocusGained,BufEnter,CursorHold,InsertEnter * call MyAutoCheckTime()
 569 augroup END
 570 command! NoAutoChecktime let b:autochecktime=0
 571 command! ToggleAutoChecktime let b:autochecktime=!get(b:, 'autochecktime', 0) | echom "b:autochecktime:" b:autochecktime
 572
 573 " bindings {{{1
 574
 575 " make
 576 function! MakeWithOpt()
 577   " TODO only do this if makeprg matches make
 578   " if &makeprg =~ "make"
 579   let l:make_dir = ""
 580   if exists("b:make_dir")
 581     let l:make_dir = "-C ".b:make_dir
 582   elseif exists("t:make_dir")
 583     let l:make_dir = "-C ".t:make_dir
 584   elseif exists("g:make_dir")
 585     let l:make_dir = "-C ".g:make_dir
 586   endif
 587
 588   let l:make_targets = ""
 589   if exists("g:make_targets")
 590     let l:make_targets = g:make_targets
 591   endif
 592   execute "Make ".l:make_dir." ".l:make_targets
 593 endf
 594 nnoremap <silent> <leader>r :call MakeWithOpt()<cr>
 595
 596 " unhighlight search
 597 nnoremap <silent> <Leader>/ :silent nohl<CR>
 598
 599 " Tabs
 600 nnoremap <leader>[ :tabprev<cr>
 601 nnoremap <leader>] :tabnext<cr>
 602
 603 " paste from selection
 604 nnoremap <leader>p* :silent! set paste<CR>"*p:set nopaste<CR>
 605 " paste from clipboard
 606 nnoremap <leader>p+ :silent! set paste<CR>"+p:set nopaste<CR>
 607
 608 " strip trailing whitespace
 609 function! StripWhitespace(line1, line2, ...)  " {{{2
 610   let s_report = &report
 611   let &report=0
 612   let pattern = a:0 ? a:1 : '\s\+$'
 613   let oldview = winsaveview()
 614   exe 'keepjumps keeppatterns '.a:line1.','.a:line2.'substitute/'.pattern.'//e'
 615   if oldview != winsaveview()
 616     redraw
 617   endif
 618   call winrestview(oldview)
 619   let &report = s_report
 620 endfunction  " }}}2
 621 command! -range=% -nargs=0 -bar Untrail keepjumps call StripWhitespace(<line1>,<line2>)
 622 nnoremap <silent> <leader>ww :Untrail<CR>
 623
 624 " Source
 625 vnoremap <leader>S y:execute @@<cr>:echo 'Sourced selection.'<cr>
 626 nnoremap <leader>S ^vg_y:execute @@<cr>:echo 'Sourced line.'<cr>
 627
 628 " jump to last cursor position
 629 noremap ' `
 630
 631 " Select (charwise) the contents of the current line, excluding indentation.
 632 nnoremap vv ^vg_
 633
 634 " Unfuck my screen
 635 nnoremap U
 636       \ :syntax sync fromstart<cr>
 637       \ :AirlineRefresh<cr>
 638       \ :call popup_clear(1)<cr>
 639       \ :redraw!<cr>
 640
 641 " Ranger
 642 " nnoremap <leader>r :silent !ranger %:h<cr>:redraw!<cr>
 643 " nnoremap <leader>R :silent !ranger<cr>:redraw!<cr>
 644
 645 " display the number of matches for the last search
 646 nmap <Leader># :%s:<C-R>/::gn<CR>
 647
 648 " center cursor after search and open folds
 649 nnoremap n nzzzv
 650 nnoremap N Nzzzv
 651
 652 " same when jumping around
 653 nnoremap g; g;zzzv
 654 nnoremap g, g,zzzv
 655 nnoremap <c-o> <c-o>zzzv
 656 nnoremap <c-i> <c-i>zzzv
 657
 658 " Not using the default mappings of 'To line from top/bottom'
 659 noremap H ^
 660 noremap L $
 661 vnoremap H ^
 662 vnoremap L g_
 663
 664 " Heresy, emacs insert bindings
 665 inoremap <C-A> <Esc>I
 666 inoremap <C-E> <Esc>A
 667 cnoremap <C-A> <Home>
 668 cnoremap <C-E> <End>
 669
 670 " proper movement when lines are wrapped
 671 noremap <silent><expr> j (v:count == 0 ? 'gj' : 'j')
 672 noremap <silent><expr> k (v:count == 0 ? 'gk' : 'k')
 673
 674 " disable arrows
 675 noremap  <Up>    <NOP>
 676 noremap  <Down>  <NOP>
 677 noremap  <Left>  <NOP>
 678 noremap  <Right> <NOP>
 679 inoremap <Up>    <NOP>
 680 inoremap <Down>  <NOP>
 681 inoremap <Left>  <NOP>
 682 inoremap <Right> <NOP>
 683 cnoremap <Up>    <NOP>
 684 cnoremap <Down>  <NOP>
 685 cnoremap <Left>  <NOP>
 686 cnoremap <Right> <NOP>
 687 cnoremap <C-K>   <Up>
 688 cnoremap <C-J>   <Down>
 689 cnoremap <C-H>   <Left>
 690 cnoremap <C-L>   <Right>
 691
 692 " close all folds open fold in cursor
 693 nnoremap zx zMzxzt
 694
 695 map <F1> :ls<CR>:b<space>
 696
 697 " move between windows (skip previewwindow)
 698 nnoremap <silent> <C-L> <C-W>w<C-W>:if &previewwindow \| wincmd w \| endif<CR>
 699 nnoremap <silent> <C-H> <C-W>W<C-W>:if &previewwindow \| wincmd W \| endif<CR>
 700 tnoremap <silent> <C-L> <C-W>w<C-W>:if &previewwindow \| wincmd w \| endif<CR>
 701 tnoremap <silent> <C-H> <C-W>W<C-W>:if &previewwindow \| wincmd W \| endif<CR>
 702
 703 "xterm mouse with middleclick paste
 704 nnoremap <MiddleMouse> i<MiddleMouse>
 705 vnoremap <MiddleMouse> s<MiddleMouse>
 706
 707 " fix legacy vi inconsistency
 708 nnoremap Y y$
 709 " copy to clipboard
 710 xnoremap Y "+y
 711
 712 " allow repeat operator on visual
 713 vnoremap . :normal .<CR>
 714
 715 " add line without changing position or leaving mode
 716 noremap <silent> <Leader>o :set paste<CR>m`o<ESC>``:set nopaste<CR>
 717 noremap <silent> <Leader>O :set paste<CR>m`O<ESC>``:set nopaste<CR>
 718
 719 " Don't use Ex mode, use Q for formatting
 720 map Q gq
 721
 722 " break undo sequence before removing word
 723 inoremap <C-W> <C-G>u<C-W>
 724
 725 nnoremap coe :set <C-R>=&expandtab ? 'noexpandtab' : 'expandtab'<CR><CR>
 726 nnoremap [oe :set expandtab<CR>
 727 nnoremap ]oe :set noexpandtab<CR>
 728
 729 for idt in range(1,8)
 730   exe 'nnoremap co'.idt.' :setlocal tabstop='.idt.' shiftwidth='.idt.' softtabstop='.idt.'<CR>'
 731 endfor
 732
 733 " toggle auto format of text
 734 nnoremap coa :set <C-R>=&formatoptions =~ "a" ? 'formatoptions-=a' : 'formatoptions+=a'<CR><CR>
 735 nnoremap [oa :set formatoptions+=a<CR>
 736 nnoremap ]oa :set formatoptions-=a<CR>
 737
 738 " space will toggle current fold in normal mode
 739 nnoremap <leader><Space> za
 740 " create folds around visual selection
 741 vnoremap <leader><Space> zf
 742
 743 " save with sudo
 744 cabbrev w!! SudoWrite
 745
 746 " uppercase previous word
 747 inoremap <C-C> <C-G>u<Esc>gUiwgi
 748
 749 " http://git.io/v3ZeU
 750 nmap <silent> <leader>qq :echo "hi<" . synIDattr(synID(line("."),col("."),1),"name") . '> trans<' . synIDattr(synID(line("."),col("."),0),"name") . "> lo<" . synIDattr(synIDtrans(synID(line("."),col("."),1)),"name") . ">"<CR>
 751
 752 " plugins options {{{1
 753 " checkattach {{{2
 754 let g:checkattach_filebrowser = 'ranger'
 755 let g:checkattach_once = 'y'
 756
 757 " close-another-window {{{2
 758 nnoremap <silent> <C-W>c  <NOP>
 759 nnoremap <silent> <C-W>cc <C-W>c
 760 nnoremap <silent> <C-W>ch :CloseLeftWindow<CR>
 761 nnoremap <silent> <C-W>cl :CloseRightWindow<CR>
 762 nnoremap <silent> <C-W>cj :CloseBelowWindow<CR>
 763 nnoremap <silent> <C-W>ck :CloseAboveWindow<CR>
 764
 765
 766 " fswitch {{{2
 767 nnoremap <silent> <Leader>ff :FSHere<CR>
 768 nnoremap <silent> <Leader>fl :FSRight<CR>
 769 nnoremap <silent> <Leader>fh :FSLeft<CR>
 770 nnoremap <silent> <Leader>fj :FSBelow<CR>
 771 nnoremap <silent> <Leader>fk :FSAbove<CR>
 772 nnoremap <silent> <Leader>fL :FSSplitRight<CR>
 773 nnoremap <silent> <Leader>fH :FSSplitLeft<CR>
 774 nnoremap <silent> <Leader>fJ :FSSplitBelow<CR>
 775 nnoremap <silent> <Leader>fK :FSSplitAbove<CR>
 776
 777 " fugitive {{{2
 778 nmap <silent> <leader>dd :tab split \| Gdiff \| wincmd h<CR>
 779 " delete fugitive buffers when closed
 780 autocmd BufReadPost fugitive://* set bufhidden=delete
 781
 782 function! GitToggle()
 783   let l:status_buffer = bufname('^fugitive:///*/.git{/worktrees/*,}//$')
 784   if buflisted(l:status_buffer)
 785     execute 'bdelete '.l:status_buffer
 786   else
 787     execute 'Git'
 788     if !empty(FugitiveGitDir())
 789       " only resize status if Git was sucessful
 790       16wincmd_
 791     endif
 792   endif
 793 endfunction
 794 command! GitToggle :call GitToggle()
 795 command! GToggle GitToggle
 796 nnoremap <silent> <leader>gs :GitToggle<CR>
 797
 798 nnoremap <silent> <leader>gd :Gdiffsplit<CR>
 799 nnoremap <silent> <leader>gc :echohl WarningMsg \| echo "use \<leader>gcc instead" \| echohl None<CR>
 800 nnoremap <silent> <leader>gcc :tab G commit -v<CR>
 801 nnoremap <silent> <leader>gca :tab G commit -v --amend<CR>
 802 nnoremap          <leader>gcf :tab G commit -v --fixup=
 803 nnoremap <silent> <leader>gp :echohl WarningMsg \| echo "use \<leader>gpp instead" \| echohl None<CR>
 804 nnoremap <silent> <leader>gpp :Git push \| copen<CR>
 805 nnoremap <silent> <leader>gpf :Git push --force-with-lease \| copen<CR>
 806 nnoremap <silent> <leader>gll :Git pull<CR>
 807 nnoremap <silent> <leader>gru :Git rebase --interactive @{upstream}<CR>
 808 nnoremap <silent> <leader>grp :Git rebase --interactive @{push}<CR>
 809 nnoremap <silent> <leader>ga :Gwrite<cr>
 810 nnoremap <silent> <leader>gb :G blame<cr>
 811
 812 augroup fugitive_gstatus
 813     au!
 814     autocmd User FugitiveIndex setlocal winfixheight
 815     autocmd User FugitiveIndex nmap <buffer> <leader><space> =
 816 augroup end
 817
 818 " Gundo {{{2
 819 nnoremap <F7> :GundoToggle<CR>
 820 let g:gundo_prefer_python3 = 1
 821
 822 " indent-guides {{{2
 823 let g:indent_guides_default_mapping = 0
 824 let g:indent_guides_guide_size = 1
 825 nmap <silent> cog <Plug>IndentGuidesToggle
 826 nmap <silent> [og <Plug>IndentGuidesEnable
 827 nmap <silent> ]og <Plug>IndentGuidesDisable
 828
 829 " signature {{{2
 830 " disable '[ mappings
 831
 832 let g:SignatureMap = {
 833   \ 'GotoNextLineAlpha'  :  "",
 834   \ 'GotoPrevLineAlpha'  :  "",
 835   \ 'GotoNextSpotAlpha'  :  "",
 836   \ 'GotoPrevSpotAlpha'  :  "",
 837   \ }
 838
 839 " switch
 840 let g:switch_mapping = "<Leader>s"
 841 let g:switch_custom_definitions = [
 842       \   ['yes', 'no']
 843       \ ]
 844
 845 " spellrotate
 846 nmap <silent> z] <Plug>(SpellRotateForward)
 847 nmap <silent> z[ <Plug>(SpellRotateBackward)
 848 vmap <silent> z] <Plug>(SpellRotateForwardV)
 849 vmap <silent> z[ <Plug>(SpellRotateBackwardV)
 850
 851 " synastic {{{2
 852 let g:syntastic_enable_highlighting = 0
 853 let g:syntastic_error_symbol='E'
 854 let g:syntastic_style_error_symbol='S'
 855 let g:syntastic_warning_symbol='W'
 856 let g:syntastic_style_warning_symbol='S'
 857 let g:syntastic_always_populate_loc_list=1
 858 nmap <silent> <leader>y :SyntasticCheck<cr>
 859
 860 let g:syntastic_cpp_clang_tidy_post_args = "-p build*"
 861
 862 if ! &diff
 863   let g:syntastic_check_on_open=1
 864 endif
 865
 866
 867 " vim-easy-align {{{2
 868 " start interactive EasyAlign in visual mode
 869 vmap <Enter>   <Esc>:echohl WarningMsg \| echo "EasyAlign mapped to \16<leader>a now" \| echohl None<CR>
 870 vmap <leader>a <Plug>(EasyAlign)
 871 nmap <leader>a <Plug>(EasyAlign)
 872
 873 " vim-gtest {{{2
 874 let g:gtest#highlight_failing_tests = 0
 875
 876 nnoremap <silent> <Leader>tt :GTestRun<CR>
 877 nnoremap          <Leader>tc :GTestCase<space>
 878 nnoremap          <Leader>tn :GTestName<space>
 879 nnoremap <silent> <Leader>ta :GTestCase *<CR>:GTestName *<CR>:GTestRun<CR>
 880 nnoremap <silent> <Leader>tu :GTestRunUnderCursor<CR>
 881
 882 " vim-json {{{2
 883 let g:vim_json_syntax_conceal = 0
 884
 885 " functions {{{1
 886
 887 " Convenient command to see the difference between the current buffer and the
 888 " file it was loaded from, thus the changes you made.
 889 " Only define it when not defined already.
 890 if !exists(":DiffOrig")
 891   command DiffOrig vert new | set bt=nofile | r # | 0d_ | diffthis
 892                   \ | wincmd p | diffthis
 893 endif
 894
 895 " sort operator {{{2
 896 function! SortLinesOpFunc(...)
 897   '[,']sort
 898 endfunction
 899 nnoremap <silent> gs :<C-U>set operatorfunc=SortLinesOpFunc<CR>g@
 900 vnoremap <silent> gs :sort<cr>
 901
 902 " edit configs  {{{2
 903 " TODO: populate location list with both .vim and .lua files
 904 " TODO: create file if it doesn't exist in nvim or vim rtps
 905 function! EditConfig(what, ext = '.vim')
 906     if a:what == 'vimrc' || a:what == 'init.lua'
 907         let l:file = a:what
 908     elseif empty(&filetype)
 909         echoe 'filetype is empty!'
 910         return
 911     else
 912         let l:file = a:what.'/'.&filetype.a:ext
 913     endif
 914
 915     execute ':Vvsplit! '.file
 916 endf
 917 nmap <leader>en :call EditConfig('init.lua')<CR>
 918 nmap <leader>ev :call EditConfig('vimrc')<CR>
 919 nmap <leader>ef :call EditConfig('ftplugin')<CR>
 920 nmap <leader>es :call EditConfig('syntax')<CR>
 921 nmap <leader>ei :call EditConfig('indent')<CR>
 922 nmap <leader>eu :call EditConfig('ultisnips', '.snippets')<CR>
 923
 924 " spell check {{{2
 925 " http://tex.stackexchange.com/a/52932
 926 let g:myLangList=["en_gb","en_us","de","fr"]
 927
 928 function! ToggleSpell()
 929   if !exists("b:myLang")
 930     let b:myLang=0
 931   endif
 932   execute "setlocal spell!"
 933   if (&spell)
 934     echo "setlocal spelllang=" g:myLangList[b:myLang]
 935   endif
 936 endfunction
 937
 938 function! SwitchSpell()
 939   if !exists("b:myLang")
 940     let b:myLang=0
 941   endif
 942   if (&spell)
 943     let b:myLang=b:myLang+1
 944     if b:myLang>=len(g:myLangList) | let b:myLang=0 | endif
 945   endif
 946   execute "setlocal spell spelllang=".get(g:myLangList, b:myLang)
 947   echo "setlocal spelllang=" g:myLangList[b:myLang]
 948 endfunction
 949
 950 nnoremap <silent> coS :call SwitchSpell()<CR>
 951
 952 " gitdir or home {{{2
 953 " from derek wyatt:
 954 " http://git.io/v3GAV
 955 function! FindGitDirOrHome()
 956   let filedir = expand('%:p:h')
 957   if isdirectory(filedir)
 958     let cmd = 'bash -c "(cd ' . filedir . '; git rev-parse --show-toplevel 2>/dev/null)"'
 959     let gitdir = system(cmd)
 960     if strlen(gitdir) == 0
 961       return '~'
 962     else
 963       return gitdir[:-2]
 964     endif
 965   else
 966     return '~'
 967   endif
 968 endfunction
 969 command! Cd cd %:h
 970 command! Cdr execute('cd ' . FindGitDirOrHome())
 971 command! LCd lcd %:h
 972 command! LCdr execute('lcd ' . FindGitDirOrHome())
 973
 974 " vim:set et sw=2 ts=2 tw=78: