vim/vimrc

   1 " My vimrc.
   2 "
   3 " Author:   Samir Benmendil <samir.benmendil[at]gmail[dot]com>
   4 "
   5
   6 " runtimepath {{{1
   7 set runtimepath ^=$XDG_CONFIG_HOME/vim
   8 set runtimepath +=$XDG_CONFIG_HOME/vim/after
   9
  10 " force python3
  11 if has('python3') | endif
  12
  13 " plugins {{{1
  14 " remove all autocommands
  15 autocmd!
  16
  17 call plug#begin('$XDG_DATA_HOME/vim')
  18 " This does not update vim-plug, use PlugUpgrade instead
  19 Plug 'junegunn/vim-plug'
  20
  21 Plug 'airblade/vim-gitgutter' " {{{
  22 " prefer other signs such as ycm diags
  23 let g:gitgutter_sign_priority = 1
  24 " don't clobber other signs
  25 let g:gitgutter_sign_allow_clobber = 0
  26 "}}}
  27 Plug 'alepez/vim-gtest'
  28 Plug 'alx741/vinfo'
  29 Plug 'andrewradev/switch.vim'
  30 Plug 'bling/vim-airline'
  31 Plug 'chrisbra/checkattach'
  32 Plug 'derekwyatt/vim-fswitch'
  33 Plug 'elzr/vim-json'
  34 Plug 'firef0x/pkgbuild.vim'
  35 Plug 'junegunn/vim-easy-align'
  36 Plug 'justinmk/vim-sneak'
  37 Plug 'klen/python-mode'
  38 Plug 'kshenoy/vim-signature'
  39 Plug 'majutsushi/tagbar'
  40 Plug 'octol/vim-cpp-enhanced-highlight'
  41 Plug 'raimondi/delimitmate'
  42 Plug 'sgeb/vim-diff-fold'
  43 Plug 'shougo/unite.vim'
  44 Plug 'shougo/vimproc.vim', {'do': 'make'}
  45 Plug 'sjl/gundo.vim'
  46 Plug 'thinca/vim-qfreplace'
  47 Plug 'tomtom/tcomment_vim'
  48 Plug 'tpope/vim-abolish'
  49 Plug 'tpope/vim-endwise'
  50 Plug 'tpope/vim-eunuch'
  51 Plug 'tpope/vim-fugitive'
  52 Plug 'tpope/vim-repeat'
  53 Plug 'tpope/vim-scriptease'
  54 Plug 'tpope/vim-speeddating'
  55 Plug 'tpope/vim-surround'  "investigate vim-sandwich
  56 Plug 'tpope/vim-unimpaired'
  57 Plug 'tweekmonster/spellrotate.vim'
  58 Plug 'valloric/youcompleteme', { 'do': './install.py --clangd-completer --clang-completer' }
  59 Plug 'vim-scripts/mediawiki.vim'
  60 Plug 'vim-scripts/replacewithregister'
  61 Plug 'vim-scripts/yankring.vim'
  62 Plug 'wincent/loupe'
  63
  64 " colorschemes
  65 Plug 'morhetz/gruvbox' " {{{2
  66 let g:gruvbox_contrast_dark  = 'hard'
  67 let g:gruvbox_contrast_light = 'soft'
  68
  69 Plug 'arcticicestudio/nord-vim' " {{{2
  70 let g:nord_bold = 1
  71 let g:nord_italic = 1
  72 let g:nord_italic_comments = 1
  73 let g:nord_underline = 1
  74 let g:nord_uniform_status_lines = 0
  75 let g:nord_uniform_diff_background = 0
  76 let g:nord_cursor_line_number_background = 0
  77 let g:nord_bold_vertical_split_line = 0
  78
  79 "}}}
  80
  81 " snippets
  82 Plug 'sirver/ultisnips'
  83 Plug 'honza/vim-snippets'
  84
  85 " text objects
  86 Plug 'kana/vim-textobj-user'
  87 Plug 'julian/vim-textobj-variable-segment'
  88 Plug 'sgur/vim-textobj-parameter'
  89 Plug 'kana/vim-operator-user'
  90
  91 " staging
  92 " Check LucHermites plugins: https://github.com/LucHermitte/lh-cpp
  93
  94 Plug 'git@github.com:/ram-z/vim-orgmode', { 'branch': 'dev' } " {{{2
  95 Plug 'vim-scripts/syntaxrange'
  96
  97 let g:org_agenda_files = ['~/org/*.org']
  98
  99 Plug 'neovimhaskell/haskell-vim'  " {{{2
 100 let g:haskell_enable_quantification = 1   " to enable highlighting of `forall`
 101 let g:haskell_enable_recursivedo = 1      " to enable highlighting of `mdo` and `rec`
 102 let g:haskell_enable_arrowsyntax = 1      " to enable highlighting of `proc`
 103 let g:haskell_enable_pattern_synonyms = 1 " to enable highlighting of `pattern`
 104 let g:haskell_enable_typeroles = 1        " to enable highlighting of type roles
 105 let g:haskell_enable_static_pointers = 1  " to enable highlighting of `static`
 106 let g:haskell_backpack = 1                " to enable highlighting of backpack keywords
 107 " }}}
 108
 109 Plug 'aklt/plantuml-syntax'
 110
 111 Plug 'mtth/scratch.vim'  " {{{2
 112   let g:scratch_no_mappings = 1
 113   let g:scratch_autohide = 0
 114 "}}}
 115
 116 Plug 'vim-utils/vim-man'  " {{{2
 117 let g:man_width = 80
 118 "}}}
 119
 120 call plug#end()
 121
 122 filetype plugin indent on
 123
 124 " colorscheme {{{1
 125 syntax on
 126 set background=dark
 127 let &t_8f = "\<Esc>[38;2;%lu;%lu;%lum"
 128 let &t_8b = "\<Esc>[48;2;%lu;%lu;%lum"
 129 set termguicolors
 130 colorscheme $THEME
 131 "TODO see how I can integrate this into a theme that customises upstream Nord
 132 hi debugPC term=reverse ctermbg=8
 133
 134 " options {{{1
 135 " moving around, searching and patterns {{{2
 136 set incsearch           " show match for partly typed search command
 137 set ignorecase          " ignore case when using a search pattern
 138 set smartcase           " override 'ignorecase' when pattern has upper case characters
 139 set hlsearch            " highlight all matches for the last used search pattern
 140
 141 set nostartofline       " don't move the cursor to the first non-blank char of a line
 142 set path+=.
 143 set path+=include/
 144 set path+=../include/
 145 set path+=/usr/include/c++/*
 146
 147 " displaying text {{{2
 148 set nowrap                      " long lines wrap
 149 set linebreak                   " wrap long lines at a character in 'breakat'
 150 set showbreak=↪                 " show these chars for wrapped lines
 151 set breakindent                 " preserve indentation in wrapped text
 152
 153 set lazyredraw                  " don't redraw while executing macros
 154
 155 set list                        " show chars defined in 'listchars'
 156 set listchars=tab:❭\            " list of strings used for list mode
 157 set listchars+=extends:❯,precedes:❮
 158 " Only shown when not in insert mode
 159 set listchars+=trail:·
 160 augroup trailing
 161     au!
 162     au FileType qf setlocal listchars-=trail:·
 163     au InsertEnter * set listchars-=trail:·
 164     au InsertLeave * set listchars+=trail:·
 165 augroup END
 166
 167 set scrolloff=5                 " number of screen lines to show around the cursor
 168 set sidescroll=1                " number of collumns to scroll
 169 set sidescrolloff=1             " don't scroll over the listchars
 170
 171 set fillchars=diff:⣿,vert:│
 172
 173 set nonumber                    " show the line number for each line
 174 set norelativenumber            " show the relative line number for each line
 175
 176 " syntax, highlighting and spelling {{{2
 177 set synmaxcol=800               " don't highlight long lines
 178
 179 set dictionary=spell            " list of dictionary files for keyword completion
 180
 181 set colorcolumn=+1
 182
 183 " multiple windows {{{2
 184 set laststatus=2                " 0, 1 or 2; when to use a status line for the last window
 185
 186 set previewheight=20            " default height for the preview window
 187
 188 set hidden
 189
 190 " set splitbelow                  " a new window is put below of the current one
 191 set splitright                  " a new window is put right of the current one
 192
 193 " terminal {{{2
 194 set ttyfast
 195
 196 " using the mouse {{{2
 197 set mouse=rnv                   " list of flags for using the mouse
 198 set ttymouse=xterm              " type of mouse
 199
 200 " messages and info {{{2
 201 set showcmd         " Show (partial) command in status line.
 202 set ruler           " show the cursor position all the time
 203 set confirm         " Ask what to do when closing unsaved documents
 204 set shortmess=      " reset option
 205 set shortmess+=a    " all abbreviations
 206 set shortmess+=o    " overwrite file-written message
 207 set shortmess+=O    " file-read message overrides previous
 208 set shortmess+=t    " truncate file message at start
 209 set shortmess+=T    " truncate other messages in the middle
 210 set shortmess+=W    " don't give 'written' or '[w]' when writing a file
 211 set shortmess+=A    " ignore swapfile warning
 212 set shortmess+=I    " no splash screen
 213
 214 " editing text {{{2
 215 set backspace=indent,eol,start  " allow backspacing over everything in insert mode
 216
 217 set showmatch                   " Show matching brackets.
 218
 219 set nojoinspaces                " don't use two spaces after '.' when joining a line
 220 set formatoptions+=j    " Delete comment leader when joining lines
 221 set formatoptions+=c    " Autowrap comments using textwidth
 222 set formatoptions+=r    " Insert comment leader after hitting <Enter>
 223 set formatoptions+=n    " Recognize numbered lists
 224 set formatoptions+=q    " Allow formatting of comments with "gq".
 225 set formatoptions+=l    " do not wrap lines that have been longer when starting insert mode already
 226 set formatoptions+=t    " Auto-wrap text using textwidth
 227 set formatoptions-=o    " Do not insert comment leader after hitting o or O in normal mode
 228
 229 set nrformats=hex               " number formats recognized for CTRL-A and CTRL-X commands
 230
 231 set complete=.       " scan the current buffer ( 'wrapscan' is ignored)
 232 set complete+=w      " scan buffers from other windows
 233 set complete+=b      " scan other loaded buffers that are in the buffer list
 234 set complete+=u      " scan the unloaded buffers that are in the buffer list
 235 set complete+=t      " scan tags
 236 set complete+=i      " scan current and included files
 237 set complete+=kspell " use the currently active spell checking |spell|
 238
 239 " whether to use a popup menu for Insert mode completion
 240 set completeopt=longest,menuone,preview
 241
 242 " tabs and indent {{{2
 243 set shiftwidth=4                " number of spaces used for each step of (auto)indent
 244 set smarttab                    " a <Tab> in an indent inserts 'shiftwidth' spaces
 245 set softtabstop=4               " if non-zero, number of spaces to insert for a <Tab>
 246 set shiftround                  " round to 'shiftwidth' for "<<" and ">>"
 247 set expandtab                   " expand <Tab> to spaces in Insert mode
 248 set autoindent
 249
 250 set pastetoggle=<F11>           " key sequence to toggle paste mode
 251
 252 " folding {{{2
 253 set foldmethod=marker           " folding type
 254 set foldlevelstart=0            " value for 'foldlevel' when starting to edit a file
 255
 256 " open folds when jumping to line
 257 set foldopen+=jump
 258
 259 set viewoptions=cursor          " save cursor position
 260 set viewoptions+=folds          " save folds
 261
 262 " diff mode {{{2
 263 set diffopt+=filler         " show filler lines
 264 set diffopt+=vertical       " always vertical split
 265 set diffopt+=context:10     " 10 lines context between changes
 266 set diffopt+=internal
 267 set diffopt+=algorithm:patience
 268
 269 " reading and writing files {{{2
 270 set modeline                    " read modelines
 271 set modelines=2                 " only check first/last 2 lines
 272
 273 set writebackup                 " write a backup file before overwriting a file
 274 set backup                      " keep a backup after owerwriting a file
 275 set backupdir=$XDG_CACHE_HOME/vim/backup//
 276
 277 set backupskip+=.netrc          " skip netrc
 278 set backupskip+=/dev/shm/pass*  " skip passwordstore files
 279
 280 set undofile                    " persistent undo history
 281 set undodir=$XDG_CACHE_HOME/vim/undo//
 282
 283 augroup undoskip
 284     au!
 285     au BufWritePre .netrc         setlocal noundofile
 286     au BufWritePre /dev/shm/pass* setlocal noundofile
 287     au BufWritePre /tmp/*         setlocal noundofile
 288 augroup END
 289
 290 set autowrite                   " automatically write a file when leaving a modified buffer
 291 set autoread                    " automatically read a file that has been modified
 292
 293 " the swap file {{{2
 294 set noswapfile
 295 set directory=$XDG_CACHE_HOME/vim/swap//
 296
 297 " command line editing {{{2
 298 set history=5000                " how many command lines are remembered
 299 set wildmenu                    " command-line completion shows a list of matches
 300 set wildmode=longest:full,full  " specifies how command line completion works
 301 set wildignorecase              " ignore case when completing file names
 302
 303 set wildignore+=.hg,.git,.svn                    " Version control
 304 set wildignore+=*.aux,*.out,*.toc                " LaTeX intermediate files
 305 set wildignore+=*.jpg,*.bmp,*.gif,*.png,*.jpeg   " binary images
 306 set wildignore+=*.o,*.obj,*.exe,*.dll,*.manifest " compiled object files
 307 set wildignore+=*.spl                            " compiled spelling word lists
 308 set wildignore+=*.sw?                            " Vim swap files
 309 set wildignore+=*.luac                           " Lua byte code
 310 set wildignore+=*.pyc                            " Python byte code
 311 set wildignore+=*.orig                           " Merge resolution files
 312
 313 " running make and jumping to errors {{{2
 314 set makeprg=make\ -w     " print changing directories
 315
 316 set grepprg=ag\ --vimgrep\ $*
 317
 318 " language specific {{{2
 319 set isfname-==    " don't treat `=` as being part of filenames
 320
 321 " various {{{2
 322 set virtualedit+=block     " let cursor move past last char in <C-V> mode
 323 set virtualedit+=onemore   " allow the cursor to move just past the end of the line
 324 set viminfo='100,<50,s10,h,n$XDG_CACHE_HOME/vim/viminfo " viminfo defaults but save file in .cache
 325
 326 set viewdir=$XDG_CACHE_HOME/vim/view//
 327
 328 set sessionoptions+=unix,slash  " damn windows and it's silly ways
 329
 330 " autocmds {{{1
 331 " Resize splits when the window is resized {{{2
 332 augroup resize
 333     au!
 334     autocmd VimResized * :wincmd =
 335 augroup END
 336
 337 " Only show cursorline in the current window and in normal mode {{{2
 338 augroup cline
 339     au!
 340     au WinLeave,InsertEnter * set nocursorline
 341     au WinEnter,InsertLeave * set cursorline
 342 augroup END
 343
 344 " Treat buffers from stdin (e.g.: echo foo | vim -) as scratch {{{2
 345 augroup ft_stdin
 346     au!
 347     au StdinReadPost * :set buftype=nofile
 348 augroup END
 349
 350 " Jump to last known cursor position {{{2
 351 augroup cursor_pos
 352     au!
 353     " blacklist certain filetype
 354     let blacklist = ['gitcommit']
 355     autocmd BufReadPost *
 356                 \ if index(blacklist, &ft) < 0 && line("'\"") > 1 && line("'\"") <= line("$") |
 357                 \   exe "normal! g`\"" |
 358                 \ endif
 359 augroup END
 360
 361 " Check for file modifications automatically {{{2
 362 " (current buffer only)
 363 " Use :NoAutoChecktime to disable it (uses b:autochecktime)
 364 fun! MyAutoCheckTime()
 365   " only check timestamp for normal files
 366   if &buftype != '' | return | endif
 367   if ! exists('b:autochecktime') || b:autochecktime
 368     checktime %
 369     let b:autochecktime = 1
 370   endif
 371 endfun
 372 augroup MyAutoChecktime
 373   au!
 374   au FocusGained,BufEnter,CursorHold,InsertEnter * call MyAutoCheckTime()
 375 augroup END
 376 command! NoAutoChecktime let b:autochecktime=0
 377 command! ToggleAutoChecktime let b:autochecktime=!get(b:, 'autochecktime', 0) | echom "b:autochecktime:" b:autochecktime
 378
 379 augroup terminal
 380   au!
 381   au TerminalOpen * if &buftype == 'terminal' | setlocal bufhidden=hide | endif
 382 augroup END
 383
 384 " bindings {{{1
 385
 386 " allow both <space> and \ to be <leader>
 387 map <space> <leader>
 388
 389 " make
 390 function! Make()
 391   let l:make_dir = ""
 392   if exists("b:make_dir")
 393     let l:make_dir = "-C ".b:make_dir
 394   elseif exists("g:make_dir")
 395     let l:make_dir = "-C ".g:make_dir
 396   endif
 397
 398   let l:make_targets = ""
 399   if exists("g:make_targets")
 400     let l:make_targets = g:make_targets
 401   endif
 402   execute "make! ".l:make_dir." ".l:make_targets
 403 endf
 404 nnoremap <leader>r :call Make()<cr>
 405
 406 " unhighlight search
 407 nnoremap <silent> <Leader>/ :silent nohl<CR>
 408
 409 " Tabs
 410 nnoremap <leader>[ :tabprev<cr>
 411 nnoremap <leader>] :tabnext<cr>
 412
 413 " paste from selection
 414 nnoremap <leader>p* :silent! set paste<CR>"*p:set nopaste<CR>
 415 " paste from clipboard
 416 nnoremap <leader>p+ :silent! set paste<CR>"+p:set nopaste<CR>
 417
 418 " strip trailing whitespace
 419 function! StripWhitespace(line1, line2, ...)  " {{{2
 420   let s_report = &report
 421   let &report=0
 422   let pattern = a:0 ? a:1 : '\s\+$'
 423   let oldview = winsaveview()
 424   exe 'keepjumps keeppatterns '.a:line1.','.a:line2.'substitute/'.pattern.'//e'
 425   if oldview != winsaveview()
 426     redraw
 427   endif
 428   call winrestview(oldview)
 429   let &report = s_report
 430 endfunction  " }}}2
 431 command! -range=% -nargs=0 -bar Untrail keepjumps call StripWhitespace(<line1>,<line2>)
 432 nnoremap <silent> <leader>ww :Untrail<CR>
 433
 434 " Source
 435 vnoremap <leader>S y:execute @@<cr>:echo 'Sourced selection.'<cr>
 436 nnoremap <leader>S ^vg_y:execute @@<cr>:echo 'Sourced line.'<cr>
 437
 438 " jump to last cursor position
 439 noremap ' `
 440
 441 " Select (charwise) the contents of the current line, excluding indentation.
 442 nnoremap vv ^vg_
 443
 444 " Unfuck my screen
 445 nnoremap U
 446       \ :syntax sync fromstart<cr>
 447       \ :AirlineRefresh<cr>
 448       \ :call popup_clear(1)<cr>
 449       \ :redraw!<cr>
 450
 451 " Ranger
 452 " nnoremap <leader>r :silent !ranger %:h<cr>:redraw!<cr>
 453 " nnoremap <leader>R :silent !ranger<cr>:redraw!<cr>
 454
 455 " Use sane regexes.
 456 nnoremap / /\v
 457 vnoremap / /\v
 458 cnoremap s/ s/\v
 459
 460 " display the number of matches for the last search
 461 nmap <Leader># :%s:<C-R>/::gn<CR>
 462
 463 " center cursor after search and open folds
 464 nnoremap n nzzzv
 465 nnoremap N Nzzzv
 466
 467 " same when jumping around
 468 nnoremap g; g;zzzv
 469 nnoremap g, g,zzzv
 470 nnoremap <c-o> <c-o>zzzv
 471 nnoremap <c-i> <c-i>zzzv
 472
 473 " Not using the default mappings of 'To line from top/bottom'
 474 noremap H ^
 475 noremap L $
 476 vnoremap H ^
 477 vnoremap L g_
 478
 479 " Heresy, emacs insert bindings
 480 inoremap <C-A> <Esc>I
 481 inoremap <C-E> <Esc>A
 482 cnoremap <C-A> <Home>
 483 cnoremap <C-E> <End>
 484
 485 " proper movement when lines are wrapped
 486 noremap <silent><expr> j (v:count == 0 ? 'gj' : 'j')
 487 noremap <silent><expr> k (v:count == 0 ? 'gk' : 'k')
 488
 489 " disable arrows
 490 noremap  <Up>    <NOP>
 491 noremap  <Down>  <NOP>
 492 noremap  <Left>  <NOP>
 493 noremap  <Right> <NOP>
 494 inoremap <Up>    <NOP>
 495 inoremap <Down>  <NOP>
 496 inoremap <Left>  <NOP>
 497 inoremap <Right> <NOP>
 498 cnoremap <Up>    <NOP>
 499 cnoremap <Down>  <NOP>
 500 cnoremap <Left>  <NOP>
 501 cnoremap <Right> <NOP>
 502 cnoremap <C-K>   <Up>
 503 cnoremap <C-J>   <Down>
 504 cnoremap <C-H>   <Left>
 505 cnoremap <C-L>   <Right>
 506
 507 " close all folds open fold in cursor
 508 nnoremap zx zMzxzt
 509
 510 map <F1> :ls<CR>:b<space>
 511
 512 " move between windows (skip previewwindow)
 513 nnoremap <silent> <C-L> <C-W>w<C-W>:if &previewwindow \| wincmd w \| endif<CR>
 514 nnoremap <silent> <C-H> <C-W>W<C-W>:if &previewwindow \| wincmd W \| endif<CR>
 515 tnoremap <silent> <C-L> <C-W>w<C-W>:if &previewwindow \| wincmd w \| endif<CR>
 516 tnoremap <silent> <C-H> <C-W>W<C-W>:if &previewwindow \| wincmd W \| endif<CR>
 517
 518 "xterm mouse with middleclick paste
 519 nnoremap <MiddleMouse> i<MiddleMouse>
 520 vnoremap <MiddleMouse> s<MiddleMouse>
 521
 522 " fix legacy vi inconsistency
 523 nnoremap Y y$
 524 " copy to clipboard
 525 xnoremap Y "+y
 526
 527 " allow repeat operator on visual
 528 vnoremap . :normal .<CR>
 529
 530 " add line without changing position or leaving mode
 531 noremap <silent> <Leader>o :set paste<CR>m`o<ESC>``:set nopaste<CR>
 532 noremap <silent> <Leader>O :set paste<CR>m`O<ESC>``:set nopaste<CR>
 533
 534 " Don't use Ex mode, use Q for formatting
 535 map Q gq
 536
 537 " break undo sequence before removing word
 538 inoremap <C-W> <C-G>u<C-W>
 539
 540 nnoremap coe :set <C-R>=&expandtab ? 'noexpandtab' : 'expandtab'<CR><CR>
 541 nnoremap [oe :set expandtab<CR>
 542 nnoremap ]oe :set noexpandtab<CR>
 543
 544 for idt in range(1,8)
 545   exe 'nnoremap co'.idt.' :setlocal tabstop='.idt.' shiftwidth='.idt.' softtabstop='.idt.'<CR>'
 546 endfor
 547
 548 " toggle auto format of text
 549 nnoremap coa :set <C-R>=&formatoptions =~ "a" ? 'formatoptions-=a' : 'formatoptions+=a'<CR><CR>
 550 nnoremap [oa :set formatoptions+=a<CR>
 551 nnoremap ]oa :set formatoptions-=a<CR>
 552
 553 " space will toggle current fold in normal mode
 554 nnoremap <leader><Space> za
 555 " create folds around visual selection
 556 vnoremap <leader><Space> zf
 557
 558 " save with sudo
 559 cabbrev w!! SudoWrite
 560
 561 " uppercase previous word
 562 inoremap <C-C> <Esc>gUiwgi
 563
 564 " http://git.io/v3ZeU
 565 nmap <silent> <leader>qq :echo "hi<" . synIDattr(synID(line("."),col("."),1),"name") . '> trans<' . synIDattr(synID(line("."),col("."),0),"name") . "> lo<" . synIDattr(synIDtrans(synID(line("."),col("."),1)),"name") . ">"<CR>
 566
 567 " plugins options {{{1
 568 " airline {{{2
 569 let g:airline#extensions#whitespace#enabled = 1
 570 let g:airline#extensions#tabline#enabled = 1
 571 let g:airline#extensions#searchcount#enabled = 0
 572 let g:airline_powerline_fonts = 1
 573
 574 " checkattach {{{2
 575 let g:checkattach_filebrowser = 'ranger'
 576 let g:checkattach_once = 'y'
 577
 578 " delimitmate {{{2
 579 let delimitMate_expand_cr = 2
 580 let g:delimitMate_expand_space = 1
 581
 582 " fswitch {{{2
 583 nnoremap <silent> <Leader>ff :FSHere<CR>
 584 nnoremap <silent> <Leader>fl :FSRight<CR>
 585 nnoremap <silent> <Leader>fh :FSLeft<CR>
 586 nnoremap <silent> <Leader>fj :FSBelow<CR>
 587 nnoremap <silent> <Leader>fk :FSAbove<CR>
 588 nnoremap <silent> <Leader>fL :FSSplitRight<CR>
 589 nnoremap <silent> <Leader>fH :FSSplitLeft<CR>
 590 nnoremap <silent> <Leader>fJ :FSSplitBelow<CR>
 591 nnoremap <silent> <Leader>fK :FSSplitAbove<CR>
 592
 593 " fugitive {{{2
 594 nmap <silent> <leader>dd :tab split \| Gdiff \| wincmd h<CR>
 595 " delete fugitive buffers when closed
 596 autocmd BufReadPost fugitive://* set bufhidden=delete
 597
 598 nnoremap <silent> <leader>gs :Git<CR>
 599 nnoremap <silent> <leader>gd :Gdiffsplit<CR>
 600 nnoremap <silent> <leader>gc :echohl WarningMsg \| echo "use \<leader>gcc instead" \| echohl None<CR>
 601 nnoremap <silent> <leader>gcc :tab G commit -v<CR>
 602 nnoremap <silent> <leader>gca :tab G commit -v --amend<CR>
 603 nnoremap          <leader>gcf :tab G commit -v --fixup=
 604 nnoremap <silent> <leader>gp :echohl WarningMsg \| echo "use \<leader>gpp instead" \| echohl None<CR>
 605 nnoremap <silent> <leader>gpp :Git push \| copen<CR>
 606 nnoremap <silent> <leader>gpf :Git push --force-with-lease \| copen<CR>
 607 nnoremap <silent> <leader>gll :Git pull<CR>
 608 nnoremap <silent> <leader>gru :Git rebase --interactive @{upstream}<CR>
 609 nnoremap <silent> <leader>grp :Git rebase --interactive @{push}<CR>
 610 nnoremap <silent> <leader>ga :Gwrite<cr>
 611 nnoremap <silent> <leader>gb :G blame<cr>
 612
 613 augroup fugitive_gstatus
 614     au!
 615     autocmd BufWinEnter */.git/index resize 16
 616 augroup end
 617
 618 " Gundo {{{2
 619 nnoremap <F7> :GundoToggle<CR>
 620 let g:gundo_prefer_python3 = 1
 621
 622 " indent-guides {{{2
 623 let g:indent_guides_default_mapping = 0
 624 let g:indent_guides_guide_size = 1
 625 nmap <silent> cog <Plug>IndentGuidesToggle
 626 nmap <silent> [og <Plug>IndentGuidesEnable
 627 nmap <silent> ]og <Plug>IndentGuidesDisable
 628
 629 " close-another-window {{{2
 630 nnoremap <silent> <C-W>c  <NOP>
 631 nnoremap <silent> <C-W>cc <C-W>c
 632 nnoremap <silent> <C-W>ch :CloseLeftWindow<CR>
 633 nnoremap <silent> <C-W>cl :CloseRightWindow<CR>
 634 nnoremap <silent> <C-W>cj :CloseBelowWindow<CR>
 635 nnoremap <silent> <C-W>ck :CloseAboveWindow<CR>
 636
 637 " python-mode {{{2
 638
 639 let g:pymode_rope_completion = 0
 640 let g:pymode_rope = 0
 641 let g:pymode_run = 0
 642 let g:pymode_folding = 1
 643 let g:pymode_lint_ignore = "E221,E266,E501"
 644 let g:pymode_lint_cwindow = 0           " don't open cwindow when linting
 645 let g:pymode_syntax_space_errors = 0    " don't bother me when I'm typing
 646
 647 " signature {{{2
 648 " disable '[ mappings
 649
 650 let g:SignatureMap = {
 651   \ 'GotoNextLineAlpha'  :  "",
 652   \ 'GotoPrevLineAlpha'  :  "",
 653   \ 'GotoNextSpotAlpha'  :  "",
 654   \ 'GotoPrevSpotAlpha'  :  "",
 655   \ }
 656
 657 " switch
 658 let g:switch_mapping = "<Leader>s"
 659
 660 " spellrotate
 661 nmap <silent> z] <Plug>(SpellRotateForward)
 662 nmap <silent> z[ <Plug>(SpellRotateBackward)
 663 vmap <silent> z] <Plug>(SpellRotateForwardV)
 664 vmap <silent> z[ <Plug>(SpellRotateBackwardV)
 665
 666 " synastic {{{2
 667 let g:syntastic_enable_highlighting = 0
 668 let g:syntastic_error_symbol='E'
 669 let g:syntastic_style_error_symbol='S'
 670 let g:syntastic_warning_symbol='W'
 671 let g:syntastic_style_warning_symbol='S'
 672 let g:syntastic_always_populate_loc_list=1
 673 nmap <silent> <leader>y :SyntasticCheck<cr>
 674
 675 let g:syntastic_cpp_clang_tidy_post_args = "-p build*"
 676
 677 if ! &diff
 678   let g:syntastic_check_on_open=1
 679 endif
 680
 681 " tagbar {{{2
 682 map <F5> :TagbarToggle<cr>
 683 let g:tagbar_sort = 0
 684 let g:tagbar_compact = 1
 685 let g:tagbar_autoshowtag = 1
 686 let g:tagbar_width = 25
 687 let g:tagbar_iconchars = ['+', '-']
 688
 689 " tcomments {{{2
 690 let g:tcomment_textobject_inlinecomment = 'gic'
 691 let g:tcomment#filetype#guess = 0
 692
 693 " ultisnips {{{2
 694 let g:UltiSnipsEditSplit = 'vertical'
 695 let g:UltiSnipsSnippetDirectories = [ expand("$XDG_CONFIG_HOME/vim/ultisnips") ]
 696 if has('fname_case')
 697   let g:UltiSnipsSnippetDirectories = ["UltiSnips", "ultisnips"]
 698 endif
 699 let g:UltiSnipsExpandTrigger       = "<tab>"
 700 let g:UltiSnipsJumpForwardTrigger  = "<tab>"
 701 let g:UltiSnipsJumpBackwardTrigger = "<s-tab>"
 702
 703 " UltiSnips completion function that tries to expand a snippet. If there's no
 704 " snippet for expanding, it checks for completion window and if it's shown,
 705 " selects first element. If there's no completion window it tries to jump to
 706 " next placeholder. If there's no placeholder it just returns TAB key
 707 " https://github.com/Valloric/YouCompleteMe/issues/36#issuecomment-15451411
 708 function! g:UltiSnips_Complete()
 709     call UltiSnips#ExpandSnippet()
 710     if g:ulti_expand_res == 0
 711         if pumvisible()
 712             return "\<C-n>"
 713         else
 714             call UltiSnips#JumpForwards()
 715             if g:ulti_jump_forwards_res == 0
 716                return "\<TAB>"
 717             endif
 718         endif
 719     endif
 720     return ""
 721 endfunction
 722 au InsertEnter * exec "inoremap <silent> " . g:UltiSnipsExpandTrigger . " <C-R>=g:UltiSnips_Complete()<cr>"
 723 let g:UltiSnipsListSnippets="<c-e>"
 724
 725 " unite {{{2
 726 call unite#filters#matcher_default#use(['matcher_fuzzy'])
 727 call unite#custom#profile('default', 'context', {
 728             \ 'winheight': 20,
 729             \ 'direction': 'botright'
 730             \ })
 731
 732 nnoremap [unite] <Nop>
 733 nmap <leader>u [unite]
 734 nnoremap [unite]u :UniteResume<CR>
 735 nnoremap <silent> [u :UnitePrevious<CR>
 736 nnoremap <silent> ]u :UniteNext<CR>
 737
 738 " unite-grep {{{3
 739 " seems not respected
 740 let g:unite_source_grep_max_candidates = 2000
 741 if executable('ag')
 742     " Use ag in unite grep source.
 743     let g:unite_source_grep_command = 'ag'
 744     let g:unite_source_grep_default_opts = '--smart-case --vimgrep --ignore ''.hg'' --ignore ''.svn'' --ignore ''.git'' --ignore ''.bzr'''
 745     let g:unite_source_grep_recursive_opt = ''
 746 end
 747 nnoremap <silent> [unite]a :<C-u>Unite grep:.::\12\17<CR>
 748 nnoremap <silent> [unite]A :<C-u>Unite grep:.:-w:\12\17<CR>
 749 command! -nargs=+ Ag Unite -input=<args> grep:.:
 750
 751 " unite-file_rec {{{3
 752 if executable('ag')
 753     " Use ag in unite rec source
 754     let g:unite_source_rec_async_command = ['ag', '--follow', '--nocolor', '--nogroup', '-g', '']
 755 end
 756 nnoremap <silent> [unite]f :<C-u>Unite -start-insert file_rec/async<CR>
 757 call unite#custom#source('file_rec/async', 'sorters', 'sorter_selecta')
 758
 759 " unite-buffer {{{3
 760 call unite#custom#default_action('buffer', 'open')
 761 nnoremap <silent> [unite]b :<C-u>Unite buffer:-<CR>
 762
 763 " unite-jumplist {{{3
 764 nnoremap <silent> [unite]j :<C-u>Unite output:jumps:<CR>
 765
 766 " unite-menu {{{3
 767 let g:unite_source_menu_menus = {}
 768 let g:unite_source_menu_menus.fugitive = { 'description' : 'fugitive menu'}
 769 let g:unite_source_menu_menus.fugitive.command_candidates = {
 770             \ 'Gstatus <Leader>gs' : 'Gstatus',
 771             \ 'Gcommit -v <Leader>gc' : 'Gcommit -v',
 772             \ 'Glog' : 'Glog',
 773             \}
 774
 775 nnoremap <silent> <leader>gg :<C-u>Unite menu:fugitive<CR>
 776
 777 let g:unite_source_history_yank_enable = 1
 778 nnoremap <silent> [unite]p :<C-u>Unite history/yank<CR>
 779
 780 " yankring {{{2
 781 nnoremap <silent> <leader>p :YRShow<cr>
 782 let g:yankring_history_dir = expand('$XDG_CACHE_HOME/vim')
 783 let g:yankring_replace_n_pkey = ''
 784 let g:yankring_replace_n_nkey = ''
 785
 786 " map Y to y$ for the yank ring
 787 function! YRRunAfterMaps()
 788     nnoremap Y   :<C-U>YRYankCount 'y$'<CR>
 789 endfunction
 790
 791 " youcompleteme {{{2
 792 let g:ycm_clangd_binary_path = 'clangd'   " use clangd in path
 793 let g:ycm_clangd_args = ['--clang-tidy']
 794 let g:ycm_extra_conf_vim_data = ['getcwd()']
 795 let g:ycm_add_preview_to_completeopt = 1
 796 let g:ycm_complete_in_comments = 1
 797 let g:ycm_complete_in_strings  = 1
 798 let g:ycm_autoclose_preview_window_after_insertion = 0
 799
 800 " vim-easy-align {{{2
 801 " start interactive EasyAlign in visual mode
 802 vmap <Enter> <Plug>(EasyAlign)
 803 nmap ga <Plug>(EasyAlign)
 804
 805 " vim-gtest {{{2
 806 let g:gtest#highlight_failing_tests = 0
 807
 808 nnoremap <silent> <Leader>tt :GTestRun<CR>
 809 nnoremap          <Leader>tc :GTestCase<space>
 810 nnoremap          <Leader>tn :GTestName<space>
 811 nnoremap <silent> <Leader>ta :GTestCase *<CR>:GTestName *<CR>:GTestRun<CR>
 812 nnoremap <silent> <Leader>tu :GTestRunUnderCursor<CR>
 813
 814 " vim-json {{{2
 815 let g:vim_json_syntax_conceal = 0
 816
 817 " vim-sneak {{{2
 818 let g:sneak#streak = 1
 819 let g:sneak#target_labels = "aoeuisnthdpylrcgfqjkxzmwvz" " dvorak
 820 let g:sneak#use_ic_scs = 1  " follow 'ignorecase' and 'smartcase'
 821
 822 " sneaky f and t
 823 nmap f <Plug>Sneak_f
 824 nmap F <Plug>Sneak_F
 825 xmap f <Plug>Sneak_f
 826 xmap F <Plug>Sneak_F
 827 omap f <Plug>Sneak_f
 828 omap F <Plug>Sneak_F
 829 nmap t <Plug>Sneak_t
 830 nmap T <Plug>Sneak_T
 831 xmap t <Plug>Sneak_t
 832 xmap T <Plug>Sneak_T
 833 omap t <Plug>Sneak_t
 834 omap T <Plug>Sneak_T
 835
 836 " functions {{{1
 837
 838 " Convenient command to see the difference between the current buffer and the
 839 " file it was loaded from, thus the changes you made.
 840 " Only define it when not defined already.
 841 if !exists(":DiffOrig")
 842   command DiffOrig vert new | set bt=nofile | r # | 0d_ | diffthis
 843                   \ | wincmd p | diffthis
 844 endif
 845
 846 " sort operator {{{2
 847 function! SortLinesOpFunc(...)
 848   '[,']sort
 849 endfunction
 850 nnoremap <silent> gs :<C-U>set operatorfunc=SortLinesOpFunc<CR>g@
 851 vnoremap <silent> gs :sort<cr>
 852
 853 " edit configs  {{{2
 854 function! EditConfig(what, ext = '.vim')
 855     let l:dir = split(&runtimepath,',')[0]
 856     if a:what == 'vimrc'
 857         let l:file = expand($MYVIMRC)
 858     elseif ! isdirectory(globpath(l:dir, a:what))
 859         echoe a:what." is not valid!"
 860     elseif empty(&filetype)
 861         echoe 'filetype is empty!'
 862     else
 863         let l:file = l:dir.'/'.a:what.'/'.&filetype.a:ext
 864     endif
 865
 866     execute ':vsplit '.file
 867     execute ':lcd %:p:h'
 868 endf
 869 nmap <leader>ev :call EditConfig('vimrc')<CR>
 870 nmap <leader>ef :call EditConfig('ftplugin')<CR>
 871 nmap <leader>es :call EditConfig('syntax')<CR>
 872 nmap <leader>ei :call EditConfig('indent')<CR>
 873 nmap <leader>eu :call EditConfig('ultisnips', '.snippets')<CR>
 874
 875 " spell check {{{2
 876 " http://tex.stackexchange.com/a/52932
 877 let g:myLangList=["en_gb","en_us","de","fr"]
 878
 879 function! ToggleSpell()
 880   if !exists("b:myLang")
 881     let b:myLang=0
 882   endif
 883   execute "setlocal spell!"
 884   if (&spell)
 885     echo "setlocal spelllang=" g:myLangList[b:myLang]
 886   endif
 887 endfunction
 888
 889 function! SwitchSpell()
 890   if !exists("b:myLang")
 891     let b:myLang=0
 892   endif
 893   if (&spell)
 894     let b:myLang=b:myLang+1
 895     if b:myLang>=len(g:myLangList) | let b:myLang=0 | endif
 896   endif
 897   execute "setlocal spell spelllang=".get(g:myLangList, b:myLang)
 898   echo "setlocal spelllang=" g:myLangList[b:myLang]
 899 endfunction
 900
 901 nnoremap <silent> coS :call SwitchSpell()<CR>
 902 " fix spelling with first choice
 903 nnoremap <Leader>f 1z=
 904
 905 " gitdir or home {{{2
 906 " from derek wyatt:
 907 " http://git.io/v3GAV
 908 function! FindGitDirOrHome()
 909   let filedir = expand('%:p:h')
 910   if isdirectory(filedir)
 911     let cmd = 'bash -c "(cd ' . filedir . '; git rev-parse --show-toplevel 2>/dev/null)"'
 912     let gitdir = system(cmd)
 913     if strlen(gitdir) == 0
 914       return '~'
 915     else
 916       return gitdir[:-2]
 917     endif
 918   else
 919     return '~'
 920   endif
 921 endfunction
 922 command! Cd cd %:h
 923 command! Cdr execute('cd ' . FindGitDirOrHome())
 924 command! LCd lcd %:h
 925 command! LCdr execute('lcd ' . FindGitDirOrHome())
 926
 927 " vim:set et sw=2 ts=2 tw=78: