# Path to config files
ZSH=$XDG_CONFIG_HOME/zsh
ZSH_CACHE=$XDG_CACHE_HOME/zsh
[[ ! -d "$ZSH" ]] && echo "Missing config dir: '$ZSH'" && return
[[ ! -d "$ZSH_CACHE" ]] && echo "Missing cache dir: '$ZSH_CACHE'" && return

# Load all of the config files in $ZSH/lib that end in .zsh
for config_file ($ZSH/lib/*.zsh); do
  source $config_file
done

# Set name of the theme to load.
# Look in $ZSH/themes
ZSH_THEME="ramsi"
[[ -f "$ZSH/themes/${ZSH_THEME}.zsh-theme" ]] && source "$ZSH/themes/${ZSH_THEME}.zsh-theme"

# load my functions
typeset -U fpath    # make fpath a unique array
[[ -d $ZSH/functions ]] && fpath=($ZSH/functions $fpath)
autoload -U ${fpath[1]}/*(:t)   # loads all functions in the first element of fpath

# initialise completion
[[ -d "$ZSH_CACHE" ]] || mkdir -p "$ZSH_CACHE"
autoload -U compinit; compinit -d "$ZSH_CACHE/zcompdump"

# miscelaneous options
setopt extendedglob
setopt cshnullglob  # if glob does not match, remove pattern, if no glob matches print error
setopt numeric_glob_sort # sort numerically not lexically
setopt noclobber    # don't allow overwriting files with '>', use '>!' instead
setopt notify
setopt rcquotes     # echo 'don''t'; prints don't
setopt dvorak       # correct_all uses dvorak

# populate path
typeset -U path     # make path a unique array
[[ -d ~/.local/bin ]] && path=(~/.local/bin $path)
[[ -d ~/bin ]] && path=(~/bin $path)
[[ -d /extra ]] && path=($path /extra/bin /extra/usr/bin /extra/sbin /extra/usr/sbin)
[[ -d /opt/android-sdk ]] && path=($path /opt/android-sdk/platform-tools)

# source aliases
[[ -f $XDG_CONFIG_HOME/aliases ]] && source $XDG_CONFIG_HOME/aliases
for alias_file ($ZSH/aliases/*.zsh); do
  source $alias_file
done

# vim stuff
[[ -d "$XDG_CACHE_HOME/vim" ]] || mkdir -p "$XDG_CACHE_HOME/vim"
export VIMINIT='let $MYVIMRC="$XDG_CONFIG_HOME/vim/vimrc" | source $MYVIMRC'
export EDITOR=vim
export VISUAL=vim

# default browser
export BROWSER=dwb

# set up a few named directories
hash -d Skaro=/mnt/Skaro
hash -d ccr=~/ccr
hash -d src=~/src
hash -d chroot_testing=/buildsystem/testing/buildroot
hash -d chroot_master=/buildsystem/master/buildroot
hash -d chroot_lib32=/buildsystem/lib32/buildroot
hash -d wineprefixes=/mnt/data/wineprefixes
hash -d UniMaas=~/dropbox/Documents/UniMaas

# set some env variables
export _gamedir=/mnt/Skaro/Games/Linux/HumbleBundle

# ros
if [[ -f "/opt/ros/groovy/setup.zsh" ]]; then
    export ROS_WORKSPACE=~/src/ros
    export ROS_OS_OVERRIDE=arch
fi