zsh/lib/termsupport.zsh

   1 #usage: title short_tab_title looooooooooooooooooooooggggggg_windows_title
   2 #http://www.faqs.org/docs/Linux-mini/Xterm-Title.html#ss3.1
   3 #Fully support screen, iterm, and probably most modern xterm and rxvt
   4 #Limited support for Apple Terminal (Terminal can't set window or tab separately)
   5 function title {
   6   if [[ "$DISABLE_AUTO_TITLE" == "true" ]] || [[ "$EMACS" == *term* ]]; then
   7     return
   8   fi
   9   if [[ "$TERM" == screen* ]]; then
  10     print -Pn "\ek$1:q\e\\" #set screen hardstatus, usually truncated at 20 chars
  11   elif [[ "$TERM" == xterm* ]] || [[ $TERM == rxvt* ]] || [[ "$TERM_PROGRAM" == "iTerm.app" ]]; then
  12     print -Pn "\e]2;$2:q\a" #set window name
  13     print -Pn "\e]1;$1:q\a" #set icon (=tab) name (will override window name on broken terminal)
  14   fi
  15 }
  16
  17 ZSH_THEME_TERM_TAB_TITLE_IDLE="%15<..<%~%<<" #15 char left truncated PWD
  18 ZSH_THEME_TERM_TITLE_IDLE="%n@%m: %~"
  19
  20 #Appears when you have the prompt
  21 function omz_termsupport_precmd {
  22   title $ZSH_THEME_TERM_TAB_TITLE_IDLE $ZSH_THEME_TERM_TITLE_IDLE
  23 }
  24
  25 #Appears at the beginning of (and during) of command execution
  26 function omz_termsupport_preexec {
  27   emulate -L zsh
  28   setopt extended_glob
  29   local CMD=${1[(wr)^(*=*|sudo|ssh|rake|-*)]} #cmd name only, or if this is sudo or ssh, the next cmd
  30   title "$CMD" "%100>...>${2:gs/%/%%}%<<"
  31 }
  32
  33 autoload -U add-zsh-hook
  34 add-zsh-hook precmd  omz_termsupport_precmd
  35 add-zsh-hook preexec omz_termsupport_preexec