vim/vimrc

   1 " My vimrc.
   2 "
   3 " Author:   Samir Benmendil <samir.benmendil[at]gmail[dot]com>
   4 "
   5
   6 " plugins {{{1
   7 filetype off
   8 set runtimepath& " reset rtp
   9 " remove all autocommands
  10 autocmd!
  11
  12 set runtimepath+=$XDG_DATA_HOME/vim/vundle
  13 call vundle#rc('$XDG_DATA_HOME/vim')
  14
  15 Plugin 'gmarik/vundle'
  16
  17 Plugin 'airblade/vim-gitgutter'
  18 Plugin 'bling/vim-airline'
  19 Plugin 'derekwyatt/vim-fswitch'
  20 Plugin 'elzr/vim-json'
  21 Plugin 'firef0x/pkgbuild.vim'
  22 Plugin 'junegunn/vim-easy-align'
  23 Plugin 'justinmk/vim-sneak'
  24 Plugin 'klen/python-mode'
  25 Plugin 'kshenoy/vim-signature'
  26 Plugin 'majutsushi/tagbar'
  27 Plugin 'octol/vim-cpp-enhanced-highlight'
  28 Plugin 'raimondi/delimitmate'
  29 Plugin 'scrooloose/syntastic'
  30 Plugin 'shougo/unite.vim'
  31 Plugin 'shougo/vimproc.vim'
  32 Plugin 'sjl/gundo.vim'
  33 Plugin 'tomtom/tcomment_vim'
  34 Plugin 'tpope/vim-abolish'
  35 Plugin 'tpope/vim-endwise'
  36 Plugin 'tpope/vim-fugitive'
  37 Plugin 'tpope/vim-repeat'
  38 Plugin 'tpope/vim-surround'
  39 Plugin 'tpope/vim-unimpaired'
  40 Plugin 'valloric/youcompleteme'
  41 Plugin 'vim-scripts/replacewithregister'
  42 Plugin 'vim-scripts/yankring.vim'
  43
  44 " colorschemes
  45 Plugin 'flazz/vim-colorschemes'
  46
  47 " snippets
  48 Plugin 'sirver/ultisnips'
  49 Plugin 'honza/vim-snippets'
  50
  51 " text objects
  52 Plugin 'kana/vim-textobj-user'
  53 Plugin 'julian/vim-textobj-variable-segment'
  54 Plugin 'sgur/vim-textobj-parameter'
  55
  56 " ros
  57 Plugin 'ompugao/ros.vim'
  58 Plugin 'ompugao/ctrlp-ros'
  59
  60 " seems to have problems right now... may be add later?
  61 " Plugin 'jalcine/cmake.vim'
  62 " Plugin 'powerman/vim-plugin-viewdoc'
  63
  64 " staging
  65 " find an alternative (latex-box? Automatic Latex Plugin?)
  66 Plugin 'http://git.code.sf.net/p/vim-latex/vim-latex'
  67 " Plugin 'lokaltog/vim-easymotion'
  68 Plugin 'chrisbra/checkattach'
  69 Plugin 'nathanaelkane/vim-indent-guides'
  70 Plugin 'alx741/vinfo'
  71 Plugin 'vim-scripts/mediawiki.vim'
  72 Plugin 'derekwyatt/vim-protodef'
  73 Plugin 'rdnetto/ycm-generator'
  74 " needs editing colorscheme
  75 " Plugin 'jeaye/color_coded'
  76
  77 " remove entries first
  78 set runtimepath -=$HOME/.vim
  79 set runtimepath -=$HOME/.vim/after
  80 set runtimepath -=$XDG_CONFIG_HOME/vim
  81 set runtimepath -=$XDG_CONFIG_HOME/vim/after
  82 " then prepend and append them
  83 set runtimepath ^=$XDG_CONFIG_HOME/vim
  84 set runtimepath +=$XDG_CONFIG_HOME/vim/after
  85
  86 filetype plugin indent on
  87
  88 " colorscheme {{{1
  89 syntax on
  90 colorscheme badfox
  91
  92 " options {{{1
  93 " moving around, searching and patterns {{{2
  94 set incsearch           " show match for partly typed search command
  95 set ignorecase          " ignore case when using a search pattern
  96 set smartcase           " override 'ignorecase' when pattern has upper case characters
  97 set hlsearch            " highlight all matches for the last used search pattern
  98
  99 set nostartofline       " don't move the cursor to the first non-blank char of a line
 100 set path+=.
 101 set path+=include/
 102 set path+=../include/
 103 set path+=/usr/include/c++/*
 104
 105 " displaying text {{{2
 106 set nowrap                      " long lines wrap
 107 set linebreak                   " wrap long lines at a character in 'breakat'
 108 set showbreak=↪                 " show these chars for wrapped lines
 109 set breakindent                 " preserve indentation in wrapped text
 110
 111 set lazyredraw                  " don't redraw while executing macros
 112
 113 set list                        " show chars defined in 'listchars'
 114 set listchars=tab:❭\            " list of strings used for list mode
 115 set listchars+=extends:❯,precedes:❮
 116 " Only shown when not in insert mode
 117 au InsertLeave * :set listchars+=trail:·
 118 augroup trailing
 119     au!
 120     au InsertEnter * :set listchars-=trail:·
 121     au InsertLeave * :set listchars+=trail:·
 122 augroup END
 123
 124 set scrolloff=5                 " number of screen lines to show around the cursor
 125 set sidescroll=1                " number of collumns to scroll
 126 set sidescrolloff=1             " don't scroll over the listchars
 127
 128 set fillchars=diff:⣿,vert:│
 129
 130 set nonumber                    " show the line number for each line
 131 set norelativenumber            " show the relative line number for each line
 132
 133 " syntax, highlighting and spelling {{{2
 134 set synmaxcol=800               " don't highlight long lines
 135
 136 set dictionary=spell            " list of dictionary files for keyword completion
 137
 138 set colorcolumn=+1
 139
 140 " multiple windows {{{2
 141 set laststatus=2                " 0, 1 or 2; when to use a status line for the last window
 142
 143 set previewheight=20            " default height for the preview window
 144
 145 set hidden
 146
 147 " set splitbelow                  " a new window is put below of the current one
 148 set splitright                  " a new window is put right of the current one
 149
 150 " terminal {{{2
 151 set ttyfast
 152
 153 " using the mouse {{{2
 154 set mouse=rnv                   " list of flags for using the mouse
 155 set ttymouse=xterm              " type of mouse
 156
 157 " messages and info {{{2
 158 set showcmd                     " Show (partial) command in status line.
 159 set ruler                       " show the cursor position all the time
 160 set confirm                     " Ask what to do when closing unsaved documents
 161 set shortmess=filnxtoOI         " don't show intro message
 162
 163 " editing text {{{2
 164 set backspace=indent,eol,start  " allow backspacing over everything in insert mode
 165
 166 set showmatch                   " Show matching brackets.
 167
 168 set nojoinspaces                " don't use two spaces after '.' when joining a line
 169 set formatoptions+=j    " Delete comment leader when joining lines
 170 set formatoptions+=c    " Autowrap comments using textwidth
 171 set formatoptions+=r    " Insert comment leader after hitting <Enter>
 172 set formatoptions+=n    " Recognize numbered lists
 173 set formatoptions+=q    " Allow formatting of comments with "gq".
 174 set formatoptions+=l    " do not wrap lines that have been longer when starting insert mode already
 175 set formatoptions+=t    " Auto-wrap text using textwidth
 176 set formatoptions-=o    " Do not insert comment leader after hitting o or O in normal mode
 177
 178 set nrformats=hex               " number formats recognized for CTRL-A and CTRL-X commands
 179
 180 set complete=.       " scan the current buffer ( 'wrapscan' is ignored)
 181 set complete+=w      " scan buffers from other windows
 182 set complete+=b      " scan other loaded buffers that are in the buffer list
 183 set complete+=u      " scan the unloaded buffers that are in the buffer list
 184 set complete+=t      " scan tags
 185 set complete+=i      " scan current and included files
 186 set complete+=kspell " use the currently active spell checking |spell|
 187
 188 " whether to use a popup menu for Insert mode completion
 189 set completeopt=longest,menuone,preview
 190
 191 " tabs and indent {{{2
 192 set shiftwidth=4                " number of spaces used for each step of (auto)indent
 193 set smarttab                    " a <Tab> in an indent inserts 'shiftwidth' spaces
 194 set softtabstop=4               " if non-zero, number of spaces to insert for a <Tab>
 195 set shiftround                  " round to 'shiftwidth' for "<<" and ">>"
 196 set expandtab                   " expand <Tab> to spaces in Insert mode
 197 set autoindent
 198
 199 set pastetoggle=<F11>           " key sequence to toggle paste mode
 200
 201 " folding {{{2
 202 set foldmethod=marker           " folding type
 203 set foldlevelstart=0            " value for 'foldlevel' when starting to edit a file
 204
 205 " open folds when jumping to line
 206 set foldopen+=jump
 207
 208 " save and restore folds
 209 set viewoptions=cursor          " only save cursor position
 210
 211 " diff mode {{{2
 212 set diffopt+=filler         " show filler lines
 213 set diffopt+=vertical       " always vertical split
 214 set diffopt+=iwhite         " ignore white space
 215 set diffopt+=context:10     " 10 lines context between changes
 216
 217 " reading and writing files {{{2
 218 set modeline                    " read modelines
 219 set modelines=2                 " only check first/last 2 lines
 220
 221 set writebackup                 " write a backup file before overwriting a file
 222 set backup                      " keep a backup after owerwriting a file
 223 set backupdir=$XDG_CACHE_HOME/vim/backup//
 224
 225 set backupskip+=.netrc          " skip netrc
 226 set backupskip+=/dev/shm/pass*  " skip passwordstore files
 227
 228 set undofile                    " persistent undo history
 229 set undodir=$XDG_CACHE_HOME/vim/undo//
 230
 231 augroup undoskip
 232     au!
 233     au BufWritePre .netrc         setlocal noundofile
 234     au BufWritePre /dev/shm/pass* setlocal noundofile
 235     au BufWritePre /tmp/*         setlocal noundofile
 236 augroup END
 237
 238 set autowrite                   " automatically write a file when leaving a modified buffer
 239 set autoread                    " automatically read a file that has been modified
 240
 241 " the swap file {{{2
 242 set noswapfile
 243 set directory=$XDG_CACHE_HOME/vim/swap//
 244
 245 " command line editing {{{2
 246 set history=5000                " how many command lines are remembered
 247 set wildmenu                    " command-line completion shows a list of matches
 248 set wildmode=longest:full,full  " specifies how command line completion works
 249
 250 set wildignore+=.hg,.git,.svn                    " Version control
 251 set wildignore+=*.aux,*.out,*.toc                " LaTeX intermediate files
 252 set wildignore+=*.jpg,*.bmp,*.gif,*.png,*.jpeg   " binary images
 253 set wildignore+=*.o,*.obj,*.exe,*.dll,*.manifest " compiled object files
 254 set wildignore+=*.spl                            " compiled spelling word lists
 255 set wildignore+=*.sw?                            " Vim swap files
 256 set wildignore+=*.luac                           " Lua byte code
 257 set wildignore+=*.pyc                            " Python byte code
 258 set wildignore+=*.orig                           " Merge resolution files
 259
 260 " running make and jumping to errors
 261 set makeprg=make\ -w     " print changing directories
 262
 263 " language specific {{{2
 264 set isfname-==    " don't treat `=` as being part of filenames
 265
 266 " various {{{2
 267 set virtualedit+=block     " let cursor move past last char in <C-V> mode
 268 set virtualedit+=onemore   " allow the cursor to move just past the end of the line
 269 set viminfo='100,<50,s10,h,n$XDG_CACHE_HOME/vim/viminfo " viminfo defaults but save file in .cache
 270
 271 set viewdir=$XDG_CACHE_HOME/vim/view//
 272
 273 set sessionoptions+=unix,slash  " damn windows and it's silly ways
 274
 275 " autocmds {{{1
 276 " Resize splits when the window is resized {{{2
 277 augroup resize
 278     au!
 279     autocmd VimResized * :wincmd =
 280 augroup END
 281
 282 " Only show cursorline in the current window and in normal mode {{{2
 283 augroup cline
 284     au!
 285     au WinLeave,InsertEnter * set nocursorline
 286     au WinEnter,InsertLeave * set cursorline
 287 augroup END
 288
 289 " Treat buffers from stdin (e.g.: echo foo | vim -) as scratch {{{2
 290 augroup ft_stdin
 291     au!
 292     au StdinReadPost * :set buftype=nofile
 293 augroup END
 294
 295 " Jump to last known cursor position {{{2
 296 augroup cursor_pos
 297     au!
 298     " blacklist certain filetype
 299     let blacklist = ['gitcommit']
 300     autocmd BufReadPost *
 301                 \ if index(blacklist, &ft) < 0 && line("'\"") > 1 && line("'\"") <= line("$") |
 302                 \   exe "normal! g`\"" |
 303                 \ endif
 304 augroup END
 305
 306 " Check for file modifications automatically {{{2
 307 " (current buffer only)
 308 " Use :NoAutoChecktime to disable it (uses b:autochecktime)
 309 fun! MyAutoCheckTime()
 310   " only check timestamp for normal files
 311   if &buftype != '' | return | endif
 312   if ! exists('b:autochecktime') || b:autochecktime
 313     checktime %
 314     let b:autochecktime = 1
 315   endif
 316 endfun
 317 augroup MyAutoChecktime
 318   au!
 319   au FocusGained,BufEnter,CursorHold,InsertEnter * call MyAutoCheckTime()
 320 augroup END
 321 command! NoAutoChecktime let b:autochecktime=0
 322 command! ToggleAutoChecktime let b:autochecktime=!get(b:, 'autochecktime', 0) | echom "b:autochecktime:" b:autochecktime
 323
 324 " bindings {{{1
 325
 326 " allow both <space> and / to be <leader>
 327 map <space> <leader>
 328
 329 " make
 330 nnoremap <leader>r :make!<cr>
 331 nnoremap <leader><cr> :make!<cr>
 332
 333 " unhighlight search
 334 nnoremap <silent> <Leader>/ :silent nohl<CR>
 335
 336 " Tabs
 337 nnoremap <leader>[ :tabprev<cr>
 338 nnoremap <leader>] :tabnext<cr>
 339
 340 " paste from selection
 341 nnoremap <leader>p* :silent! set paste<CR>"*p:set nopaste<CR>
 342 " paste from clipboard
 343 nnoremap <leader>p+ :silent! set paste<CR>"+p:set nopaste<CR>
 344
 345 " strip trailing whitespace
 346 function! StripWhitespace(line1, line2, ...)  " {{{2
 347   let s_report = &report
 348   let &report=0
 349   let pattern = a:0 ? a:1 : '[\\]\@<!\s\+$'
 350   let oldview = winsaveview()
 351   exe 'keepjumps keeppatterns '.a:line1.','.a:line2.'substitute/'.pattern.'//e'
 352   if oldview != winsaveview()
 353     redraw
 354   endif
 355   call winrestview(oldview)
 356   let &report = s_report
 357 endfunction  " }}}2
 358 command! -range=% -nargs=0 -bar Untrail keepjumps call StripWhitespace(<line1>,<line2>)
 359 nnoremap <silent> <leader>ww :Untrail<CR>
 360
 361 " Source
 362 vnoremap <leader>S y:execute @@<cr>:echo 'Sourced selection.'<cr>
 363 nnoremap <leader>S ^vg_y:execute @@<cr>:echo 'Sourced line.'<cr>
 364
 365 " jump to last cursor position
 366 noremap ' `
 367
 368 " Select (charwise) the contents of the current line, excluding indentation.
 369 nnoremap vv ^vg_
 370
 371 " Unfuck my screen
 372 nnoremap U :syntax sync fromstart<cr>:AirlineRefresh<cr>:redraw!<cr>
 373
 374 " Ranger
 375 " nnoremap <leader>r :silent !ranger %:h<cr>:redraw!<cr>
 376 " nnoremap <leader>R :silent !ranger<cr>:redraw!<cr>
 377
 378 " Use sane regexes.
 379 nnoremap / /\v
 380 vnoremap / /\v
 381 cnoremap s/ s/\v
 382
 383 " display the number of matches for the last search
 384 nmap <Leader># :%s:<C-R>/::gn<CR>
 385
 386 " center cursor after search and open folds
 387 nnoremap n nzzzv
 388 nnoremap N Nzzzv
 389
 390 " same when jumping around
 391 nnoremap g; g;zzzv
 392 nnoremap g, g,zzzv
 393 nnoremap <c-o> <c-o>zzzv
 394 nnoremap <c-i> <c-i>zzzv
 395
 396 " Not using the default mappings of 'To line from top/bottom'
 397 noremap H ^
 398 noremap L $
 399 vnoremap H ^
 400 vnoremap L g_
 401
 402 " Heresy, emacs insert bindings
 403 inoremap <C-A> <Esc>I
 404 inoremap <C-E> <Esc>A
 405 cnoremap <C-A> <Home>
 406 cnoremap <C-E> <End>
 407
 408 " proper movement when lines are wrapped
 409 noremap <expr> j (v:count == 0 ? 'gj' : 'j')
 410 noremap <expr> k (v:count == 0 ? 'gk' : 'k')
 411
 412 " disable arrows
 413 noremap  <Up>    <NOP>
 414 noremap  <Down>  <NOP>
 415 noremap  <Left>  <NOP>
 416 noremap  <Right> <NOP>
 417 inoremap <Up>    <NOP>
 418 inoremap <Down>  <NOP>
 419 inoremap <Left>  <NOP>
 420 inoremap <Right> <NOP>
 421 cnoremap <Up>    <NOP>
 422 cnoremap <Down>  <NOP>
 423 cnoremap <Left>  <NOP>
 424 cnoremap <Right> <NOP>
 425 cnoremap <C-K>   <Up>
 426 cnoremap <C-J>   <Down>
 427 cnoremap <C-H>   <Left>
 428 cnoremap <C-L>   <Right>
 429
 430 " close all folds open fold in cursor
 431 nnoremap zx zMzxzt
 432
 433 map <F1> :ls<CR>:b<space>
 434
 435 nnoremap <C-L> <C-W>w
 436 nnoremap <C-H> <C-W>W
 437
 438 "xterm mouse with middleclick paste
 439 nnoremap <MiddleMouse> i<MiddleMouse>
 440 vnoremap <MiddleMouse> s<MiddleMouse>
 441
 442 " fix legacy vi inconsistency
 443 nnoremap Y y$
 444 " copy to clipboard
 445 xnoremap Y "+y
 446
 447 " allow repeat operator on visual
 448 vnoremap . :normal .<CR>
 449
 450 " add line without changing position or leaving mode
 451 noremap <silent> <Leader>o :set paste<CR>m`o<ESC>``:set nopaste<CR>
 452 noremap <silent> <Leader>O :set paste<CR>m`O<ESC>``:set nopaste<CR>
 453
 454 " Don't use Ex mode, use Q for formatting
 455 map Q gq
 456
 457 " break undo sequence before removing word
 458 inoremap <C-W> <C-G>u<C-W>
 459
 460 nnoremap coe :set <C-R>=&expandtab ? 'noexpandtab' : 'expandtab'<CR><CR>
 461 nnoremap [oe :set expandtab<CR>
 462 nnoremap ]oe :set noexpandtab<CR>
 463
 464 for idt in range(1,8)
 465   exe 'nnoremap co'.idt.' :set tabstop='.idt.' shiftwidth='.idt.' softtabstop='.idt.'<CR>'
 466 endfor
 467
 468 " toggle auto format of text
 469 nnoremap coa :set <C-R>=&formatoptions =~ "a" ? 'formatoptions-=a' : 'formatoptions+=a'<CR><CR>
 470 nnoremap [oa :set formatoptions+=a<CR>
 471 nnoremap ]oa :set formatoptions-=a<CR>
 472
 473 " space will toggle current fold in normal mode
 474 nnoremap <leader><Space> za
 475 " create folds around visual selection
 476 vnoremap <leader><Space> zf
 477
 478 autocmd BufWinLeave *.* mkview
 479 autocmd BufWinEnter *.* silent loadview
 480
 481 " save with sudo
 482 cabbrev w!! w !sudo tee % > /dev/null
 483
 484 " uppercase previous word
 485 inoremap <C-C> <Esc>gUiwgi
 486
 487 " http://git.io/v3ZeU
 488 nmap <silent> <leader>qq :echo "hi<" . synIDattr(synID(line("."),col("."),1),"name") . '> trans<' . synIDattr(synID(line("."),col("."),0),"name") . "> lo<" . synIDattr(synIDtrans(synID(line("."),col("."),1)),"name") . ">"<CR>
 489
 490 " commands {{{1
 491 command! Cd cd %:h
 492 command! Cr execute('cd ' . FindGitDirOrHome())
 493 command! LCd lcd %:h
 494 command! LCr execute('lcd ' . FindGitDirOrHome())
 495
 496 " plugins options {{{1
 497 " airline {{{2
 498 let g:airline#extensions#whitespace#enabled = 1
 499 let g:airline#extensions#tabline#enabled = 1
 500 let g:airline_powerline_fonts = 1
 501
 502 " checkattach {{{2
 503 let g:checkattach_filebrowser = 'ranger'
 504 let g:checkattach_once = 'y'
 505
 506 " delimitmate {{{2
 507 let delimitMate_expand_cr = 2
 508 let g:delimitMate_expand_space = 1
 509
 510 " fswitch {{{2
 511 nnoremap <silent> <Leader>ff :FSHere<CR>
 512 nnoremap <silent> <Leader>fl :FSRight<CR>
 513 nnoremap <silent> <Leader>fh :FSLeft<CR>
 514 nnoremap <silent> <Leader>fj :FSBelow<CR>
 515 nnoremap <silent> <Leader>fk :FSAbove<CR>
 516 nnoremap <silent> <Leader>fL :FSSplitRight<CR>
 517 nnoremap <silent> <Leader>fH :FSSplitLeft<CR>
 518 nnoremap <silent> <Leader>fJ :FSSplitBelow<CR>
 519 nnoremap <silent> <Leader>fK :FSSplitAbove<CR>
 520
 521 " fugitive {{{2
 522 nmap <silent> <leader>dd :tab split \| Gdiff \| wincmd h<CR>
 523 " delete fugitive buffers when closed
 524 autocmd BufReadPost fugitive://* set bufhidden=delete
 525
 526 nnoremap <silent> <leader>gs :Gstatus<CR>
 527 nnoremap <silent> <leader>gd :Gdiff<CR>
 528 nnoremap <silent> <leader>gc :Gcommit -v<CR>
 529 nnoremap <silent> <leader>ga :Gwrite<cr>
 530 nnoremap <silent> <leader>gb :Gblame<cr>
 531
 532 " Gundo {{{2
 533 nnoremap <F7> :GundoToggle<CR>
 534
 535 " indent-guides {{{2
 536 let g:indent_guides_default_mapping = 0
 537 let g:indent_guides_guide_size = 1
 538 nmap <silent> cog <Plug>IndentGuidesToggle
 539 nmap <silent> [og <Plug>IndentGuidesEnable
 540 nmap <silent> ]og <Plug>IndentGuidesDisable
 541
 542 " python-mode {{{2
 543
 544 let g:pymode_rope_completion = 0
 545 let g:pymode_rope = 0
 546 let g:pymode_folding = 1
 547 let g:pymode_lint_ignore = "E221,E266,E501"
 548 let g:pymode_syntax_space_errors = 0    " don't bother me when I'm typing
 549
 550 " synastic {{{2
 551 let g:syntastic_enable_highlighting = 0
 552 let g:syntastic_error_symbol='E'
 553 let g:syntastic_style_error_symbol='S'
 554 let g:syntastic_warning_symbol='W'
 555 let g:syntastic_style_warning_symbol='S'
 556 let g:syntastic_always_populate_loc_list=1
 557 nmap <silent> <leader>y :SyntasticCheck<cr>
 558
 559 if ! &diff
 560   let g:syntastic_check_on_open=1
 561 endif
 562
 563 " tagbar {{{2
 564 map <F5> :TagbarToggle<cr>
 565 let g:tagbar_sort = 0
 566 let g:tagbar_compact = 1
 567 let g:tagbar_autoshowtag = 1
 568 let g:tagbar_width = 25
 569 let g:tagbar_iconchars = ['+', '-']
 570
 571 " ultisnips {{{2
 572 let g:UltiSnipsEditSplit = 'vertical'
 573 let g:UltiSnipsSnippetsDir = expand("$XDG_CONFIG_HOME/vim/ultisnips")
 574 if has('fname_case')
 575   let g:UltiSnipsSnippetDirectories = ["UltiSnips", "ultisnips"]
 576 endif
 577 let g:UltiSnipsExpandTrigger       = "<tab>"
 578 let g:UltiSnipsJumpForwardTrigger  = "<tab>"
 579 let g:UltiSnipsJumpBackwardTrigger = "<s-tab>"
 580
 581 " UltiSnips completion function that tries to expand a snippet. If there's no
 582 " snippet for expanding, it checks for completion window and if it's shown,
 583 " selects first element. If there's no completion window it tries to jump to
 584 " next placeholder. If there's no placeholder it just returns TAB key
 585 " https://github.com/Valloric/YouCompleteMe/issues/36#issuecomment-15451411
 586 function! g:UltiSnips_Complete()
 587     call UltiSnips#ExpandSnippet()
 588     if g:ulti_expand_res == 0
 589         if pumvisible()
 590             return "\<C-n>"
 591         else
 592             call UltiSnips#JumpForwards()
 593             if g:ulti_jump_forwards_res == 0
 594                return "\<TAB>"
 595             endif
 596         endif
 597     endif
 598     return ""
 599 endfunction
 600 au InsertEnter * exec "inoremap <silent> " . g:UltiSnipsExpandTrigger . " <C-R>=g:UltiSnips_Complete()<cr>"
 601 let g:UltiSnipsListSnippets="<c-e>"
 602
 603 " unite {{{2
 604 call unite#filters#matcher_default#use(['matcher_fuzzy'])
 605 call unite#custom#profile('default', 'context', {
 606             \ 'winheight': 20,
 607             \ 'direction': 'botright'
 608             \ })
 609
 610 nnoremap [unite] <Nop>
 611 nmap <leader>u [unite]
 612
 613 " unite-grep {{{3
 614 " seems not respected
 615 let g:unite_source_grep_max_candidates = 2000
 616 if executable('ag')
 617     " Use ag in unite grep source.
 618     let g:unite_source_grep_command = 'ag'
 619     let g:unite_source_grep_default_opts = '--smart-case -w --vimgrep --hidden --ignore ''.hg'' --ignore ''.svn'' --ignore ''.git'' --ignore ''.bzr'''
 620     let g:unite_source_grep_recursive_opt = ''
 621 end
 622 nnoremap <silent> [unite]a :<C-u>Unite grep:.::\12\17<CR>
 623 command! -nargs=1 Ag Unite grep -input=<args>
 624
 625 " unite-file_rec {{{3
 626 if executable('ag')
 627     " Use ag in unite rec source
 628     let g:unite_source_rec_async_command = 'ag --follow --nocolor --nogroup --hidden -g ""'
 629 end
 630 nnoremap <silent> [unite]f :<C-u>Unite -start-insert file_rec/async<CR>
 631
 632 " unite-buffer {{{3
 633 call unite#custom#default_action('buffer', 'goto')
 634 nnoremap <silent> [unite]b :<C-u>Unite buffer<CR>
 635
 636 " unite-menu {{{3
 637 let g:unite_source_menu_menus = {}
 638 let g:unite_source_menu_menus.fugitive = { 'description' : 'fugitive menu'}
 639 let g:unite_source_menu_menus.fugitive.command_candidates = {
 640             \ 'Gstatus <Leader>gs' : 'Gstatus',
 641             \ 'Gcommit -v <Leader>gc' : 'Gcommit -v',
 642             \ 'Glog' : 'Glog',
 643             \}
 644
 645 nnoremap <silent> <leader>gg :<C-u>Unite menu:fugitive<CR>
 646
 647 let g:unite_source_history_yank_enable = 1
 648 nnoremap <silent> [unite]p :<C-u>Unite history/yank<CR>
 649
 650 " yankring {{{2
 651 nnoremap <silent> <leader>p :YRShow<cr>
 652 let g:yankring_history_dir = expand('$XDG_CACHE_HOME/vim')
 653 let g:yankring_replace_n_pkey = ''
 654 let g:yankring_replace_n_nkey = ''
 655
 656 " map Y to y$ for the yank ring
 657 function! YRRunAfterMaps()
 658     nnoremap Y   :<C-U>YRYankCount 'y$'<CR>
 659 endfunction
 660
 661 " youcompleteme {{{2
 662 let g:ycm_extra_conf_globlist = ['~/src/*','/mnt/data/src/*']
 663 let g:ycm_global_ycm_extra_conf = expand('$XDG_CONFIG_HOME/vim/ycm_extra_conf.py')
 664 let g:ycm_extra_conf_vim_data = ['getcwd()']
 665 let g:ycm_add_preview_to_completeopt = 1
 666 let g:ycm_complete_in_comments = 1
 667 let g:ycm_complete_in_strings  = 1
 668 let g:ycm_autoclose_preview_window_after_insertion = 0
 669 "let g:ycm_extra_conf_vim_data = ['%:p']
 670 nnoremap gd :YcmCompleter GoTo<CR>
 671
 672 " vim-easy-align {{{2
 673 " start interactive EasyAlign in visual mode
 674 vmap <Enter> <Plug>(EasyAlign)
 675 nmap ga <Plug>(EasyAlign)
 676
 677 " vim-json {{{2
 678 let g:vim_json_syntax_conceal = 0
 679
 680 " vim-latex {{{2
 681 let g:tex_flavor='latex'
 682 let g:Tex_DefaultTargetFormat='pdf'
 683 let g:Tex_MultipleCompileFormats='pdf'
 684
 685 " vim-sneak {{{2
 686 let g:sneak#streak = 1
 687 let g:sneak#target_labels = "aoeuisnthdpylrcgfqjkxzmwvz" " dvorak
 688 let g:sneak#use_ic_scs = 1  " follow 'ignorecase' and 'smartcase'
 689
 690 " sneaky f and t
 691 nmap f <Plug>Sneak_f
 692 nmap F <Plug>Sneak_F
 693 xmap f <Plug>Sneak_f
 694 xmap F <Plug>Sneak_F
 695 omap f <Plug>Sneak_f
 696 omap F <Plug>Sneak_F
 697 nmap t <Plug>Sneak_t
 698 nmap T <Plug>Sneak_T
 699 xmap t <Plug>Sneak_t
 700 xmap T <Plug>Sneak_T
 701 omap t <Plug>Sneak_t
 702 omap T <Plug>Sneak_T
 703
 704 " functions {{{1
 705
 706 " Convenient command to see the difference between the current buffer and the
 707 " file it was loaded from, thus the changes you made.
 708 " Only define it when not defined already.
 709 if !exists(":DiffOrig")
 710   command DiffOrig vert new | set bt=nofile | r # | 0d_ | diffthis
 711                   \ | wincmd p | diffthis
 712 endif
 713
 714 " edit configs  {{{2
 715 function! EditConfig(what)
 716     let l:dir = split(&runtimepath,',')[0]
 717     if a:what == 'vimrc'
 718         let l:file = expand($MYVIMRC)
 719     elseif ! isdirectory(globpath(l:dir, a:what))
 720         echoe a:what." is not valid!"
 721     elseif empty(&filetype)
 722         echoe 'filetype is empty!'
 723     else
 724         let l:file = l:dir.'/'.a:what.'/'.&filetype.'.vim'
 725     endif
 726
 727     execute ':vsplit '.file
 728     execute ':lcd %:p:h'
 729 endf
 730 nmap <leader>ev :call EditConfig('vimrc')<CR>
 731 nmap <leader>ef :call EditConfig('ftplugin')<CR>
 732 nmap <leader>es :call EditConfig('syntax')<CR>
 733 nmap <leader>ei :call EditConfig('indent')<CR>
 734 nmap <leader>eu :UltiSnipsEdit<CR>:lcd %:p:h<CR>
 735
 736 " spell check {{{2
 737 " http://tex.stackexchange.com/a/52932
 738 let g:myLangList=["en_gb","en_us","de","fr"]
 739
 740 function! ToggleSpell()
 741   if !exists("b:myLang")
 742     let b:myLang=0
 743   endif
 744   execute "setlocal spell!"
 745   if (&spell)
 746     echo "setlocal spelllang=" g:myLangList[b:myLang]
 747   endif
 748 endfunction
 749
 750 function! SwitchSpell()
 751   if !exists("b:myLang")
 752     let b:myLang=0
 753   endif
 754   if (&spell)
 755     let b:myLang=b:myLang+1
 756     if b:myLang>=len(g:myLangList) | let b:myLang=0 | endif
 757   endif
 758   execute "setlocal spell spelllang=".get(g:myLangList, b:myLang)
 759   echo "setlocal spelllang=" g:myLangList[b:myLang]
 760 endfunction
 761
 762 nnoremap <silent> coS :call SwitchSpell()<CR>
 763 " fix spelling with first choice
 764 nnoremap <Leader>f 1z=
 765
 766 " gitdir or home {{{2
 767 " from derek wyatt:
 768 " http://git.io/v3GAV
 769 function! FindGitDirOrHome()
 770   let filedir = expand('%:p:h')
 771   if isdirectory(filedir)
 772     let cmd = 'bash -c "(cd ' . filedir . '; git rev-parse --show-toplevel 2>/dev/null)"'
 773     let gitdir = system(cmd)
 774     if strlen(gitdir) == 0
 775       return '~'
 776     else
 777       return gitdir[:-2]
 778     endif
 779   else
 780     return '~'
 781   endif
 782 endfunction
 783
 784 " vim:set et sw=2 ts=2 tw=78: