zsh/plugins/bundler/bundler.plugin.zsh

   1 alias be="bundle exec"
   2 alias bi="bundle install"
   3 alias bl="bundle list"
   4 alias bp="bundle package"
   5 alias bu="bundle update"
   6
   7 # The following is based on https://github.com/gma/bundler-exec
   8
   9 bundled_commands=(annotate cap capify cucumber foreman guard middleman nanoc rackup rainbows rake rspec ruby shotgun spec spork thin thor unicorn unicorn_rails puma zeus)
  10
  11 ## Functions
  12
  13 _bundler-installed() {
  14   which bundle > /dev/null 2>&1
  15 }
  16
  17 _within-bundled-project() {
  18   local check_dir=$PWD
  19   while [ $check_dir != "/" ]; do
  20     [ -f "$check_dir/Gemfile" ] && return
  21     check_dir="$(dirname $check_dir)"
  22   done
  23   false
  24 }
  25
  26 _run-with-bundler() {
  27   if _bundler-installed && _within-bundled-project; then
  28     bundle exec $@
  29   else
  30     $@
  31   fi
  32 }
  33
  34 ## Main program
  35 for cmd in $bundled_commands; do
  36   eval "function unbundled_$cmd () { $cmd \$@ }"
  37   eval "function bundled_$cmd () { _run-with-bundler $cmd \$@}"
  38   alias $cmd=bundled_$cmd
  39
  40   if which _$cmd > /dev/null 2>&1; then
  41         compdef _$cmd bundled_$cmd=$cmd
  42   fi
  43 done