" My vimrc file.
"
" Author:   Samir Benmendil <samir.benmendil[at]gmail[dot]com>
"

" bundles {{{1
filetype off
set runtimepath& " reset rtp

set runtimepath+=$XDG_DATA_HOME/vim/vundle
call vundle#rc('$XDG_DATA_HOME/vim')

Bundle 'gmarik/vundle'

Bundle 'bling/vim-airline'
Bundle 'elzr/vim-json'
Bundle 'ervandew/ag.git'
Bundle 'http://git.code.sf.net/p/vim-latex/vim-latex'
Bundle 'kien/ctrlp.vim'
Bundle 'majutsushi/tagbar'
Bundle 'scrooloose/nerdtree'
Bundle 'scrooloose/syntastic'
Bundle 'sjl/gundo.vim'
Bundle 'tomtom/tcomment_vim'
Bundle 'tpope/vim-fugitive'
Bundle 'tpope/vim-surround'
Bundle 'tpope/vim-unimpaired'
Bundle 'valloric/youcompleteme'
"Bundle 'zhaocai/goldenview.vim'

Bundle 'ompugao/ros.vim'
Bundle 'ompugao/ctrlp-ros'

Bundle 'derekwyatt/vim-fswitch'
Bundle 'jalcine/cmake.vim'

" rtp + xdg {{{1
" remove entries first
set runtimepath -=$HOME/.vim
set runtimepath -=$HOME/.vim/after
set runtimepath -=$XDG_CONFIG_HOME/vim
set runtimepath -=$XDG_CONFIG_HOME/vim/after
" then add prepend and append them
set runtimepath ^=$XDG_CONFIG_HOME/vim
set runtimepath +=$XDG_CONFIG_HOME/vim/after

filetype plugin indent on

" moving around, searching and patterns {{{1
set incsearch           " show match for partly typed search command
set ignorecase          " ignore case when using a search pattern
set smartcase           " override 'ignorecase' when pattern has upper case characters
set hlsearch                    " highlight all matches for the last used search pattern

" use leader-n to unhighlight search
nmap <silent> <Leader>n :silent nohl<CR>
" use leader-# to display the number of matches for the last search
nmap <Leader># :%s:<C-R>/::gn<CR>
" center cursor after search
nnoremap n nzz
" disable arrows
inoremap <Up> <NOP>
inoremap <Down> <NOP>
inoremap <Left> <NOP>
inoremap <Right> <NOP>
noremap <Up> <NOP>
noremap <Down> <NOP>
noremap <Left> <NOP>
noremap <Right> <NOP>

set nostartofline       " don't  move the cursor to the first non-blank char of a line
set path=.,include/,../include/,/usr/include/c++/*,/opt/ros/hydro/include

" displaying text {{{1
set scrolloff=5                 " number of screen lines to show around the cursor
set nowrap                      " long lines wrap
set linebreak                   " wrap long lines at a character in 'breakat'
set showbreak=▒▒                " show these chars for wrapped lines

set lazyredraw                  " don't redraw while executing macros

set list                        " show chars defined in 'listchars'
set listchars=tab:»·,trail:·    " list of strings used for list mode

set number                      " show the line number for each line
set relativenumber              " show the relative line number for each line
" toggle relativenumber
nnoremap <silent> <Leader>u :exe "set relativenumber!"<CR>

if has("autocmd")
  " When editing a file, always jump to the last known cursor position.
  " Don't do it when the position is invalid or when inside an event handler
  " (happens when dropping a file on gvim).
  " Also don't do it when the mark is in the first line, that is the default
  " position when opening a file.
  " blacklist certain filetype, you can get a file type with :echo &ft
  let blacklist = ['gitcommit']
  autocmd BufReadPost *
    \ if index(blacklist, &ft) < 0 && line("'\"") > 1 && line("'\"") <= line("$") |
    \   exe "normal! g`\"" |
    \ endif
endif


" syntax, highlighting and spelling {{{1
colorscheme badwolf
syntax on

set dictionary=spell            " list of dictionary files for keyword completion
" Spell Check http://tex.stackexchange.com/a/52932
let b:myLang=0
let g:myLangList=["en_gb","en_us","de","fr"]

function! ToggleSpell()
  execute "setlocal spell!"
  if (&spell)
    echo "setlocal spelllang=" g:myLangList[b:myLang]
  endif
endfunction
nnoremap <silent> <Leader>s :call ToggleSpell()<CR>

function! SwitchSpell()
  if (&spell)
    let b:myLang=b:myLang+1
    if b:myLang>=len(g:myLangList) | let b:myLang=0 | endif
  endif
  execute "setlocal spell spelllang=".get(g:myLangList, b:myLang)
  echo "setlocal spelllang=" g:myLangList[b:myLang]
endfunction
nnoremap <silent> <Leader>S :call SwitchSpell()<CR>

" fix spelling with first choice
nnoremap <Leader>f 1z=

if has("autocmd")
    au Filetype *
        \ if &omnifunc == "" | setl omnifunc=syntaxcomplete#Complete | endif
endif

" multiple windows {{{1
set laststatus=2                " 0, 1 or 2; when to use a status line for the last window

set previewheight=20            " default height for the preview window

set splitright                  " a new window is put right of the current one

map <F1> :ls<CR>:b<space>

nmap <C-L> <C-W>w
nmap <C-H> <C-W>W

" using the mouse {{{1
set mouse=rnv                   " list of flags for using the mouse
set ttymouse=xterm              " type of mouse

"xterm mouse with middleclick paste
nnoremap <MiddleMouse> i<MiddleMouse>
vnoremap <MiddleMouse> s<MiddleMouse>

" messages and info {{{1
set showcmd                     " Show (partial) command in status line.
set ruler                       " show the cursor position all the time
set confirm                     " Ask what to do when closing unsaved documents
set shortmess=filnxtoOI         " don't show intro message

" editing text {{{1
set backspace=indent,eol,start  " allow backspacing over everything in insert mode

set showmatch                   " Show matching brackets.

set nojoinspaces                " don't use two spaces after '.' when joining a line
set formatoptions+=j            " remove comment leader when joining lines

set nrformats=hex               " number formats recognized for CTRL-A and CTRL-X commands

" whether to use a popup menu for Insert mode completion
set completeopt=longest,menuone,preview

" Indent if we're at the beginning of a line. Else, do completion.
function! InsertTabWrapper()
  let col = col('.') - 1
  if !col || getline('.')[col - 1] !~ '\k'
    return "\<Tab>"
  else
    return "\<C-N>"
endif
endfunction
inoremap <Tab> <C-R>=InsertTabWrapper()<CR>
inoremap <S-Tab> <C-P>

" fix legacy vi inconsistency
map Y y$

" allow repeat operator on visual
vnoremap . :normal .<CR>

" add line without changing position or leaving mode
map <Leader>o :set paste<CR>m`o<ESC>``:set nopaste<CR>
map <Leader>O :set paste<CR>m`O<ESC>``:set nopaste<CR>

" Don't use Ex mode, use Q for formatting
map Q gq

" allow undoing in insert-mode
inoremap <C-U> <C-G>u<C-U>
inoremap <C-W> <C-G>u<C-W>

" tabs and indent {{{1
set shiftwidth=4                " number of spaces used for each step of (auto)indent
set smarttab                    " a <Tab> in an indent inserts 'shiftwidth' spaces
set softtabstop=4               " if non-zero, number of spaces to insert for a <Tab>
set shiftround                  " round to 'shiftwidth' for "<<" and ">>"
set expandtab                   " expand <Tab> to spaces in Insert mode

set cindent                     " use smart C indenting (see :h C-indenting)
set cinoptions=l1,c4,(0,U1,w1,m1,j1,J1

set pastetoggle=<F11>           " key sequence to toggle paste mode

nmap <Leader>b :set expandtab tabstop=4 shiftwidth=4 softtabstop=4<CR>
nmap <Leader>B :set expandtab tabstop=8 shiftwidth=8 softtabstop=4<CR>
nmap <Leader>M :set noexpandtab tabstop=8 softtabstop=4 shiftwidth=4<CR>
nmap <Leader>m :set expandtab tabstop=2 shiftwidth=2 softtabstop=2<CR>

" folding {{{1
set foldmethod=marker           " folding type
set foldlevelstart=0            " value for 'foldlevel' when starting to edit a file

" space will toggle current fold in normal mode
nnoremap <silent> <Space> @=(foldlevel('.')?'za':"\<Space>")<CR>
" create folds around visual selection
vnoremap <Space> zf

" save and restore folds
set viewoptions=folds,cursor    " don't save local options
autocmd BufWinLeave *.* mkview
autocmd BufWinEnter *.* silent loadview

" reading and writing files {{{1
set writebackup                 " write a backup file before overwriting a file
set backup                      " keep a backup after owerwriting a file
set backupdir=$XDG_CACHE_HOME/vim

set undofile                    " persistent undo history
set undodir=$XDG_CACHE_HOME/vim

set autowrite                   " automatically write a file when leaving a modified buffer

" save with sudo
cmap w!! w !sudo tee % > /dev/null

" the swap file {{{1
set directory=$XDG_CACHE_HOME/vim,.,/var/tmp

" command line editing {{{1
set history=500                 " how many command lines are remembered
set wildmode=longest:full       " specifies how command line completion works
set wildmenu                    " command-line completion shows a list of matches

" various {{{1
set virtualedit=block           " let cursor move past last char in <C-V> mode
set viminfo='100,<50,s10,h,n$XDG_CACHE_HOME/vim/viminfo " viminfo defaults but save file in .cache

set viewdir=$XDG_CACHE_HOME/vim

" plugins {{{1
" airline {{{2
let g:airline_detect_whitespace=2
let g:airline#extensions#tabline#enabled = 1
let g:airline_powerline_fonts = 1

" GoldenView {{{2
"let g:goldenview__enable_default_mapping = 0
"nmap <silent> <C-N>   <Plug>GoldenViewSplit
"nmap <silent> <C-L>   <Plug>GoldenViewNext
"nmap <silent> <C-H>   <Plug>GoldenViewPrevious
"nmap <silent> <C-M>   <Plug>GoldenViewSwitchMain
"nmap <silent> <C-S-M> <Plug>GoldenViewPrevious

" Gundo {{{2
nnoremap <F7> :GundoToggle<CR>
" fugitive {{{2
nmap <silent> <leader>dd :tab split \| Gdiff \| wincmd h<CR>
" delete fugitive buffers when closed
autocmd BufReadPost fugitive://* set bufhidden=delete

" NERDTree {{{2
" open/close NERDTree with \e
nmap <Leader>e :NERDTreeToggle<CR>
nmap <F6> :NERDTreeToggle<CR>
" <space> to open files/dirs
let NERDTreeMapActivateNode='<space>'
" close vim if only NERDTree is open
autocmd bufenter * if (winnr("$") == 1 && exists("b:NERDTreeType") && b:NERDTreeType == "primary") | q | endif

" synastic {{{2
let g:syntastic_enable_highlighting = 0
let g:syntastic_error_symbol='E'
let g:syntastic_style_error_symbol='S'
let g:syntastic_warning_symbol='W'
let g:syntastic_style_warning_symbol='S'
let g:syntastic_always_populate_loc_list=1
nmap <silent> <leader>y :SyntasticCheck<cr>

if ! &diff
  let g:syntastic_check_on_open=1
endif

" tagbar {{{2
map <F5> :TagbarToggle<cr>
let g:tagbar_sort = 0
let g:tagbar_compact = 1
let g:tagbar_autoshowtag = 1
let g:tagbar_width = 25
let g:tagbar_iconchars = ['+', '-']

" YouCompleteMe {{{2
let g:ycm_extra_conf_globlist = ['~/src/*']

" vim-json {{{2
let g:vim_json_syntax_conceal = 0

" vim-latex {{{2
let g:tex_flavor='latex'
let g:Tex_DefaultTargetFormat='pdf'

" functions {{{1
" auto source vimrc when saved
autocmd bufwritepost vimrc source $MYVIMRC
nmap <leader>v :tabedit $MYVIMRC<CR>

" Convenient command to see the difference between the current buffer and the
" file it was loaded from, thus the changes you made.
" Only define it when not defined already.
if !exists(":DiffOrig")
  command DiffOrig vert new | set bt=nofile | r # | 0d_ | diffthis
                  \ | wincmd p | diffthis
endif