X-Git-Url: https://git.rmz.io/dotfiles.git/blobdiff_plain/8c7911883ed8b42987c9179512d60dbb3681dc2f..698483f78280d2b5d5af36b1b82987d5b7b11f9e:/zsh/plugins/pip/_pip?ds=sidebyside

diff --git a/zsh/plugins/pip/_pip b/zsh/plugins/pip/_pip
new file mode 100644
index 0000000..df53ba5
--- /dev/null
+++ b/zsh/plugins/pip/_pip
@@ -0,0 +1,74 @@
+#compdef pip
+#autoload
+
+# pip zsh completion, based on homebrew completion
+
+_pip_all() {
+  # we cache the list of packages (originally from the macports plugin)
+  if (( ! $+piplist )); then
+    echo -n " (caching package index...)"
+	piplist=($(pip search * | cut -d ' ' -f 1 | tr '[A-Z]' '[a-z]'))
+  fi
+}
+
+_pip_installed() {
+  installed_pkgs=(`pip freeze | cut -d '=' -f 1`)
+}
+
+local -a _1st_arguments
+_1st_arguments=(
+  'bundle:create pybundles (archives containing multiple packages)'
+  'freeze:output all currently installed packages (exact versions) to stdout'
+  'help:show available commands'
+  'install:install packages'
+  'search:search PyPI'
+  'uninstall:uninstall packages'
+  'unzip:unzip individual packages'
+  'zip:zip individual packages'
+)
+
+local expl
+local -a all_pkgs installed_pkgs
+
+_arguments \
+  '(--version)--version[show version number of program and exit]' \
+  '(-h --help)'{-h,--help}'[show help]' \
+  '(-E --environment)'{-E,--environment}'[virtualenv environment to run pip in]' \
+  '(-s --enable-site-packages)'{-s,--enable-site-packages}'[include site-packages in virtualenv]' \
+  '(-v --verbose)'{-v,--verbose}'[give more output]' \
+  '(-q --quiet)'{-q,--quiet}'[give less output]' \
+  '(--log)--log[log file location]' \
+  '(--proxy)--proxy[proxy in form user:passwd@proxy.server:port]' \
+  '(--timeout)--timeout[socket timeout (default 15s)]' \
+  '*:: :->subcmds' && return 0
+
+if (( CURRENT == 1 )); then
+  _describe -t commands "pip subcommand" _1st_arguments
+  return
+fi
+
+case "$words[1]" in
+  search)
+    _arguments \
+      '(--index)--index[base URL of Python Package Index]' ;;
+  freeze)
+    _arguments \
+      '(-l --local)'{-l,--local}'[report only virtualenv packages]' ;;
+  install)
+  	_arguments \
+      '(-U --upgrade)'{-U,--upgrade}'[upgrade all packages to the newest available version]' \
+      '(-f --find-links)'{-f,--find-links}'[URL for finding packages]' \
+      '(--no-deps --no-dependencies)'{--no-deps,--no-dependencies}'[iIgnore package dependencies]' \
+      '(--no-install)--no-install[only download packages]' \
+      '(--no-download)--no-download[only install downloaded packages]' \
+      '(--install-option)--install-option[extra arguments to be supplied to the setup.py]' \
+      '1: :->packages' &&  return 0
+     
+      if [[ "$state" == packages ]]; then
+        _pip_all
+        _wanted piplist expl 'packages' compadd -a piplist
+      fi ;;
+  uninstall)
+    _pip_installed
+    _wanted installed_pkgs expl 'installed packages' compadd -a installed_pkgs ;;
+esac