zsh/plugins/extract/extract.plugin.zsh

   1 # ------------------------------------------------------------------------------
   2 #          FILE:  extract.plugin.zsh
   3 #   DESCRIPTION:  oh-my-zsh plugin file.
   4 #        AUTHOR:  Sorin Ionescu (sorin.ionescu@gmail.com)
   5 #       VERSION:  1.0.1
   6 # ------------------------------------------------------------------------------
   7
   8
   9 function extract() {
  10   local remove_archive
  11   local success
  12   local file_name
  13   local extract_dir
  14
  15   if (( $# == 0 )); then
  16     echo "Usage: extract [-option] [file ...]"
  17     echo
  18     echo Options:
  19     echo "    -r, --remove    Remove archive."
  20     echo
  21     echo "Report bugs to <sorin.ionescu@gmail.com>."
  22   fi
  23
  24   remove_archive=1
  25   if [[ "$1" == "-r" ]] || [[ "$1" == "--remove" ]]; then
  26     remove_archive=0
  27     shift
  28   fi
  29
  30   while (( $# > 0 )); do
  31     if [[ ! -f "$1" ]]; then
  32       echo "extract: '$1' is not a valid file" 1>&2
  33       shift
  34       continue
  35     fi
  36
  37     success=0
  38     file_name="$( basename "$1" )"
  39     extract_dir="$( echo "$file_name" | sed "s/\.${1##*.}//g" )"
  40     case "$1" in
  41       (*.tar.gz|*.tgz) tar xvzf "$1" ;;
  42       (*.tar.bz2|*.tbz|*.tbz2) tar xvjf "$1" ;;
  43       (*.tar.xz|*.txz) tar --xz --help &> /dev/null \
  44         && tar --xz -xvf "$1" \
  45         || xzcat "$1" | tar xvf - ;;
  46       (*.tar.zma|*.tlz) tar --lzma --help &> /dev/null \
  47         && tar --lzma -xvf "$1" \
  48         || lzcat "$1" | tar xvf - ;;
  49       (*.tar) tar xvf "$1" ;;
  50       (*.gz) gunzip "$1" ;;
  51       (*.bz2) bunzip2 "$1" ;;
  52       (*.xz) unxz "$1" ;;
  53       (*.lzma) unlzma "$1" ;;
  54       (*.Z) uncompress "$1" ;;
  55       (*.zip) unzip "$1" -d $extract_dir ;;
  56       (*.rar) unrar e -ad "$1" ;;
  57       (*.7z) 7za x "$1" ;;
  58       (*.deb)
  59         mkdir -p "$extract_dir/control"
  60         mkdir -p "$extract_dir/data"
  61         cd "$extract_dir"; ar vx "../${1}" > /dev/null
  62         cd control; tar xzvf ../control.tar.gz
  63         cd ../data; tar xzvf ../data.tar.gz
  64         cd ..; rm *.tar.gz debian-binary
  65         cd ..
  66       ;;
  67       (*)
  68         echo "extract: '$1' cannot be extracted" 1>&2
  69         success=1
  70       ;;
  71     esac
  72
  73     (( success = $success > 0 ? $success : $? ))
  74     (( $success == 0 )) && (( $remove_archive == 0 )) && rm "$1"
  75     shift
  76   done
  77 }
  78
  79 alias x=extract
  80