vim/vimrc

   1 " My vimrc.
   2 "
   3 " Author:   Samir Benmendil <samir.benmendil[at]gmail[dot]com>
   4 "
   5
   6 " plugins {{{1
   7 filetype off
   8 set runtimepath& " reset rtp
   9 " remove all autocommands
  10 autocmd!
  11
  12 set runtimepath+=$XDG_DATA_HOME/vim/vundle
  13 call vundle#rc('$XDG_DATA_HOME/vim')
  14
  15 Plugin 'gmarik/vundle'
  16
  17 Plugin 'airblade/vim-gitgutter'
  18 Plugin 'bling/vim-airline'
  19 Plugin 'derekwyatt/vim-fswitch'
  20 Plugin 'elzr/vim-json'
  21 Plugin 'firef0x/pkgbuild.vim'
  22 Plugin 'junegunn/vim-easy-align'
  23 Plugin 'justinmk/vim-sneak'
  24 Plugin 'klen/python-mode'
  25 Plugin 'kshenoy/vim-signature'
  26 Plugin 'majutsushi/tagbar'
  27 Plugin 'octol/vim-cpp-enhanced-highlight'
  28 Plugin 'raimondi/delimitmate'
  29 Plugin 'scrooloose/syntastic'
  30 Plugin 'shougo/unite.vim'
  31 Plugin 'shougo/vimproc.vim'
  32 Plugin 'sjl/gundo.vim'
  33 Plugin 'tomtom/tcomment_vim'
  34 Plugin 'tpope/vim-abolish'
  35 Plugin 'tpope/vim-endwise'
  36 Plugin 'tpope/vim-fugitive'
  37 Plugin 'tpope/vim-repeat'
  38 Plugin 'tpope/vim-surround'
  39 Plugin 'tpope/vim-unimpaired'
  40 Plugin 'valloric/youcompleteme'
  41 Plugin 'vim-scripts/replacewithregister'
  42 Plugin 'vim-scripts/yankring.vim'
  43
  44 " colorschemes
  45 Plugin 'flazz/vim-colorschemes'
  46
  47 " snippets
  48 Plugin 'sirver/ultisnips'
  49 Plugin 'honza/vim-snippets'
  50
  51 " text objects
  52 Plugin 'kana/vim-textobj-user'
  53 Plugin 'julian/vim-textobj-variable-segment'
  54 Plugin 'sgur/vim-textobj-parameter'
  55
  56 " ros
  57 Plugin 'ompugao/ros.vim'
  58 Plugin 'ompugao/ctrlp-ros'
  59
  60 " seems to have problems right now... may be add later?
  61 " Plugin 'jalcine/cmake.vim'
  62 " Plugin 'powerman/vim-plugin-viewdoc'
  63
  64 " staging
  65 " find an alternative (latex-box? Automatic Latex Plugin?)
  66 Plugin 'http://git.code.sf.net/p/vim-latex/vim-latex'
  67 " Plugin 'lokaltog/vim-easymotion'
  68 Plugin 'chrisbra/checkattach'
  69 Plugin 'nathanaelkane/vim-indent-guides'
  70 Plugin 'alx741/vinfo'
  71 Plugin 'vim-scripts/mediawiki.vim'
  72 Plugin 'derekwyatt/vim-protodef'
  73 Plugin 'rdnetto/ycm-generator'
  74 " needs editing colorscheme
  75 " Plugin 'jeaye/color_coded'
  76
  77 " remove entries first
  78 set runtimepath -=$HOME/.vim
  79 set runtimepath -=$HOME/.vim/after
  80 set runtimepath -=$XDG_CONFIG_HOME/vim
  81 set runtimepath -=$XDG_CONFIG_HOME/vim/after
  82 " then prepend and append them
  83 set runtimepath ^=$XDG_CONFIG_HOME/vim
  84 set runtimepath +=$XDG_CONFIG_HOME/vim/after
  85
  86 filetype plugin indent on
  87
  88 " colorscheme {{{1
  89 syntax on
  90 colorscheme badfox
  91
  92 " options {{{1
  93 " moving around, searching and patterns {{{2
  94 set incsearch           " show match for partly typed search command
  95 set ignorecase          " ignore case when using a search pattern
  96 set smartcase           " override 'ignorecase' when pattern has upper case characters
  97 set hlsearch            " highlight all matches for the last used search pattern
  98
  99 set nostartofline       " don't move the cursor to the first non-blank char of a line
 100 set path+=.
 101 set path+=include/
 102 set path+=../include/
 103 set path+=/usr/include/c++/*
 104
 105 " displaying text {{{2
 106 set nowrap                      " long lines wrap
 107 set linebreak                   " wrap long lines at a character in 'breakat'
 108 set showbreak=↪                 " show these chars for wrapped lines
 109 set breakindent                 " preserve indentation in wrapped text
 110
 111 set lazyredraw                  " don't redraw while executing macros
 112
 113 set list                        " show chars defined in 'listchars'
 114 set listchars=tab:❭\            " list of strings used for list mode
 115 set listchars+=extends:❯,precedes:❮
 116 " Only shown when not in insert mode
 117 au InsertLeave * :set listchars+=trail:·
 118 augroup trailing
 119     au!
 120     au InsertEnter * :set listchars-=trail:·
 121     au InsertLeave * :set listchars+=trail:·
 122 augroup END
 123
 124 set scrolloff=5                 " number of screen lines to show around the cursor
 125 set sidescroll=1                " number of collumns to scroll
 126 set sidescrolloff=1             " don't scroll over the listchars
 127
 128 set fillchars=diff:⣿,vert:│
 129
 130 set nonumber                    " show the line number for each line
 131 set norelativenumber            " show the relative line number for each line
 132
 133 " syntax, highlighting and spelling {{{2
 134 set synmaxcol=800               " don't highlight long lines
 135
 136 set dictionary=spell            " list of dictionary files for keyword completion
 137
 138 set colorcolumn=+1
 139
 140 " multiple windows {{{2
 141 set laststatus=2                " 0, 1 or 2; when to use a status line for the last window
 142
 143 set previewheight=20            " default height for the preview window
 144
 145 set hidden
 146
 147 " set splitbelow                  " a new window is put below of the current one
 148 set splitright                  " a new window is put right of the current one
 149
 150 " terminal {{{2
 151 set ttyfast
 152
 153 " using the mouse {{{2
 154 set mouse=rnv                   " list of flags for using the mouse
 155 set ttymouse=xterm              " type of mouse
 156
 157 " messages and info {{{2
 158 set showcmd                     " Show (partial) command in status line.
 159 set ruler                       " show the cursor position all the time
 160 set confirm                     " Ask what to do when closing unsaved documents
 161 set shortmess=filnxtoOI         " don't show intro message
 162
 163 " editing text {{{2
 164 set backspace=indent,eol,start  " allow backspacing over everything in insert mode
 165
 166 set showmatch                   " Show matching brackets.
 167
 168 set nojoinspaces                " don't use two spaces after '.' when joining a line
 169 set formatoptions+=j    " Delete comment leader when joining lines
 170 set formatoptions+=c    " Autowrap comments using textwidth
 171 set formatoptions+=r    " Insert comment leader after hitting <Enter>
 172 set formatoptions+=n    " Recognize numbered lists
 173 set formatoptions+=q    " Allow formatting of comments with "gq".
 174 set formatoptions+=l    " do not wrap lines that have been longer when starting insert mode already
 175 set formatoptions+=t    " Auto-wrap text using textwidth
 176 set formatoptions-=o    " Do not insert comment leader after hitting o or O in normal mode
 177
 178 set nrformats=hex               " number formats recognized for CTRL-A and CTRL-X commands
 179
 180 set complete=.       " scan the current buffer ( 'wrapscan' is ignored)
 181 set complete+=w      " scan buffers from other windows
 182 set complete+=b      " scan other loaded buffers that are in the buffer list
 183 set complete+=u      " scan the unloaded buffers that are in the buffer list
 184 set complete+=t      " scan tags
 185 set complete+=i      " scan current and included files
 186 set complete+=kspell " use the currently active spell checking |spell|
 187
 188 " whether to use a popup menu for Insert mode completion
 189 set completeopt=longest,menuone,preview
 190
 191 " tabs and indent {{{2
 192 set shiftwidth=4                " number of spaces used for each step of (auto)indent
 193 set smarttab                    " a <Tab> in an indent inserts 'shiftwidth' spaces
 194 set softtabstop=4               " if non-zero, number of spaces to insert for a <Tab>
 195 set shiftround                  " round to 'shiftwidth' for "<<" and ">>"
 196 set expandtab                   " expand <Tab> to spaces in Insert mode
 197 set autoindent
 198
 199 set pastetoggle=<F11>           " key sequence to toggle paste mode
 200
 201 " folding {{{2
 202 set foldmethod=marker           " folding type
 203 set foldlevelstart=0            " value for 'foldlevel' when starting to edit a file
 204
 205 " open folds when jumping to line
 206 set foldopen+=jump
 207
 208 " save and restore folds
 209 set viewoptions=cursor          " only save cursor position
 210
 211 " diff mode {{{2
 212 set diffopt+=filler         " show filler lines
 213 set diffopt+=vertical       " always vertical split
 214 set diffopt+=iwhite         " ignore white space
 215 set diffopt+=context:10     " 10 lines context between changes
 216
 217 " reading and writing files {{{2
 218 set modeline                    " read modelines
 219 set modelines=2                 " only check first/last 2 lines
 220
 221 set writebackup                 " write a backup file before overwriting a file
 222 set backup                      " keep a backup after owerwriting a file
 223 set backupdir=$XDG_CACHE_HOME/vim/backup//
 224
 225 set backupskip+=.netrc          " skip netrc
 226 set backupskip+=/dev/shm/pass*  " skip passwordstore files
 227
 228 set undofile                    " persistent undo history
 229 set undodir=$XDG_CACHE_HOME/vim/undo//
 230
 231 augroup undoskip
 232     au!
 233     au BufWritePre .netrc         setlocal noundofile
 234     au BufWritePre /dev/shm/pass* setlocal noundofile
 235     au BufWritePre /tmp/*         setlocal noundofile
 236 augroup END
 237
 238 set autowrite                   " automatically write a file when leaving a modified buffer
 239 set autoread                    " automatically read a file that has been modified
 240
 241 " the swap file {{{2
 242 set noswapfile
 243 set directory=$XDG_CACHE_HOME/vim/swap//
 244
 245 " command line editing {{{2
 246 set history=5000                " how many command lines are remembered
 247 set wildmenu                    " command-line completion shows a list of matches
 248 set wildmode=longest:full,full  " specifies how command line completion works
 249
 250 set wildignore+=.hg,.git,.svn                    " Version control
 251 set wildignore+=*.aux,*.out,*.toc                " LaTeX intermediate files
 252 set wildignore+=*.jpg,*.bmp,*.gif,*.png,*.jpeg   " binary images
 253 set wildignore+=*.o,*.obj,*.exe,*.dll,*.manifest " compiled object files
 254 set wildignore+=*.spl                            " compiled spelling word lists
 255 set wildignore+=*.sw?                            " Vim swap files
 256 set wildignore+=*.luac                           " Lua byte code
 257 set wildignore+=*.pyc                            " Python byte code
 258 set wildignore+=*.orig                           " Merge resolution files
 259
 260 " running make and jumping to errors
 261 set makeprg=make\ -w     " print changing directories
 262
 263 " language specific {{{2
 264 set isfname-==    " don't treat `=` as being part of filenames
 265
 266 " various {{{2
 267 set virtualedit=all             " let cursor move past last char in <C-V> mode
 268 set viminfo='100,<50,s10,h,n$XDG_CACHE_HOME/vim/viminfo " viminfo defaults but save file in .cache
 269
 270 set viewdir=$XDG_CACHE_HOME/vim/view//
 271
 272 set sessionoptions+=unix,slash  " damn windows and it's silly ways
 273
 274 " autocmds {{{1
 275 " Resize splits when the window is resized {{{2
 276 augroup resize
 277     au!
 278     autocmd VimResized * :wincmd =
 279 augroup END
 280
 281 " Only show cursorline in the current window and in normal mode {{{2
 282 augroup cline
 283     au!
 284     au WinLeave,InsertEnter * set nocursorline
 285     au WinEnter,InsertLeave * set cursorline
 286 augroup END
 287
 288 " Treat buffers from stdin (e.g.: echo foo | vim -) as scratch {{{2
 289 augroup ft_stdin
 290     au!
 291     au StdinReadPost * :set buftype=nofile
 292 augroup END
 293
 294 " Jump to last known cursor position {{{2
 295 augroup cursor_pos
 296     au!
 297     " blacklist certain filetype
 298     let blacklist = ['gitcommit']
 299     autocmd BufReadPost *
 300                 \ if index(blacklist, &ft) < 0 && line("'\"") > 1 && line("'\"") <= line("$") |
 301                 \   exe "normal! g`\"" |
 302                 \ endif
 303 augroup END
 304
 305 " Check for file modifications automatically {{{2
 306 " (current buffer only)
 307 " Use :NoAutoChecktime to disable it (uses b:autochecktime)
 308 fun! MyAutoCheckTime()
 309   " only check timestamp for normal files
 310   if &buftype != '' | return | endif
 311   if ! exists('b:autochecktime') || b:autochecktime
 312     checktime %
 313     let b:autochecktime = 1
 314   endif
 315 endfun
 316 augroup MyAutoChecktime
 317   au!
 318   au FocusGained,BufEnter,CursorHold,InsertEnter * call MyAutoCheckTime()
 319 augroup END
 320 command! NoAutoChecktime let b:autochecktime=0
 321 command! ToggleAutoChecktime let b:autochecktime=!get(b:, 'autochecktime', 0) | echom "b:autochecktime:" b:autochecktime
 322
 323 " bindings {{{1
 324
 325 " allow both <space> and / to be <leader>
 326 map <space> <leader>
 327
 328 " make
 329 nnoremap <leader>r :make!<cr>
 330 nnoremap <leader><cr> :make!<cr>
 331
 332 " unhighlight search
 333 nnoremap <silent> <Leader>/ :silent nohl<CR>
 334
 335 " Tabs
 336 nnoremap <leader>[ :tabprev<cr>
 337 nnoremap <leader>] :tabnext<cr>
 338
 339 " paste from selection
 340 nnoremap <leader>p* :silent! set paste<CR>"*p:set nopaste<CR>
 341 " paste from clipboard
 342 nnoremap <leader>p+ :silent! set paste<CR>"+p:set nopaste<CR>
 343
 344 " strip trailing whitespace
 345 function! StripWhitespace(line1, line2, ...)  " {{{2
 346   let s_report = &report
 347   let &report=0
 348   let pattern = a:0 ? a:1 : '[\\]\@<!\s\+$'
 349   let oldview = winsaveview()
 350   exe 'keepjumps keeppatterns '.a:line1.','.a:line2.'substitute/'.pattern.'//e'
 351   if oldview != winsaveview()
 352     redraw
 353   endif
 354   call winrestview(oldview)
 355   let &report = s_report
 356 endfunction  " }}}2
 357 command! -range=% -nargs=0 -bar Untrail keepjumps call StripWhitespace(<line1>,<line2>)
 358 nnoremap <silent> <leader>ww :Untrail<CR>
 359
 360 " Source
 361 vnoremap <leader>S y:execute @@<cr>:echo 'Sourced selection.'<cr>
 362 nnoremap <leader>S ^vg_y:execute @@<cr>:echo 'Sourced line.'<cr>
 363
 364 " jump to last cursor position
 365 noremap ' `
 366
 367 " Select (charwise) the contents of the current line, excluding indentation.
 368 nnoremap vv ^vg_
 369
 370 " Unfuck my screen
 371 nnoremap U :syntax sync fromstart<cr>:AirlineRefresh<cr>:redraw!<cr>
 372
 373 " Ranger
 374 " nnoremap <leader>r :silent !ranger %:h<cr>:redraw!<cr>
 375 " nnoremap <leader>R :silent !ranger<cr>:redraw!<cr>
 376
 377 " Use sane regexes.
 378 nnoremap / /\v
 379 vnoremap / /\v
 380 cnoremap s/ s/\v
 381
 382 " display the number of matches for the last search
 383 nmap <Leader># :%s:<C-R>/::gn<CR>
 384
 385 " center cursor after search and open folds
 386 nnoremap n nzzzv
 387 nnoremap N Nzzzv
 388
 389 " same when jumping around
 390 nnoremap g; g;zzzv
 391 nnoremap g, g,zzzv
 392 nnoremap <c-o> <c-o>zzzv
 393 nnoremap <c-i> <c-i>zzzv
 394
 395 " Not using the default mappings of 'To line from top/bottom'
 396 noremap H ^
 397 noremap L $
 398 vnoremap H ^
 399 vnoremap L g_
 400
 401 " Heresy, emacs insert bindings
 402 inoremap <C-A> <Esc>I
 403 inoremap <C-E> <Esc>A
 404 cnoremap <C-A> <Home>
 405 cnoremap <C-E> <End>
 406
 407 " proper movement when lines are wrapped
 408 noremap <expr> j (v:count == 0 ? 'gj' : 'j')
 409 noremap <expr> k (v:count == 0 ? 'gk' : 'k')
 410
 411 " disable arrows
 412 noremap  <Up>    <NOP>
 413 noremap  <Down>  <NOP>
 414 noremap  <Left>  <NOP>
 415 noremap  <Right> <NOP>
 416 inoremap <Up>    <NOP>
 417 inoremap <Down>  <NOP>
 418 inoremap <Left>  <NOP>
 419 inoremap <Right> <NOP>
 420 cnoremap <Up>    <NOP>
 421 cnoremap <Down>  <NOP>
 422 cnoremap <Left>  <NOP>
 423 cnoremap <Right> <NOP>
 424 cnoremap <C-K>   <Up>
 425 cnoremap <C-J>   <Down>
 426 cnoremap <C-H>   <Left>
 427 cnoremap <C-L>   <Right>
 428
 429 " close all folds open fold in cursor
 430 nnoremap zx zMzxzt
 431
 432 map <F1> :ls<CR>:b<space>
 433
 434 nnoremap <C-L> <C-W>w
 435 nnoremap <C-H> <C-W>W
 436
 437 "xterm mouse with middleclick paste
 438 nnoremap <MiddleMouse> i<MiddleMouse>
 439 vnoremap <MiddleMouse> s<MiddleMouse>
 440
 441 " fix legacy vi inconsistency
 442 nnoremap Y y$
 443 " copy to clipboard
 444 xnoremap Y "+y
 445
 446 " allow repeat operator on visual
 447 vnoremap . :normal .<CR>
 448
 449 " add line without changing position or leaving mode
 450 noremap <silent> <Leader>o :set paste<CR>m`o<ESC>``:set nopaste<CR>
 451 noremap <silent> <Leader>O :set paste<CR>m`O<ESC>``:set nopaste<CR>
 452
 453 " Don't use Ex mode, use Q for formatting
 454 map Q gq
 455
 456 " break undo sequence before removing word
 457 inoremap <C-W> <C-G>u<C-W>
 458
 459 nnoremap coe :set <C-R>=&expandtab ? 'noexpandtab' : 'expandtab'<CR><CR>
 460 nnoremap [oe :set expandtab<CR>
 461 nnoremap ]oe :set noexpandtab<CR>
 462
 463 for idt in range(1,8)
 464   exe 'nnoremap co'.idt.' :set tabstop='.idt.' shiftwidth='.idt.' softtabstop='.idt.'<CR>'
 465 endfor
 466
 467 " toggle auto format of text
 468 nnoremap coa :set <C-R>=&formatoptions =~ "a" ? 'formatoptions-=a' : 'formatoptions+=a'<CR><CR>
 469 nnoremap [oa :set formatoptions+=a<CR>
 470 nnoremap ]oa :set formatoptions-=a<CR>
 471
 472 " space will toggle current fold in normal mode
 473 nnoremap <leader><Space> za
 474 " create folds around visual selection
 475 vnoremap <leader><Space> zf
 476
 477 autocmd BufWinLeave *.* mkview
 478 autocmd BufWinEnter *.* silent loadview
 479
 480 " save with sudo
 481 cabbrev w!! w !sudo tee % > /dev/null
 482
 483 " uppercase previous word
 484 inoremap <C-C> <Esc>gUiwgi
 485
 486 " http://git.io/v3ZeU
 487 nmap <silent> <leader>qq :echo "hi<" . synIDattr(synID(line("."),col("."),1),"name") . '> trans<' . synIDattr(synID(line("."),col("."),0),"name") . "> lo<" . synIDattr(synIDtrans(synID(line("."),col("."),1)),"name") . ">"<CR>
 488
 489 " commands {{{1
 490 command! Cd cd %:h
 491 command! Cr execute('cd ' . FindGitDirOrHome())
 492 command! LCd lcd %:h
 493 command! LCr execute('lcd ' . FindGitDirOrHome())
 494
 495 " plugins options {{{1
 496 " airline {{{2
 497 let g:airline#extensions#whitespace#enabled = 1
 498 let g:airline#extensions#tabline#enabled = 1
 499 let g:airline_powerline_fonts = 1
 500
 501 " checkattach {{{2
 502 let g:checkattach_filebrowser = 'ranger'
 503 let g:checkattach_once = 'y'
 504
 505 " delimitmate {{{2
 506 let delimitMate_expand_cr = 2
 507 let g:delimitMate_expand_space = 1
 508
 509 " fswitch {{{2
 510 nnoremap <silent> <Leader>ff :FSHere<CR>
 511 nnoremap <silent> <Leader>fl :FSRight<CR>
 512 nnoremap <silent> <Leader>fh :FSLeft<CR>
 513 nnoremap <silent> <Leader>fj :FSBelow<CR>
 514 nnoremap <silent> <Leader>fk :FSAbove<CR>
 515 nnoremap <silent> <Leader>fL :FSSplitRight<CR>
 516 nnoremap <silent> <Leader>fH :FSSplitLeft<CR>
 517 nnoremap <silent> <Leader>fJ :FSSplitBelow<CR>
 518 nnoremap <silent> <Leader>fK :FSSplitAbove<CR>
 519
 520 " fugitive {{{2
 521 nmap <silent> <leader>dd :tab split \| Gdiff \| wincmd h<CR>
 522 " delete fugitive buffers when closed
 523 autocmd BufReadPost fugitive://* set bufhidden=delete
 524
 525 nnoremap <silent> <leader>gs :Gstatus<CR>
 526 nnoremap <silent> <leader>gd :Gdiff<CR>
 527 nnoremap <silent> <leader>gc :Gcommit -v<CR>
 528 nnoremap <silent> <leader>ga :Gwrite<cr>
 529 nnoremap <silent> <leader>gb :Gblame<cr>
 530
 531 " Gundo {{{2
 532 nnoremap <F7> :GundoToggle<CR>
 533
 534 " indent-guides {{{2
 535 let g:indent_guides_default_mapping = 0
 536 let g:indent_guides_guide_size = 1
 537 nmap <silent> cog <Plug>IndentGuidesToggle
 538 nmap <silent> [og <Plug>IndentGuidesEnable
 539 nmap <silent> ]og <Plug>IndentGuidesDisable
 540
 541 " python-mode {{{2
 542
 543 let g:pymode_rope_completion = 0
 544 let g:pymode_rope = 0
 545 let g:pymode_folding = 1
 546 let g:pymode_lint_ignore = "E221,E266,E501"
 547 let g:pymode_syntax_space_errors = 0    " don't bother me when I'm typing
 548
 549 " synastic {{{2
 550 let g:syntastic_enable_highlighting = 0
 551 let g:syntastic_error_symbol='E'
 552 let g:syntastic_style_error_symbol='S'
 553 let g:syntastic_warning_symbol='W'
 554 let g:syntastic_style_warning_symbol='S'
 555 let g:syntastic_always_populate_loc_list=1
 556 nmap <silent> <leader>y :SyntasticCheck<cr>
 557
 558 if ! &diff
 559   let g:syntastic_check_on_open=1
 560 endif
 561
 562 " tagbar {{{2
 563 map <F5> :TagbarToggle<cr>
 564 let g:tagbar_sort = 0
 565 let g:tagbar_compact = 1
 566 let g:tagbar_autoshowtag = 1
 567 let g:tagbar_width = 25
 568 let g:tagbar_iconchars = ['+', '-']
 569
 570 " ultisnips {{{2
 571 let g:UltiSnipsEditSplit = 'vertical'
 572 let g:UltiSnipsSnippetsDir = expand("$XDG_CONFIG_HOME/vim/ultisnips")
 573 if has('fname_case')
 574   let g:UltiSnipsSnippetDirectories = ["UltiSnips", "ultisnips"]
 575 endif
 576 let g:UltiSnipsExpandTrigger       = "<tab>"
 577 let g:UltiSnipsJumpForwardTrigger  = "<tab>"
 578 let g:UltiSnipsJumpBackwardTrigger = "<s-tab>"
 579
 580 " UltiSnips completion function that tries to expand a snippet. If there's no
 581 " snippet for expanding, it checks for completion window and if it's shown,
 582 " selects first element. If there's no completion window it tries to jump to
 583 " next placeholder. If there's no placeholder it just returns TAB key
 584 " https://github.com/Valloric/YouCompleteMe/issues/36#issuecomment-15451411
 585 function! g:UltiSnips_Complete()
 586     call UltiSnips#ExpandSnippet()
 587     if g:ulti_expand_res == 0
 588         if pumvisible()
 589             return "\<C-n>"
 590         else
 591             call UltiSnips#JumpForwards()
 592             if g:ulti_jump_forwards_res == 0
 593                return "\<TAB>"
 594             endif
 595         endif
 596     endif
 597     return ""
 598 endfunction
 599 au InsertEnter * exec "inoremap <silent> " . g:UltiSnipsExpandTrigger . " <C-R>=g:UltiSnips_Complete()<cr>"
 600 let g:UltiSnipsListSnippets="<c-e>"
 601
 602 " unite {{{2
 603 call unite#filters#matcher_default#use(['matcher_fuzzy'])
 604 call unite#custom#profile('default', 'context', {
 605             \ 'winheight': 20,
 606             \ 'direction': 'botright'
 607             \ })
 608
 609 nnoremap [unite] <Nop>
 610 nmap <leader>u [unite]
 611
 612 " unite-grep {{{3
 613 " seems not respected
 614 let g:unite_source_grep_max_candidates = 2000
 615 if executable('ag')
 616     " Use ag in unite grep source.
 617     let g:unite_source_grep_command = 'ag'
 618     let g:unite_source_grep_default_opts = '--smart-case -w --vimgrep --hidden --ignore ''.hg'' --ignore ''.svn'' --ignore ''.git'' --ignore ''.bzr'''
 619     let g:unite_source_grep_recursive_opt = ''
 620 end
 621 nnoremap <silent> [unite]a :<C-u>Unite grep:.::\12\17<CR>
 622 command! -nargs=1 Ag Unite grep -input=<args>
 623
 624 " unite-file_rec {{{3
 625 if executable('ag')
 626     " Use ag in unite rec source
 627     let g:unite_source_rec_async_command = 'ag --follow --nocolor --nogroup --hidden -g ""'
 628 end
 629 nnoremap <silent> [unite]f :<C-u>Unite -start-insert file_rec/async<CR>
 630
 631 " unite-buffer {{{3
 632 call unite#custom#default_action('buffer', 'goto')
 633 nnoremap <silent> [unite]b :<C-u>Unite buffer<CR>
 634
 635 " unite-menu {{{3
 636 let g:unite_source_menu_menus = {}
 637 let g:unite_source_menu_menus.fugitive = { 'description' : 'fugitive menu'}
 638 let g:unite_source_menu_menus.fugitive.command_candidates = {
 639             \ 'Gstatus <Leader>gs' : 'Gstatus',
 640             \ 'Gcommit -v <Leader>gc' : 'Gcommit -v',
 641             \ 'Glog' : 'Glog',
 642             \}
 643
 644 nnoremap <silent> <leader>gg :<C-u>Unite menu:fugitive<CR>
 645
 646 let g:unite_source_history_yank_enable = 1
 647 nnoremap <silent> [unite]p :<C-u>Unite history/yank<CR>
 648
 649 " yankring {{{2
 650 nnoremap <silent> <leader>p :YRShow<cr>
 651 let g:yankring_history_dir = expand('$XDG_CACHE_HOME/vim')
 652 let g:yankring_replace_n_pkey = ''
 653 let g:yankring_replace_n_nkey = ''
 654
 655 " map Y to y$ for the yank ring
 656 function! YRRunAfterMaps()
 657     nnoremap Y   :<C-U>YRYankCount 'y$'<CR>
 658 endfunction
 659
 660 " youcompleteme {{{2
 661 let g:ycm_extra_conf_globlist = ['~/src/*','/mnt/data/src/*']
 662 let g:ycm_global_ycm_extra_conf = expand('$XDG_CONFIG_HOME/vim/ycm_extra_conf.py')
 663 let g:ycm_extra_conf_vim_data = ['getcwd()']
 664 let g:ycm_add_preview_to_completeopt = 1
 665 let g:ycm_complete_in_comments = 1
 666 let g:ycm_complete_in_strings  = 1
 667 let g:ycm_autoclose_preview_window_after_insertion = 0
 668 "let g:ycm_extra_conf_vim_data = ['%:p']
 669 nnoremap gd :YcmCompleter GoTo<CR>
 670
 671 " vim-easy-align {{{2
 672 " start interactive EasyAlign in visual mode
 673 vmap <Enter> <Plug>(EasyAlign)
 674 nmap ga <Plug>(EasyAlign)
 675
 676 " vim-json {{{2
 677 let g:vim_json_syntax_conceal = 0
 678
 679 " vim-latex {{{2
 680 let g:tex_flavor='latex'
 681 let g:Tex_DefaultTargetFormat='pdf'
 682 let g:Tex_MultipleCompileFormats='pdf'
 683
 684 " vim-sneak {{{2
 685 let g:sneak#streak = 1
 686 let g:sneak#target_labels = "aoeuisnthdpylrcgfqjkxzmwvz" " dvorak
 687 let g:sneak#use_ic_scs = 1  " follow 'ignorecase' and 'smartcase'
 688
 689 " sneaky f and t
 690 nmap f <Plug>Sneak_f
 691 nmap F <Plug>Sneak_F
 692 xmap f <Plug>Sneak_f
 693 xmap F <Plug>Sneak_F
 694 omap f <Plug>Sneak_f
 695 omap F <Plug>Sneak_F
 696 nmap t <Plug>Sneak_t
 697 nmap T <Plug>Sneak_T
 698 xmap t <Plug>Sneak_t
 699 xmap T <Plug>Sneak_T
 700 omap t <Plug>Sneak_t
 701 omap T <Plug>Sneak_T
 702
 703 " functions {{{1
 704
 705 " Convenient command to see the difference between the current buffer and the
 706 " file it was loaded from, thus the changes you made.
 707 " Only define it when not defined already.
 708 if !exists(":DiffOrig")
 709   command DiffOrig vert new | set bt=nofile | r # | 0d_ | diffthis
 710                   \ | wincmd p | diffthis
 711 endif
 712
 713 " edit configs  {{{2
 714 function! EditConfig(what)
 715     let l:dir = split(&runtimepath,',')[0]
 716     if a:what == 'vimrc'
 717         let l:file = expand($MYVIMRC)
 718     elseif ! isdirectory(globpath(l:dir, a:what))
 719         echoe a:what." is not valid!"
 720     elseif empty(&filetype)
 721         echoe 'filetype is empty!'
 722     else
 723         let l:file = l:dir.'/'.a:what.'/'.&filetype.'.vim'
 724     endif
 725
 726     execute ':vsplit '.file
 727     execute ':lcd %:p:h'
 728 endf
 729 nmap <leader>ev :call EditConfig('vimrc')<CR>
 730 nmap <leader>ef :call EditConfig('ftplugin')<CR>
 731 nmap <leader>es :call EditConfig('syntax')<CR>
 732 nmap <leader>ei :call EditConfig('indent')<CR>
 733 nmap <leader>eu :UltiSnipsEdit<CR>:lcd %:p:h<CR>
 734
 735 " spell check {{{2
 736 " http://tex.stackexchange.com/a/52932
 737 let g:myLangList=["en_gb","en_us","de","fr"]
 738
 739 function! ToggleSpell()
 740   if !exists("b:myLang")
 741     let b:myLang=0
 742   endif
 743   execute "setlocal spell!"
 744   if (&spell)
 745     echo "setlocal spelllang=" g:myLangList[b:myLang]
 746   endif
 747 endfunction
 748
 749 function! SwitchSpell()
 750   if !exists("b:myLang")
 751     let b:myLang=0
 752   endif
 753   if (&spell)
 754     let b:myLang=b:myLang+1
 755     if b:myLang>=len(g:myLangList) | let b:myLang=0 | endif
 756   endif
 757   execute "setlocal spell spelllang=".get(g:myLangList, b:myLang)
 758   echo "setlocal spelllang=" g:myLangList[b:myLang]
 759 endfunction
 760
 761 nnoremap <silent> coS :call SwitchSpell()<CR>
 762 " fix spelling with first choice
 763 nnoremap <Leader>f 1z=
 764
 765 " gitdir or home {{{2
 766 " from derek wyatt:
 767 " http://git.io/v3GAV
 768 function! FindGitDirOrHome()
 769   let filedir = expand('%:p:h')
 770   if isdirectory(filedir)
 771     let cmd = 'bash -c "(cd ' . filedir . '; git rev-parse --show-toplevel 2>/dev/null)"'
 772     let gitdir = system(cmd)
 773     if strlen(gitdir) == 0
 774       return '~'
 775     else
 776       return gitdir[:-2]
 777     endif
 778   else
 779     return '~'
 780   endif
 781 endfunction
 782
 783 " vim:set et sw=2 ts=2 tw=78: