if (( ! $+commands[task] )); then
    return 1
fi

alias task="noglob task"
alias t="task"
alias tt="task today"

alias in="task add +in"
alias inn="in rc.context=none"

alias tw="task context wfh"
alias th="task context home"

alias tlatest="t +LATEST"

autoload -Uz task-quote-magic
zle -N self-insert task-quote-magic

function tparent() {
    # TODO: check args
    task _get $1.rparent
}

function tick() {
    # TODO: have duration as an option to allow multiple filter
    if (( # < 1 || # > 2)); then
        print >&2 "Usage: $0 <filter> [duration]"
        return 1
    fi
    task $1 mod wait:${2:-1h}
}

function turg() {
    local context=$(task _get rc.context)
    local context_read=$(task _get rc.context.$context.read)
    local urg_task=$(task +READY $context_read _urgency | sort -k4 -n | tail -1 | cut -d" " -f2)
    task $urg_task $@
}

# TODO: function to show the latest report

function task_today_list() {
  local task_cmd=(task rc.verbose:nothing)
  local task_count=$($task_cmd $($task_cmd _get rc.report.today.filter) count)

  local task_status=""
  task_status+="%{$fg_bold[red]%} $task_count "
  task_status+="%{$reset_color%}"
  echo $task_status
}