vim/vimrc

   1 " force python3
   2 if has('python3') | endif
   3
   4 " space is leader
   5 let g:mapleader = " "
   6
   7 " runtimepath {{{1
   8 set runtimepath ^=$XDG_CONFIG_HOME/vim
   9 set runtimepath +=$XDG_CONFIG_HOME/vim/after
  10
  11 " plugins {{{1
  12 call plug#begin('$XDG_DATA_HOME/vim')
  13 " This does not update vim-plug, use PlugUpgrade instead
  14 Plug 'junegunn/vim-plug'
  15
  16 Plug 'airblade/vim-gitgutter' " {{{
  17 " prefer other signs such as ycm diags
  18 let g:gitgutter_sign_priority = 1
  19 " don't clobber other signs
  20 let g:gitgutter_sign_allow_clobber = 0
  21 "}}}
  22 Plug 'alepez/vim-gtest'
  23 Plug 'alx741/vinfo'
  24 Plug 'andrewradev/sideways.vim' " {{{2
  25 nnoremap <silent> ,h :SidewaysLeft<CR>:delmarks z<CR>
  26 nnoremap <silent> ,l :SidewaysRight<CR>:delmarks z<CR>
  27 "}}}
  28 Plug 'andrewradev/switch.vim'
  29 if !has('nvim')
  30   Plug 'bling/vim-airline' "{{{2
  31   let g:airline#extensions#whitespace#enabled = 1
  32   let g:airline#extensions#tabline#enabled = 1
  33   let g:airline#extensions#searchcount#enabled = 0
  34   let g:airline_powerline_fonts = 1
  35
  36   let g:asyncrun_status = "stopped"
  37   " let g:airline_section_error = airline#section#create_right(['%{g:asyncrun_status}'])
  38   "}}}
  39 endif
  40
  41 Plug 'chrisbra/checkattach'
  42 Plug 'derekwyatt/vim-fswitch'
  43 Plug 'elzr/vim-json'
  44 Plug 'firef0x/pkgbuild.vim'
  45 Plug 'junegunn/vim-easy-align'
  46 Plug 'justinmk/vim-sneak'
  47 Plug 'klen/python-mode'
  48 Plug 'kshenoy/vim-signature'
  49 Plug 'majutsushi/tagbar'
  50 Plug 'octol/vim-cpp-enhanced-highlight'
  51 if !has('nvim')
  52   Plug 'raimondi/delimitmate' " {{{2
  53   let delimitMate_expand_cr = 2
  54   let g:delimitMate_expand_space = 1
  55   "}}}
  56 end
  57 Plug 'sgeb/vim-diff-fold'
  58 Plug 'skywind3000/asyncrun.vim' " {{{2
  59 command! -bang -nargs=* -complete=file Make AsyncRun -save=2 -program=make @ <args>
  60 let g:asyncrun_open = 10
  61 "}}}
  62 Plug 'shougo/unite.vim'
  63 Plug 'shougo/vimproc.vim', {'do': 'make'}
  64 Plug 'sjl/gundo.vim'
  65 Plug 'thinca/vim-qfreplace'
  66 Plug 'tomtom/tcomment_vim'
  67 Plug 'tpope/vim-abolish'
  68 Plug 'tpope/vim-characterize'
  69 Plug 'tpope/vim-endwise'
  70 Plug 'tpope/vim-eunuch'
  71 Plug 'tpope/vim-fugitive'
  72 Plug 'tpope/vim-repeat'
  73 Plug 'tpope/vim-scriptease'
  74 Plug 'tpope/vim-speeddating'
  75 if !has('nvim')
  76   Plug 'tpope/vim-surround'  "investigate vim-sandwich
  77 endif
  78 Plug 'tpope/vim-unimpaired'
  79 Plug 'tweekmonster/spellrotate.vim'
  80 if !has("nvim")
  81   " Plug 'valloric/youcompleteme' {{{2
  82   Plug 'valloric/youcompleteme',
  83         \{ 'do': './install.py --clangd-completer --clang-completer' }
  84   let g:ycm_clangd_binary_path = 'clangd'   " use clangd in path
  85   let g:ycm_clangd_args = ['--clang-tidy']
  86   let g:ycm_extra_conf_vim_data = ['getcwd()']
  87   let g:ycm_add_preview_to_completeopt = 1
  88   let g:ycm_complete_in_comments = 1
  89   let g:ycm_complete_in_strings  = 1
  90   let g:ycm_autoclose_preview_window_after_insertion = 0
  91
  92   let g:ycm_language_server =
  93         \ [
  94         \   {
  95         \     'name': 'haskell',
  96         \     'cmdline': [ 'haskell-language-server-wrapper', '--lsp' ],
  97         \     'filetypes': [ 'haskell', 'lhaskell'  ]
  98         \   },
  99         \ ]
 100   " }}}
 101 endif
 102 Plug 'vim-scripts/mediawiki.vim'
 103 Plug 'vim-scripts/replacewithregister'
 104 if !has('nvim')
 105   Plug 'svermeulen/vim-yoink'
 106 end
 107 Plug 'wincent/loupe'
 108
 109 " colorschemes
 110 Plug 'morhetz/gruvbox' " {{{2
 111 let g:gruvbox_contrast_dark  = 'hard'
 112 let g:gruvbox_contrast_light = 'soft'
 113
 114 if !has('nvim')
 115   Plug 'arcticicestudio/nord-vim' " {{{2
 116   let g:nord_bold = 1
 117   let g:nord_italic = 1
 118   let g:nord_italic_comments = 1
 119   let g:nord_underline = 1
 120   let g:nord_uniform_status_lines = 0
 121   let g:nord_uniform_diff_background = 0
 122   let g:nord_cursor_line_number_background = 0
 123   let g:nord_bold_vertical_split_line = 0
 124 endif
 125
 126 "}}}
 127
 128 if !has("nvim")
 129   Plug 'sirver/ultisnips' " {{{
 130   Plug 'honza/vim-snippets'
 131
 132   let g:UltiSnipsEditSplit = 'vertical'
 133   let g:UltiSnipsSnippetDirectories = [ expand("$XDG_CONFIG_HOME/vim/ultisnips") ]
 134   if has('fname_case')
 135     let g:UltiSnipsSnippetDirectories = ["UltiSnips", "ultisnips"]
 136   endif
 137   let g:UltiSnipsExpandTrigger       = "<tab>"
 138   let g:UltiSnipsJumpForwardTrigger  = "<tab>"
 139   let g:UltiSnipsJumpBackwardTrigger = "<s-tab>"
 140
 141   " UltiSnips completion function that tries to expand a snippet. If there's no
 142   " snippet for expanding, it checks for completion window and if it's shown,
 143   " selects first element. If there's no completion window it tries to jump to
 144   " next placeholder. If there's no placeholder it just returns TAB key
 145   " https://github.com/Valloric/YouCompleteMe/issues/36#issuecomment-15451411
 146   function! g:UltiSnips_Complete()
 147       call UltiSnips#ExpandSnippet()
 148       if g:ulti_expand_res == 0
 149           if pumvisible()
 150               return "\<C-n>"
 151           else
 152               call UltiSnips#JumpForwards()
 153               if g:ulti_jump_forwards_res == 0
 154                  return "\<TAB>"
 155               endif
 156           endif
 157       endif
 158       return ""
 159   endfunction
 160   au InsertEnter * exec "inoremap <silent> " . g:UltiSnipsExpandTrigger . " <C-R>=g:UltiSnips_Complete()<cr>"
 161   let g:UltiSnipsListSnippets="<c-e>"
 162 "}}}
 163 endif
 164
 165 " text objects
 166 Plug 'kana/vim-textobj-user'
 167 Plug 'julian/vim-textobj-variable-segment'
 168 Plug 'sgur/vim-textobj-parameter'
 169 Plug 'kana/vim-operator-user'
 170
 171 " staging
 172 " Check LucHermites plugins: https://github.com/LucHermitte/lh-cpp
 173 Plug 'imsnif/kdl.vim'
 174
 175 Plug 'puremourning/vimspector'
 176 Plug 'ilyachur/cmake4vim'
 177 Plug 'ilyachur/gtest-vim'
 178
 179 Plug 'junegunn/vim-peekaboo' "{{{2
 180 " issue with having it at the bottom is that it doesn't leave much
 181 let g:peekaboo_window = 'bo 16new'
 182 let g:peekaboo_compact = 1
 183 let g:peekaboo_delay = 500
 184 "}}}
 185
 186 Plug 'vim-scripts/syntaxrange'
 187
 188 let g:org_agenda_files = ['~/org/**.org']
 189
 190 Plug 'vim-scripts/ansiesc.vim' "{{{2
 191 nmap corwp <Plug>RestoreWinPosn
 192 nmap coswp <Plug>SaveWinPosn
 193 "}}}
 194
 195 Plug 'neovimhaskell/haskell-vim'  " {{{2
 196 let g:haskell_enable_quantification = 1   " to enable highlighting of `forall`
 197 let g:haskell_enable_recursivedo = 1      " to enable highlighting of `mdo` and `rec`
 198 let g:haskell_enable_arrowsyntax = 1      " to enable highlighting of `proc`
 199 let g:haskell_enable_pattern_synonyms = 1 " to enable highlighting of `pattern`
 200 let g:haskell_enable_typeroles = 1        " to enable highlighting of type roles
 201 let g:haskell_enable_static_pointers = 1  " to enable highlighting of `static`
 202 let g:haskell_backpack = 1                " to enable highlighting of backpack keywords
 203
 204 let g:haskell_indent_before_where = 2
 205 " }}}
 206
 207 Plug 'aklt/plantuml-syntax'
 208
 209 Plug 'mtth/scratch.vim'  " {{{2
 210   let g:scratch_no_mappings = 1
 211   let g:scratch_autohide = 0
 212 "}}}
 213
 214 let g:man_hardwrap = 80
 215 if !has('nvim')
 216   Plug 'vim-utils/vim-man'  " {{{2
 217   let g:man_width = 80
 218 "}}}
 219 endif
 220
 221 Plug 'jenterkin/vim-autosource'  " {{{2
 222   let g:autosource_hashdir = $XDG_CACHE_HOME . '/vim/vim-autosource'
 223   let g:autosource_conf_names = ['.vimrc', '.vimrc.lua']
 224 "}}}
 225 call plug#end()
 226
 227 filetype plugin indent on
 228 syntax on
 229
 230 " colorscheme {{{1
 231 set background=dark
 232 let &t_8f = "\<Esc>[38;2;%lu;%lu;%lum"
 233 let &t_8b = "\<Esc>[48;2;%lu;%lu;%lum"
 234 set termguicolors
 235 if !has('nvim')
 236   colorscheme $THEME
 237 endif
 238 "TODO see how I can integrate this into a theme that customises upstream Nord
 239 hi debugPC term=reverse ctermbg=8
 240
 241 " options {{{1
 242 " moving around, searching and patterns {{{2
 243 set incsearch           " show match for partly typed search command
 244 set ignorecase          " ignore case when using a search pattern
 245 set smartcase           " override 'ignorecase' when pattern has upper case characters
 246 set hlsearch            " highlight all matches for the last used search pattern
 247
 248 set nostartofline       " don't move the cursor to the first non-blank char of a line
 249 set path+=.
 250 set path+=include/
 251 set path+=../include/
 252 set path+=/usr/include/c++/*
 253
 254 " displaying text {{{2
 255 set nowrap                      " long lines wrap
 256 set linebreak                   " wrap long lines at a character in 'breakat'
 257 set showbreak=↪                 " show these chars for wrapped lines
 258 set breakindent                 " preserve indentation in wrapped text
 259
 260 set list                        " show chars defined in 'listchars'
 261 set listchars=tab:❭\            " list of strings used for list mode
 262 set listchars+=extends:❯,precedes:❮
 263 set listchars+=nbsp:␣
 264 " Only shown when not in insert mode
 265 set listchars+=trail:·
 266 augroup trailing
 267     au!
 268     au FileType qf setlocal listchars-=trail:·
 269     au InsertEnter * set listchars-=trail:·
 270     au InsertLeave * set listchars+=trail:·
 271 augroup END
 272
 273 set scrolloff=5                 " number of screen lines to show around the cursor
 274 set sidescroll=1                " number of collumns to scroll
 275 set sidescrolloff=1             " don't scroll over the listchars
 276 set display+=lastline           " display as much as possible of last line
 277
 278 set fillchars=diff:⣿,vert:│
 279
 280 set nonumber                    " show the line number for each line
 281 set norelativenumber            " show the relative line number for each line
 282
 283 " syntax, highlighting and spelling {{{2
 284 set synmaxcol=800               " don't highlight long lines
 285
 286 set dictionary=spell            " list of dictionary files for keyword completion
 287
 288 set colorcolumn=+1
 289
 290 " multiple windows {{{2
 291 set laststatus=2                " 0, 1 or 2; when to use a status line for the last window
 292
 293 set previewheight=20            " default height for the preview window
 294
 295 set hidden
 296
 297 " set splitbelow                  " a new window is put below of the current one
 298 set splitright                  " a new window is put right of the current one
 299
 300 " terminal {{{2
 301 set ttyfast
 302
 303 " using the mouse {{{2
 304 set mouse=rnv                   " list of flags for using the mouse
 305 if !has('nvim')
 306   set ttymouse=xterm              " type of mouse
 307 endif
 308
 309 " messages and info {{{2
 310 set showcmd         " Show (partial) command in status line.
 311 set ruler           " show the cursor position all the time
 312 set confirm         " Ask what to do when closing unsaved documents
 313 set shortmess=      " reset option
 314 set shortmess+=a    " all abbreviations
 315 set shortmess+=o    " overwrite file-written message
 316 set shortmess+=O    " file-read message overrides previous
 317 set shortmess+=t    " truncate file message at start
 318 set shortmess+=T    " truncate other messages in the middle
 319 set shortmess+=W    " don't give 'written' or '[w]' when writing a file
 320 set shortmess+=A    " ignore swapfile warning
 321 set shortmess+=I    " no splash screen
 322 set shortmess+=c    " don't give |ins-completion-menu| messages
 323
 324 " editing text {{{2
 325 set backspace=indent,eol,start  " allow backspacing over everything in insert mode
 326
 327 set showmatch                   " Show matching brackets.
 328
 329 set nojoinspaces                " don't use two spaces after '.' when joining a line
 330 set formatoptions+=j    " Delete comment leader when joining lines
 331 set formatoptions+=c    " Autowrap comments using textwidth
 332 set formatoptions+=r    " Insert comment leader after hitting <Enter>
 333 set formatoptions+=n    " Recognize numbered lists
 334 set formatoptions+=q    " Allow formatting of comments with "gq".
 335 set formatoptions+=l    " do not wrap lines that have been longer when starting insert mode already
 336 set formatoptions+=t    " Auto-wrap text using textwidth
 337 set formatoptions-=o    " Do not insert comment leader after hitting o or O in normal mode
 338
 339 set nrformats-=octal    " don't inc/dec octal numbers with ^[AX]
 340 set nrformats+=unsigned " treat all numbers as unsigned
 341
 342 set complete=.       " scan the current buffer ( 'wrapscan' is ignored)
 343 set complete+=w      " scan buffers from other windows
 344 set complete+=b      " scan other loaded buffers that are in the buffer list
 345 set complete+=u      " scan the unloaded buffers that are in the buffer list
 346 set complete+=t      " scan tags
 347 set complete+=i      " scan current and included files
 348 set complete+=kspell " use the currently active spell checking |spell|
 349
 350 " whether to use a popup menu for Insert mode completion
 351 set completeopt=longest,menuone,preview
 352
 353 " tabs and indent {{{2
 354 set shiftwidth=4                " number of spaces used for each step of (auto)indent
 355 set smarttab                    " a <Tab> in an indent inserts 'shiftwidth' spaces
 356 set softtabstop=4               " if non-zero, number of spaces to insert for a <Tab>
 357 set shiftround                  " round to 'shiftwidth' for "<<" and ">>"
 358 set expandtab                   " expand <Tab> to spaces in Insert mode
 359 set autoindent
 360
 361 set pastetoggle=<F11>           " key sequence to toggle paste mode
 362
 363 " folding {{{2
 364 set foldmethod=marker           " folding type
 365 set foldlevelstart=0            " value for 'foldlevel' when starting to edit a file
 366
 367 " open folds when jumping to line
 368 set foldopen+=jump
 369
 370 set viewoptions=cursor          " save cursor position
 371 set viewoptions+=folds          " save folds
 372
 373 " diff mode {{{2
 374 set diffopt+=filler         " show filler lines
 375 set diffopt+=vertical       " always vertical split
 376 set diffopt+=context:10     " 10 lines context between changes
 377 set diffopt+=internal
 378 set diffopt+=algorithm:patience
 379
 380 " reading and writing files {{{2
 381 set modeline                    " read modelines
 382 set modelines=2                 " only check first/last 2 lines
 383
 384 set writebackup                 " write a backup file before overwriting a file
 385 set backup                      " keep a backup after owerwriting a file
 386 set backupdir=$XDG_CACHE_HOME/vim/backup//
 387
 388 set backupskip+=.netrc          " skip netrc
 389 set backupskip+=/dev/shm/pass*  " skip passwordstore files
 390
 391 set undofile                    " persistent undo history
 392 set undolevels=10000            " moar undos
 393 if !has('nvim')
 394   set undodir=$XDG_CACHE_HOME/vim/undo//
 395 endif
 396
 397 augroup undoskip
 398     au!
 399     au BufWritePre .netrc         setlocal noundofile
 400     au BufWritePre /dev/shm/pass* setlocal noundofile
 401     au BufWritePre /tmp/*         setlocal noundofile
 402 augroup END
 403
 404 set autowrite                   " automatically write a file when leaving a modified buffer
 405 set autoread                    " automatically read a file that has been modified
 406
 407 " the swap file {{{2
 408 set noswapfile
 409 set directory=$XDG_CACHE_HOME/vim/swap//
 410
 411 " command line editing {{{2
 412 set history=5000                " how many command lines are remembered
 413 set wildmenu                    " command-line completion shows a list of matches
 414 set wildmode=longest:full,full  " specifies how command line completion works
 415 set wildignorecase              " ignore case when completing file names
 416
 417 set wildignore+=.hg,.git,.svn                    " Version control
 418 set wildignore+=*.aux,*.out,*.toc                " LaTeX intermediate files
 419 set wildignore+=*.jpg,*.bmp,*.gif,*.png,*.jpeg   " binary images
 420 set wildignore+=*.o,*.obj,*.exe,*.dll,*.manifest " compiled object files
 421 set wildignore+=*.spl                            " compiled spelling word lists
 422 set wildignore+=*.sw?                            " Vim swap files
 423 set wildignore+=*.luac                           " Lua byte code
 424 set wildignore+=*.pyc                            " Python byte code
 425 set wildignore+=*.orig                           " Merge resolution files
 426
 427 " running make and jumping to errors {{{2
 428 set makeprg=make\ -w     " print changing directories
 429
 430 set grepformat=%f:%l:%c:%m
 431 set grepprg=ag\ --vimgrep\ $*
 432
 433 " language specific {{{2
 434 set isfname-==    " don't treat `=` as being part of filenames
 435
 436 " various {{{2
 437 set virtualedit+=block     " let cursor move past last char in <C-V> mode
 438 set virtualedit+=onemore   " allow the cursor to move just past the end of the line
 439 if !has('nvim')
 440   " viminfo defaults but save file in .cache
 441   set viminfo='100,<50,s10,h,n$XDG_CACHE_HOME/vim/viminfo
 442 else
 443   " shada is the replacement format for viminfo
 444   " this setting is probably not needed as it's most likely the default
 445   " the default path is in XDG_DATA_HOME, which is fine
 446   set shada='100,<50,s10,h
 447 endif
 448
 449 set viewdir=$XDG_CACHE_HOME/vim/view//
 450
 451 set sessionoptions+=unix,slash  " damn windows and it's silly ways
 452
 453 " autocmds {{{1
 454 " Resize splits when the window is resized {{{2
 455 augroup resize_splits
 456     au!
 457     autocmd VimResized * :tabdo wincmd =
 458 augroup END
 459
 460 " Only show cursorline in the current window and in normal mode {{{2
 461 augroup cline
 462     au!
 463     au WinLeave,InsertEnter * set nocursorline
 464     au WinEnter,InsertLeave * set cursorline
 465 augroup END
 466
 467 " Treat buffers from stdin (e.g.: echo foo | vim -) as scratch {{{2
 468 augroup ft_stdin
 469     au!
 470     au StdinReadPost * :set buftype=nofile
 471 augroup END
 472
 473 " Jump to last known cursor position {{{2
 474 augroup last_loc
 475     au!
 476     " blacklist certain filetype
 477     let blacklist = ['gitcommit']
 478     autocmd BufReadPost *
 479                 \ if index(blacklist, &ft) < 0 && line("'\"") > 1 && line("'\"") <= line("$") |
 480                 \   exe "normal! g`\"" |
 481                 \ endif
 482 augroup END
 483
 484 " Check for file modifications automatically {{{2
 485 " (current buffer only)
 486 " Use :NoAutoChecktime to disable it (uses b:autochecktime)
 487 fun! MyAutoCheckTime()
 488   " only check timestamp for normal files
 489   if &buftype != '' | return | endif
 490   if ! exists('b:autochecktime') || b:autochecktime
 491     checktime %
 492     let b:autochecktime = 1
 493   endif
 494 endfun
 495 augroup MyAutoChecktime
 496   au!
 497   au FocusGained,BufEnter,CursorHold,InsertEnter * call MyAutoCheckTime()
 498 augroup END
 499 command! NoAutoChecktime let b:autochecktime=0
 500 command! ToggleAutoChecktime let b:autochecktime=!get(b:, 'autochecktime', 0) | echom "b:autochecktime:" b:autochecktime
 501
 502 " bindings {{{1
 503
 504 " make
 505 function! MakeWithOpt()
 506   " TODO only do this if makeprg matches make
 507   " if &makeprg =~ "make"
 508   let l:make_dir = ""
 509   if exists("b:make_dir")
 510     let l:make_dir = "-C ".b:make_dir
 511   elseif exists("t:make_dir")
 512     let l:make_dir = "-C ".t:make_dir
 513   elseif exists("g:make_dir")
 514     let l:make_dir = "-C ".g:make_dir
 515   endif
 516
 517   let l:make_targets = ""
 518   if exists("g:make_targets")
 519     let l:make_targets = g:make_targets
 520   endif
 521   execute "Make ".l:make_dir." ".l:make_targets
 522 endf
 523 nnoremap <silent> <leader>r :call MakeWithOpt()<cr>
 524
 525 " unhighlight search
 526 nnoremap <silent> <Leader>/ :silent nohl<CR>
 527
 528 " Tabs
 529 nnoremap <leader>[ :tabprev<cr>
 530 nnoremap <leader>] :tabnext<cr>
 531
 532 " paste from selection
 533 nnoremap <leader>p* :silent! set paste<CR>"*p:set nopaste<CR>
 534 " paste from clipboard
 535 nnoremap <leader>p+ :silent! set paste<CR>"+p:set nopaste<CR>
 536
 537 " strip trailing whitespace
 538 function! StripWhitespace(line1, line2, ...)  " {{{2
 539   let s_report = &report
 540   let &report=0
 541   let pattern = a:0 ? a:1 : '\s\+$'
 542   let oldview = winsaveview()
 543   exe 'keepjumps keeppatterns '.a:line1.','.a:line2.'substitute/'.pattern.'//e'
 544   if oldview != winsaveview()
 545     redraw
 546   endif
 547   call winrestview(oldview)
 548   let &report = s_report
 549 endfunction  " }}}2
 550 command! -range=% -nargs=0 -bar Untrail keepjumps call StripWhitespace(<line1>,<line2>)
 551 nnoremap <silent> <leader>ww :Untrail<CR>
 552
 553 " Source
 554 vnoremap <leader>S y:execute @@<cr>:echo 'Sourced selection.'<cr>
 555 nnoremap <leader>S ^vg_y:execute @@<cr>:echo 'Sourced line.'<cr>
 556
 557 " jump to last cursor position
 558 noremap ' `
 559
 560 " Select (charwise) the contents of the current line, excluding indentation.
 561 nnoremap vv ^vg_
 562
 563 " Unfuck my screen
 564 nnoremap U
 565       \ :syntax sync fromstart<cr>
 566       \ :AirlineRefresh<cr>
 567       \ :call popup_clear(1)<cr>
 568       \ :redraw!<cr>
 569
 570 " Ranger
 571 " nnoremap <leader>r :silent !ranger %:h<cr>:redraw!<cr>
 572 " nnoremap <leader>R :silent !ranger<cr>:redraw!<cr>
 573
 574 " Use sane regexes.
 575 nnoremap / /\v
 576 vnoremap / /\v
 577 cnoremap s/ s/\v
 578
 579 " display the number of matches for the last search
 580 nmap <Leader># :%s:<C-R>/::gn<CR>
 581
 582 " center cursor after search and open folds
 583 nnoremap n nzzzv
 584 nnoremap N Nzzzv
 585
 586 " same when jumping around
 587 nnoremap g; g;zzzv
 588 nnoremap g, g,zzzv
 589 nnoremap <c-o> <c-o>zzzv
 590 nnoremap <c-i> <c-i>zzzv
 591
 592 " Not using the default mappings of 'To line from top/bottom'
 593 noremap H ^
 594 noremap L $
 595 vnoremap H ^
 596 vnoremap L g_
 597
 598 " Heresy, emacs insert bindings
 599 inoremap <C-A> <Esc>I
 600 inoremap <C-E> <Esc>A
 601 cnoremap <C-A> <Home>
 602 cnoremap <C-E> <End>
 603
 604 " proper movement when lines are wrapped
 605 noremap <silent><expr> j (v:count == 0 ? 'gj' : 'j')
 606 noremap <silent><expr> k (v:count == 0 ? 'gk' : 'k')
 607
 608 " disable arrows
 609 noremap  <Up>    <NOP>
 610 noremap  <Down>  <NOP>
 611 noremap  <Left>  <NOP>
 612 noremap  <Right> <NOP>
 613 inoremap <Up>    <NOP>
 614 inoremap <Down>  <NOP>
 615 inoremap <Left>  <NOP>
 616 inoremap <Right> <NOP>
 617 cnoremap <Up>    <NOP>
 618 cnoremap <Down>  <NOP>
 619 cnoremap <Left>  <NOP>
 620 cnoremap <Right> <NOP>
 621 cnoremap <C-K>   <Up>
 622 cnoremap <C-J>   <Down>
 623 cnoremap <C-H>   <Left>
 624 cnoremap <C-L>   <Right>
 625
 626 " close all folds open fold in cursor
 627 nnoremap zx zMzxzt
 628
 629 map <F1> :ls<CR>:b<space>
 630
 631 " move between windows (skip previewwindow)
 632 nnoremap <silent> <C-L> <C-W>w<C-W>:if &previewwindow \| wincmd w \| endif<CR>
 633 nnoremap <silent> <C-H> <C-W>W<C-W>:if &previewwindow \| wincmd W \| endif<CR>
 634 tnoremap <silent> <C-L> <C-W>w<C-W>:if &previewwindow \| wincmd w \| endif<CR>
 635 tnoremap <silent> <C-H> <C-W>W<C-W>:if &previewwindow \| wincmd W \| endif<CR>
 636
 637 "xterm mouse with middleclick paste
 638 nnoremap <MiddleMouse> i<MiddleMouse>
 639 vnoremap <MiddleMouse> s<MiddleMouse>
 640
 641 " fix legacy vi inconsistency
 642 nnoremap Y y$
 643 " copy to clipboard
 644 xnoremap Y "+y
 645
 646 " allow repeat operator on visual
 647 vnoremap . :normal .<CR>
 648
 649 " add line without changing position or leaving mode
 650 noremap <silent> <Leader>o :set paste<CR>m`o<ESC>``:set nopaste<CR>
 651 noremap <silent> <Leader>O :set paste<CR>m`O<ESC>``:set nopaste<CR>
 652
 653 " Don't use Ex mode, use Q for formatting
 654 map Q gq
 655
 656 " break undo sequence before removing word
 657 inoremap <C-W> <C-G>u<C-W>
 658
 659 nnoremap coe :set <C-R>=&expandtab ? 'noexpandtab' : 'expandtab'<CR><CR>
 660 nnoremap [oe :set expandtab<CR>
 661 nnoremap ]oe :set noexpandtab<CR>
 662
 663 for idt in range(1,8)
 664   exe 'nnoremap co'.idt.' :setlocal tabstop='.idt.' shiftwidth='.idt.' softtabstop='.idt.'<CR>'
 665 endfor
 666
 667 " toggle auto format of text
 668 nnoremap coa :set <C-R>=&formatoptions =~ "a" ? 'formatoptions-=a' : 'formatoptions+=a'<CR><CR>
 669 nnoremap [oa :set formatoptions+=a<CR>
 670 nnoremap ]oa :set formatoptions-=a<CR>
 671
 672 " space will toggle current fold in normal mode
 673 nnoremap <leader><Space> za
 674 " create folds around visual selection
 675 vnoremap <leader><Space> zf
 676
 677 " save with sudo
 678 cabbrev w!! SudoWrite
 679
 680 " uppercase previous word
 681 inoremap <C-C> <Esc>gUiwgi
 682
 683 " http://git.io/v3ZeU
 684 nmap <silent> <leader>qq :echo "hi<" . synIDattr(synID(line("."),col("."),1),"name") . '> trans<' . synIDattr(synID(line("."),col("."),0),"name") . "> lo<" . synIDattr(synIDtrans(synID(line("."),col("."),1)),"name") . ">"<CR>
 685
 686 " plugins options {{{1
 687 " checkattach {{{2
 688 let g:checkattach_filebrowser = 'ranger'
 689 let g:checkattach_once = 'y'
 690
 691 " close-another-window {{{2
 692 nnoremap <silent> <C-W>c  <NOP>
 693 nnoremap <silent> <C-W>cc <C-W>c
 694 nnoremap <silent> <C-W>ch :CloseLeftWindow<CR>
 695 nnoremap <silent> <C-W>cl :CloseRightWindow<CR>
 696 nnoremap <silent> <C-W>cj :CloseBelowWindow<CR>
 697 nnoremap <silent> <C-W>ck :CloseAboveWindow<CR>
 698
 699
 700 " fswitch {{{2
 701 nnoremap <silent> <Leader>ff :FSHere<CR>
 702 nnoremap <silent> <Leader>fl :FSRight<CR>
 703 nnoremap <silent> <Leader>fh :FSLeft<CR>
 704 nnoremap <silent> <Leader>fj :FSBelow<CR>
 705 nnoremap <silent> <Leader>fk :FSAbove<CR>
 706 nnoremap <silent> <Leader>fL :FSSplitRight<CR>
 707 nnoremap <silent> <Leader>fH :FSSplitLeft<CR>
 708 nnoremap <silent> <Leader>fJ :FSSplitBelow<CR>
 709 nnoremap <silent> <Leader>fK :FSSplitAbove<CR>
 710
 711 " fugitive {{{2
 712 nmap <silent> <leader>dd :tab split \| Gdiff \| wincmd h<CR>
 713 " delete fugitive buffers when closed
 714 autocmd BufReadPost fugitive://* set bufhidden=delete
 715
 716 function! GitToggle()
 717   let l:status_buffer = bufname('^fugitive:///*/.git{/worktrees/*,}//$')
 718   if buflisted(l:status_buffer)
 719     execute 'bdelete '.l:status_buffer
 720   else
 721     execute 'Git'
 722     if !empty(FugitiveGitDir())
 723       " only resize status if Git was sucessful
 724       16wincmd_
 725     endif
 726   endif
 727 endfunction
 728 command! GitToggle :call GitToggle()
 729 command! GToggle GitToggle
 730 nnoremap <silent> <leader>gs :GitToggle<CR>
 731
 732 nnoremap <silent> <leader>gd :Gdiffsplit<CR>
 733 nnoremap <silent> <leader>gc :echohl WarningMsg \| echo "use \<leader>gcc instead" \| echohl None<CR>
 734 nnoremap <silent> <leader>gcc :tab G commit -v<CR>
 735 nnoremap <silent> <leader>gca :tab G commit -v --amend<CR>
 736 nnoremap          <leader>gcf :tab G commit -v --fixup=
 737 nnoremap <silent> <leader>gp :echohl WarningMsg \| echo "use \<leader>gpp instead" \| echohl None<CR>
 738 nnoremap <silent> <leader>gpp :Git push \| copen<CR>
 739 nnoremap <silent> <leader>gpf :Git push --force-with-lease \| copen<CR>
 740 nnoremap <silent> <leader>gll :Git pull<CR>
 741 nnoremap <silent> <leader>gru :Git rebase --interactive @{upstream}<CR>
 742 nnoremap <silent> <leader>grp :Git rebase --interactive @{push}<CR>
 743 nnoremap <silent> <leader>ga :Gwrite<cr>
 744 nnoremap <silent> <leader>gb :G blame<cr>
 745
 746 augroup fugitive_gstatus
 747     au!
 748     autocmd User FugitiveIndex setlocal winfixheight
 749     autocmd User FugitiveIndex nmap <buffer> <leader><space> =
 750 augroup end
 751
 752 " Gundo {{{2
 753 nnoremap <F7> :GundoToggle<CR>
 754 let g:gundo_prefer_python3 = 1
 755
 756 " indent-guides {{{2
 757 let g:indent_guides_default_mapping = 0
 758 let g:indent_guides_guide_size = 1
 759 nmap <silent> cog <Plug>IndentGuidesToggle
 760 nmap <silent> [og <Plug>IndentGuidesEnable
 761 nmap <silent> ]og <Plug>IndentGuidesDisable
 762
 763 " python-mode {{{2
 764
 765 let g:pymode_rope_completion = 0
 766 let g:pymode_rope = 0
 767 let g:pymode_run = 0
 768 let g:pymode_folding = 1
 769 let g:pymode_lint_ignore = "E221,E266,E501"
 770 let g:pymode_lint_cwindow = 0           " don't open cwindow when linting
 771 let g:pymode_syntax_space_errors = 0    " don't bother me when I'm typing
 772
 773 " signature {{{2
 774 " disable '[ mappings
 775
 776 let g:SignatureMap = {
 777   \ 'GotoNextLineAlpha'  :  "",
 778   \ 'GotoPrevLineAlpha'  :  "",
 779   \ 'GotoNextSpotAlpha'  :  "",
 780   \ 'GotoPrevSpotAlpha'  :  "",
 781   \ }
 782
 783 " switch
 784 let g:switch_mapping = "<Leader>s"
 785 let g:switch_custom_definitions = [
 786       \   ['yes', 'no']
 787       \ ]
 788
 789 " spellrotate
 790 nmap <silent> z] <Plug>(SpellRotateForward)
 791 nmap <silent> z[ <Plug>(SpellRotateBackward)
 792 vmap <silent> z] <Plug>(SpellRotateForwardV)
 793 vmap <silent> z[ <Plug>(SpellRotateBackwardV)
 794
 795 " synastic {{{2
 796 let g:syntastic_enable_highlighting = 0
 797 let g:syntastic_error_symbol='E'
 798 let g:syntastic_style_error_symbol='S'
 799 let g:syntastic_warning_symbol='W'
 800 let g:syntastic_style_warning_symbol='S'
 801 let g:syntastic_always_populate_loc_list=1
 802 nmap <silent> <leader>y :SyntasticCheck<cr>
 803
 804 let g:syntastic_cpp_clang_tidy_post_args = "-p build*"
 805
 806 if ! &diff
 807   let g:syntastic_check_on_open=1
 808 endif
 809
 810 " tagbar {{{2
 811 map <F5> :TagbarToggle<cr>
 812 let g:tagbar_sort = 0
 813 let g:tagbar_compact = 1
 814 let g:tagbar_autoshowtag = 1
 815 let g:tagbar_width = 25
 816 let g:tagbar_iconchars = ['+', '-']
 817
 818 " tcomments {{{2
 819 let g:tcomment_textobject_inlinecomment = 'gic'
 820 let g:tcomment#filetype#guess = 0
 821 "let g:tcomment#options = {'whitespace' : 'no'}
 822
 823 " unite {{{2
 824 call unite#filters#matcher_default#use(['matcher_fuzzy'])
 825 call unite#custom#profile('default', 'context', {
 826             \ 'winheight': 20,
 827             \ 'direction': 'botright'
 828             \ })
 829
 830 nnoremap [unite] <Nop>
 831 nmap <leader>u [unite]
 832 nnoremap [unite]u :UniteResume<CR>
 833 nnoremap <silent> [u :UnitePrevious<CR>
 834 nnoremap <silent> ]u :UniteNext<CR>
 835
 836 " unite-grep {{{3
 837 " seems not respected
 838 let g:unite_source_grep_max_candidates = 2000
 839 if executable('ag')
 840     " Use ag in unite grep source.
 841     let g:unite_source_grep_command = 'ag'
 842     let g:unite_source_grep_default_opts = '--smart-case --vimgrep --ignore ''.hg'' --ignore ''.svn'' --ignore ''.git'' --ignore ''.bzr'''
 843     let g:unite_source_grep_recursive_opt = ''
 844 end
 845 nnoremap <silent> [unite]a :<C-u>Unite grep:.::\12\17<CR>
 846 nnoremap <silent> [unite]A :<C-u>Unite grep:.:-w:\12\17<CR>
 847 command! -nargs=+ Ag Unite grep:.::<args>
 848
 849 " unite-file_rec {{{3
 850 if executable('ag')
 851     " Use ag in unite rec source
 852     let g:unite_source_rec_async_command = ['ag', '--follow', '--nocolor', '--nogroup', '-g', '']
 853 end
 854 nnoremap <silent> [unite]f :<C-u>Unite -start-insert file_rec/async<CR>
 855 call unite#custom#source('file_rec/async', 'sorters', 'sorter_selecta')
 856
 857 " unite-buffer {{{3
 858 call unite#custom#default_action('buffer', 'open')
 859 nnoremap <silent> [unite]b :<C-u>Unite buffer:-<CR>
 860
 861 " unite-jumplist {{{3
 862 nnoremap <silent> [unite]j :<C-u>Unite output:jumps:<CR>
 863
 864 " unite-menu {{{3
 865 let g:unite_source_menu_menus = {}
 866 let g:unite_source_menu_menus.fugitive = { 'description' : 'fugitive menu'}
 867 let g:unite_source_menu_menus.fugitive.command_candidates = {
 868             \ 'Gstatus <Leader>gs' : 'Gstatus',
 869             \ 'Gcommit -v <Leader>gc' : 'Gcommit -v',
 870             \ 'Glog' : 'Glog',
 871             \}
 872
 873 nnoremap <silent> <leader>gg :<C-u>Unite menu:fugitive<CR>
 874
 875 let g:unite_source_history_yank_enable = 1
 876 nnoremap <silent> [unite]p :<C-u>Unite history/yank<CR>
 877
 878 " vim-easy-align {{{2
 879 " start interactive EasyAlign in visual mode
 880 vmap <Enter>   <Esc>:echohl WarningMsg \| echo "EasyAlign mapped to \16<leader>a now" \| echohl None<CR>
 881 vmap <leader>a <Plug>(EasyAlign)
 882 nmap <leader>a <Plug>(EasyAlign)
 883
 884 " vim-gtest {{{2
 885 let g:gtest#highlight_failing_tests = 0
 886
 887 nnoremap <silent> <Leader>tt :GTestRun<CR>
 888 nnoremap          <Leader>tc :GTestCase<space>
 889 nnoremap          <Leader>tn :GTestName<space>
 890 nnoremap <silent> <Leader>ta :GTestCase *<CR>:GTestName *<CR>:GTestRun<CR>
 891 nnoremap <silent> <Leader>tu :GTestRunUnderCursor<CR>
 892
 893 " vim-json {{{2
 894 let g:vim_json_syntax_conceal = 0
 895
 896 " vim-sneak {{{2
 897 let g:sneak#streak = 1
 898 let g:sneak#target_labels = "aoeuisnthdpylrcgfqjkxzmwvz" " dvorak
 899 let g:sneak#use_ic_scs = 1  " follow 'ignorecase' and 'smartcase'
 900
 901 " sneaky f and t
 902 nmap f <Plug>Sneak_f
 903 nmap F <Plug>Sneak_F
 904 xmap f <Plug>Sneak_f
 905 xmap F <Plug>Sneak_F
 906 omap f <Plug>Sneak_f
 907 omap F <Plug>Sneak_F
 908 nmap t <Plug>Sneak_t
 909 nmap T <Plug>Sneak_T
 910 xmap t <Plug>Sneak_t
 911 xmap T <Plug>Sneak_T
 912 omap t <Plug>Sneak_t
 913 omap T <Plug>Sneak_T
 914
 915 " functions {{{1
 916
 917 " Convenient command to see the difference between the current buffer and the
 918 " file it was loaded from, thus the changes you made.
 919 " Only define it when not defined already.
 920 if !exists(":DiffOrig")
 921   command DiffOrig vert new | set bt=nofile | r # | 0d_ | diffthis
 922                   \ | wincmd p | diffthis
 923 endif
 924
 925 " sort operator {{{2
 926 function! SortLinesOpFunc(...)
 927   '[,']sort
 928 endfunction
 929 nnoremap <silent> gs :<C-U>set operatorfunc=SortLinesOpFunc<CR>g@
 930 vnoremap <silent> gs :sort<cr>
 931
 932 " edit configs  {{{2
 933 function! EditConfig(what, ext = '.vim')
 934     let l:dir = split(&runtimepath,',')[0]
 935     if a:what == 'vimrc'
 936         let l:file = expand($MYVIMRC)
 937     elseif ! isdirectory(globpath(l:dir, a:what))
 938         echoe a:what." is not valid!"
 939     elseif empty(&filetype)
 940         echoe 'filetype is empty!'
 941     else
 942         let l:file = l:dir.'/'.a:what.'/'.&filetype.a:ext
 943     endif
 944
 945     execute ':vsplit '.file
 946     execute ':lcd %:p:h'
 947 endf
 948 nmap <leader>ev :call EditConfig('vimrc')<CR>
 949 nmap <leader>ef :call EditConfig('ftplugin')<CR>
 950 nmap <leader>es :call EditConfig('syntax')<CR>
 951 nmap <leader>ei :call EditConfig('indent')<CR>
 952 nmap <leader>eu :call EditConfig('ultisnips', '.snippets')<CR>
 953
 954 " spell check {{{2
 955 " http://tex.stackexchange.com/a/52932
 956 let g:myLangList=["en_gb","en_us","de","fr"]
 957
 958 function! ToggleSpell()
 959   if !exists("b:myLang")
 960     let b:myLang=0
 961   endif
 962   execute "setlocal spell!"
 963   if (&spell)
 964     echo "setlocal spelllang=" g:myLangList[b:myLang]
 965   endif
 966 endfunction
 967
 968 function! SwitchSpell()
 969   if !exists("b:myLang")
 970     let b:myLang=0
 971   endif
 972   if (&spell)
 973     let b:myLang=b:myLang+1
 974     if b:myLang>=len(g:myLangList) | let b:myLang=0 | endif
 975   endif
 976   execute "setlocal spell spelllang=".get(g:myLangList, b:myLang)
 977   echo "setlocal spelllang=" g:myLangList[b:myLang]
 978 endfunction
 979
 980 nnoremap <silent> coS :call SwitchSpell()<CR>
 981
 982 " gitdir or home {{{2
 983 " from derek wyatt:
 984 " http://git.io/v3GAV
 985 function! FindGitDirOrHome()
 986   let filedir = expand('%:p:h')
 987   if isdirectory(filedir)
 988     let cmd = 'bash -c "(cd ' . filedir . '; git rev-parse --show-toplevel 2>/dev/null)"'
 989     let gitdir = system(cmd)
 990     if strlen(gitdir) == 0
 991       return '~'
 992     else
 993       return gitdir[:-2]
 994     endif
 995   else
 996     return '~'
 997   endif
 998 endfunction
 999 command! Cd cd %:h
1000 command! Cdr execute('cd ' . FindGitDirOrHome())
1001 command! LCd lcd %:h
1002 command! LCdr execute('lcd ' . FindGitDirOrHome())
1003
1004 " vim:set et sw=2 ts=2 tw=78: