vim/vimrc

   1 " My vimrc.
   2 "
   3 " Author:   Samir Benmendil <samir.benmendil[at]gmail[dot]com>
   4 "
   5
   6 " plugins {{{1
   7 filetype off
   8 set runtimepath& " reset rtp
   9 " remove all autocommands
  10 autocmd!
  11
  12 set runtimepath+=$XDG_DATA_HOME/vim/vundle
  13 call vundle#begin('$XDG_DATA_HOME/vim')
  14
  15 Plugin 'gmarik/vundle'
  16
  17 Plugin 'AndrewRadev/switch.vim'
  18 Plugin 'airblade/vim-gitgutter'
  19 Plugin 'bling/vim-airline'
  20 Plugin 'chrisbra/checkattach'
  21 Plugin 'derekwyatt/vim-fswitch'
  22 Plugin 'elzr/vim-json'
  23 Plugin 'firef0x/pkgbuild.vim'
  24 Plugin 'junegunn/vim-easy-align'
  25 Plugin 'justinmk/vim-sneak'
  26 Plugin 'klen/python-mode'
  27 Plugin 'kshenoy/vim-signature'
  28 Plugin 'majutsushi/tagbar'
  29 Plugin 'octol/vim-cpp-enhanced-highlight'
  30 Plugin 'raimondi/delimitmate'
  31 Plugin 'rdnetto/ycm-generator'
  32 Plugin 'scrooloose/syntastic'
  33 Plugin 'shougo/unite.vim'
  34 Plugin 'shougo/vimproc.vim'
  35 Plugin 'sjl/gundo.vim'
  36 Plugin 'tomtom/tcomment_vim'
  37 Plugin 'tpope/vim-abolish'
  38 Plugin 'tpope/vim-endwise'
  39 Plugin 'tpope/vim-eunuch'
  40 Plugin 'tpope/vim-fugitive'
  41 Plugin 'tpope/vim-repeat'
  42 Plugin 'tpope/vim-surround'  "investigate vim-sandwich
  43 Plugin 'tpope/vim-unimpaired'
  44 Plugin 'tweekmonster/spellrotate.vim'
  45 Plugin 'valloric/youcompleteme'
  46 Plugin 'vim-scripts/mediawiki.vim'
  47 Plugin 'vim-scripts/replacewithregister'
  48 Plugin 'vim-scripts/yankring.vim'
  49
  50 " colorschemes
  51 Plugin 'flazz/vim-colorschemes'
  52
  53 " snippets
  54 Plugin 'sirver/ultisnips'
  55 Plugin 'honza/vim-snippets'
  56
  57 " text objects
  58 Plugin 'kana/vim-textobj-user'
  59 Plugin 'julian/vim-textobj-variable-segment'
  60 Plugin 'sgur/vim-textobj-parameter'
  61 Plugin 'kana/vim-operator-user'
  62
  63 " ros
  64 Plugin 'ompugao/ros.vim'
  65 Plugin 'ompugao/ctrlp-ros'
  66
  67 " staging
  68 " find an alternative (latex-box? Automatic Latex Plugin?)
  69 Plugin 'vim-latex/vim-latex'
  70 Plugin 'alx741/vinfo'
  71 Plugin 'derekwyatt/vim-protodef'
  72 " needs editing colorscheme
  73 " Plugin 'jeaye/color_coded'
  74 " Check LucHermites plugins: https://github.com/LucHermitte/lh-cpp
  75
  76 call vundle#end()
  77
  78 " remove entries first
  79 set runtimepath -=$HOME/.vim
  80 set runtimepath -=$HOME/.vim/after
  81 set runtimepath -=$XDG_CONFIG_HOME/vim
  82 set runtimepath -=$XDG_CONFIG_HOME/vim/after
  83 " then prepend and append them
  84 set runtimepath ^=$XDG_CONFIG_HOME/vim
  85 set runtimepath +=$XDG_CONFIG_HOME/vim/after
  86
  87 filetype plugin indent on
  88
  89 " colorscheme {{{1
  90 syntax on
  91 colorscheme badfox
  92
  93 " options {{{1
  94 " moving around, searching and patterns {{{2
  95 set incsearch           " show match for partly typed search command
  96 set ignorecase          " ignore case when using a search pattern
  97 set smartcase           " override 'ignorecase' when pattern has upper case characters
  98 set hlsearch            " highlight all matches for the last used search pattern
  99
 100 set nostartofline       " don't move the cursor to the first non-blank char of a line
 101 set path+=.
 102 set path+=include/
 103 set path+=../include/
 104 set path+=/usr/include/c++/*
 105
 106 " displaying text {{{2
 107 set nowrap                      " long lines wrap
 108 set linebreak                   " wrap long lines at a character in 'breakat'
 109 set showbreak=↪                 " show these chars for wrapped lines
 110 set breakindent                 " preserve indentation in wrapped text
 111
 112 set lazyredraw                  " don't redraw while executing macros
 113
 114 set list                        " show chars defined in 'listchars'
 115 set listchars=tab:❭\            " list of strings used for list mode
 116 set listchars+=extends:❯,precedes:❮
 117 " Only shown when not in insert mode
 118 au InsertLeave * :set listchars+=trail:·
 119 augroup trailing
 120     au!
 121     au InsertEnter * :set listchars-=trail:·
 122     au InsertLeave * :set listchars+=trail:·
 123 augroup END
 124
 125 set scrolloff=5                 " number of screen lines to show around the cursor
 126 set sidescroll=1                " number of collumns to scroll
 127 set sidescrolloff=1             " don't scroll over the listchars
 128
 129 set fillchars=diff:⣿,vert:│
 130
 131 set nonumber                    " show the line number for each line
 132 set norelativenumber            " show the relative line number for each line
 133
 134 " syntax, highlighting and spelling {{{2
 135 set synmaxcol=800               " don't highlight long lines
 136
 137 set dictionary=spell            " list of dictionary files for keyword completion
 138
 139 set colorcolumn=+1
 140
 141 " multiple windows {{{2
 142 set laststatus=2                " 0, 1 or 2; when to use a status line for the last window
 143
 144 set previewheight=20            " default height for the preview window
 145
 146 set hidden
 147
 148 " set splitbelow                  " a new window is put below of the current one
 149 set splitright                  " a new window is put right of the current one
 150
 151 " terminal {{{2
 152 set ttyfast
 153
 154 " using the mouse {{{2
 155 set mouse=rnv                   " list of flags for using the mouse
 156 set ttymouse=xterm              " type of mouse
 157
 158 " messages and info {{{2
 159 set showcmd         " Show (partial) command in status line.
 160 set ruler           " show the cursor position all the time
 161 set confirm         " Ask what to do when closing unsaved documents
 162 set shortmess=      " reset option
 163 set shortmess+=a    " all abbreviations
 164 set shortmess+=o    " overwrite file-written message
 165 set shortmess+=O    " file-read message overrides previous
 166 set shortmess+=t    " truncate file message at start
 167 set shortmess+=T    " truncate other messages in the middle
 168 set shortmess+=W    " don't give 'written' or '[w]' when writing a file
 169 set shortmess+=A    " ignore swapfile warning
 170 set shortmess+=I    " no splash screen
 171
 172 " editing text {{{2
 173 set backspace=indent,eol,start  " allow backspacing over everything in insert mode
 174
 175 set showmatch                   " Show matching brackets.
 176
 177 set nojoinspaces                " don't use two spaces after '.' when joining a line
 178 set formatoptions+=j    " Delete comment leader when joining lines
 179 set formatoptions+=c    " Autowrap comments using textwidth
 180 set formatoptions+=r    " Insert comment leader after hitting <Enter>
 181 set formatoptions+=n    " Recognize numbered lists
 182 set formatoptions+=q    " Allow formatting of comments with "gq".
 183 set formatoptions+=l    " do not wrap lines that have been longer when starting insert mode already
 184 set formatoptions+=t    " Auto-wrap text using textwidth
 185 set formatoptions-=o    " Do not insert comment leader after hitting o or O in normal mode
 186
 187 set nrformats=hex               " number formats recognized for CTRL-A and CTRL-X commands
 188
 189 set complete=.       " scan the current buffer ( 'wrapscan' is ignored)
 190 set complete+=w      " scan buffers from other windows
 191 set complete+=b      " scan other loaded buffers that are in the buffer list
 192 set complete+=u      " scan the unloaded buffers that are in the buffer list
 193 set complete+=t      " scan tags
 194 set complete+=i      " scan current and included files
 195 set complete+=kspell " use the currently active spell checking |spell|
 196
 197 " whether to use a popup menu for Insert mode completion
 198 set completeopt=longest,menuone,preview
 199
 200 " tabs and indent {{{2
 201 set shiftwidth=4                " number of spaces used for each step of (auto)indent
 202 set smarttab                    " a <Tab> in an indent inserts 'shiftwidth' spaces
 203 set softtabstop=4               " if non-zero, number of spaces to insert for a <Tab>
 204 set shiftround                  " round to 'shiftwidth' for "<<" and ">>"
 205 set expandtab                   " expand <Tab> to spaces in Insert mode
 206 set autoindent
 207
 208 set pastetoggle=<F11>           " key sequence to toggle paste mode
 209
 210 " folding {{{2
 211 set foldmethod=marker           " folding type
 212 set foldlevelstart=0            " value for 'foldlevel' when starting to edit a file
 213
 214 " open folds when jumping to line
 215 set foldopen+=jump
 216
 217 " save and restore folds
 218 set viewoptions=cursor          " only save cursor position
 219
 220 " diff mode {{{2
 221 set diffopt+=filler         " show filler lines
 222 set diffopt+=vertical       " always vertical split
 223 set diffopt+=context:10     " 10 lines context between changes
 224
 225 " reading and writing files {{{2
 226 set modeline                    " read modelines
 227 set modelines=2                 " only check first/last 2 lines
 228
 229 set writebackup                 " write a backup file before overwriting a file
 230 set backup                      " keep a backup after owerwriting a file
 231 set backupdir=$XDG_CACHE_HOME/vim/backup//
 232
 233 set backupskip+=.netrc          " skip netrc
 234 set backupskip+=/dev/shm/pass*  " skip passwordstore files
 235
 236 set undofile                    " persistent undo history
 237 set undodir=$XDG_CACHE_HOME/vim/undo//
 238
 239 augroup undoskip
 240     au!
 241     au BufWritePre .netrc         setlocal noundofile
 242     au BufWritePre /dev/shm/pass* setlocal noundofile
 243     au BufWritePre /tmp/*         setlocal noundofile
 244 augroup END
 245
 246 set autowrite                   " automatically write a file when leaving a modified buffer
 247 set autoread                    " automatically read a file that has been modified
 248
 249 " the swap file {{{2
 250 set noswapfile
 251 set directory=$XDG_CACHE_HOME/vim/swap//
 252
 253 " command line editing {{{2
 254 set history=5000                " how many command lines are remembered
 255 set wildmenu                    " command-line completion shows a list of matches
 256 set wildmode=longest:full,full  " specifies how command line completion works
 257 set wildignorecase              " ignore case when completing file names
 258
 259 set wildignore+=.hg,.git,.svn                    " Version control
 260 set wildignore+=*.aux,*.out,*.toc                " LaTeX intermediate files
 261 set wildignore+=*.jpg,*.bmp,*.gif,*.png,*.jpeg   " binary images
 262 set wildignore+=*.o,*.obj,*.exe,*.dll,*.manifest " compiled object files
 263 set wildignore+=*.spl                            " compiled spelling word lists
 264 set wildignore+=*.sw?                            " Vim swap files
 265 set wildignore+=*.luac                           " Lua byte code
 266 set wildignore+=*.pyc                            " Python byte code
 267 set wildignore+=*.orig                           " Merge resolution files
 268
 269 " running make and jumping to errors {{{2
 270 set makeprg=make\ -w     " print changing directories
 271
 272 set grepprg=ag\ --vimgrep\ $*
 273
 274 " language specific {{{2
 275 set isfname-==    " don't treat `=` as being part of filenames
 276
 277 " various {{{2
 278 set virtualedit+=block     " let cursor move past last char in <C-V> mode
 279 set virtualedit+=onemore   " allow the cursor to move just past the end of the line
 280 set viminfo='100,<50,s10,h,n$XDG_CACHE_HOME/vim/viminfo " viminfo defaults but save file in .cache
 281
 282 set viewdir=$XDG_CACHE_HOME/vim/view//
 283
 284 set sessionoptions+=unix,slash  " damn windows and it's silly ways
 285
 286 " autocmds {{{1
 287 " Resize splits when the window is resized {{{2
 288 augroup resize
 289     au!
 290     autocmd VimResized * :wincmd =
 291 augroup END
 292
 293 " Only show cursorline in the current window and in normal mode {{{2
 294 augroup cline
 295     au!
 296     au WinLeave,InsertEnter * set nocursorline
 297     au WinEnter,InsertLeave * set cursorline
 298 augroup END
 299
 300 " Treat buffers from stdin (e.g.: echo foo | vim -) as scratch {{{2
 301 augroup ft_stdin
 302     au!
 303     au StdinReadPost * :set buftype=nofile
 304 augroup END
 305
 306 " Jump to last known cursor position {{{2
 307 augroup cursor_pos
 308     au!
 309     " blacklist certain filetype
 310     let blacklist = ['gitcommit']
 311     autocmd BufReadPost *
 312                 \ if index(blacklist, &ft) < 0 && line("'\"") > 1 && line("'\"") <= line("$") |
 313                 \   exe "normal! g`\"" |
 314                 \ endif
 315 augroup END
 316
 317 " Check for file modifications automatically {{{2
 318 " (current buffer only)
 319 " Use :NoAutoChecktime to disable it (uses b:autochecktime)
 320 fun! MyAutoCheckTime()
 321   " only check timestamp for normal files
 322   if &buftype != '' | return | endif
 323   if ! exists('b:autochecktime') || b:autochecktime
 324     checktime %
 325     let b:autochecktime = 1
 326   endif
 327 endfun
 328 augroup MyAutoChecktime
 329   au!
 330   au FocusGained,BufEnter,CursorHold,InsertEnter * call MyAutoCheckTime()
 331 augroup END
 332 command! NoAutoChecktime let b:autochecktime=0
 333 command! ToggleAutoChecktime let b:autochecktime=!get(b:, 'autochecktime', 0) | echom "b:autochecktime:" b:autochecktime
 334
 335 " bindings {{{1
 336
 337 " allow both <space> and \ to be <leader>
 338 map <space> <leader>
 339
 340 " make
 341 nnoremap <leader>r :make!<cr>
 342 nnoremap <leader><cr> :make!<cr>
 343
 344 " unhighlight search
 345 nnoremap <silent> <Leader>/ :silent nohl<CR>
 346
 347 " Tabs
 348 nnoremap <leader>[ :tabprev<cr>
 349 nnoremap <leader>] :tabnext<cr>
 350
 351 " paste from selection
 352 nnoremap <leader>p* :silent! set paste<CR>"*p:set nopaste<CR>
 353 " paste from clipboard
 354 nnoremap <leader>p+ :silent! set paste<CR>"+p:set nopaste<CR>
 355
 356 " strip trailing whitespace
 357 function! StripWhitespace(line1, line2, ...)  " {{{2
 358   let s_report = &report
 359   let &report=0
 360   let pattern = a:0 ? a:1 : '\s\+$'
 361   let oldview = winsaveview()
 362   exe 'keepjumps keeppatterns '.a:line1.','.a:line2.'substitute/'.pattern.'//e'
 363   if oldview != winsaveview()
 364     redraw
 365   endif
 366   call winrestview(oldview)
 367   let &report = s_report
 368 endfunction  " }}}2
 369 command! -range=% -nargs=0 -bar Untrail keepjumps call StripWhitespace(<line1>,<line2>)
 370 nnoremap <silent> <leader>ww :Untrail<CR>
 371
 372 " Source
 373 vnoremap <leader>S y:execute @@<cr>:echo 'Sourced selection.'<cr>
 374 nnoremap <leader>S ^vg_y:execute @@<cr>:echo 'Sourced line.'<cr>
 375
 376 " jump to last cursor position
 377 noremap ' `
 378
 379 " Select (charwise) the contents of the current line, excluding indentation.
 380 nnoremap vv ^vg_
 381
 382 " Unfuck my screen
 383 nnoremap U :syntax sync fromstart<cr>:AirlineRefresh<cr>:redraw!<cr>
 384
 385 " Ranger
 386 " nnoremap <leader>r :silent !ranger %:h<cr>:redraw!<cr>
 387 " nnoremap <leader>R :silent !ranger<cr>:redraw!<cr>
 388
 389 " Use sane regexes.
 390 nnoremap / /\v
 391 vnoremap / /\v
 392 cnoremap s/ s/\v
 393
 394 " display the number of matches for the last search
 395 nmap <Leader># :%s:<C-R>/::gn<CR>
 396
 397 " center cursor after search and open folds
 398 nnoremap n nzzzv
 399 nnoremap N Nzzzv
 400
 401 " same when jumping around
 402 nnoremap g; g;zzzv
 403 nnoremap g, g,zzzv
 404 nnoremap <c-o> <c-o>zzzv
 405 nnoremap <c-i> <c-i>zzzv
 406
 407 " Not using the default mappings of 'To line from top/bottom'
 408 noremap H ^
 409 noremap L $
 410 vnoremap H ^
 411 vnoremap L g_
 412
 413 " Heresy, emacs insert bindings
 414 inoremap <C-A> <Esc>I
 415 inoremap <C-E> <Esc>A
 416 cnoremap <C-A> <Home>
 417 cnoremap <C-E> <End>
 418
 419 " proper movement when lines are wrapped
 420 noremap <expr> j (v:count == 0 ? 'gj' : 'j')
 421 noremap <expr> k (v:count == 0 ? 'gk' : 'k')
 422
 423 " disable arrows
 424 noremap  <Up>    <NOP>
 425 noremap  <Down>  <NOP>
 426 noremap  <Left>  <NOP>
 427 noremap  <Right> <NOP>
 428 inoremap <Up>    <NOP>
 429 inoremap <Down>  <NOP>
 430 inoremap <Left>  <NOP>
 431 inoremap <Right> <NOP>
 432 cnoremap <Up>    <NOP>
 433 cnoremap <Down>  <NOP>
 434 cnoremap <Left>  <NOP>
 435 cnoremap <Right> <NOP>
 436 cnoremap <C-K>   <Up>
 437 cnoremap <C-J>   <Down>
 438 cnoremap <C-H>   <Left>
 439 cnoremap <C-L>   <Right>
 440
 441 " close all folds open fold in cursor
 442 nnoremap zx zMzxzt
 443
 444 map <F1> :ls<CR>:b<space>
 445
 446 " move between windows
 447 nnoremap <C-L> <C-W>w
 448 nnoremap <C-H> <C-W>W
 449
 450 "xterm mouse with middleclick paste
 451 nnoremap <MiddleMouse> i<MiddleMouse>
 452 vnoremap <MiddleMouse> s<MiddleMouse>
 453
 454 " fix legacy vi inconsistency
 455 nnoremap Y y$
 456 " copy to clipboard
 457 xnoremap Y "+y
 458
 459 " allow repeat operator on visual
 460 vnoremap . :normal .<CR>
 461
 462 " add line without changing position or leaving mode
 463 noremap <silent> <Leader>o :set paste<CR>m`o<ESC>``:set nopaste<CR>
 464 noremap <silent> <Leader>O :set paste<CR>m`O<ESC>``:set nopaste<CR>
 465
 466 " Don't use Ex mode, use Q for formatting
 467 map Q gq
 468
 469 " break undo sequence before removing word
 470 inoremap <C-W> <C-G>u<C-W>
 471
 472 nnoremap coe :set <C-R>=&expandtab ? 'noexpandtab' : 'expandtab'<CR><CR>
 473 nnoremap [oe :set expandtab<CR>
 474 nnoremap ]oe :set noexpandtab<CR>
 475
 476 for idt in range(1,8)
 477   exe 'nnoremap co'.idt.' :set tabstop='.idt.' shiftwidth='.idt.' softtabstop='.idt.'<CR>'
 478 endfor
 479
 480 " toggle auto format of text
 481 nnoremap coa :set <C-R>=&formatoptions =~ "a" ? 'formatoptions-=a' : 'formatoptions+=a'<CR><CR>
 482 nnoremap [oa :set formatoptions+=a<CR>
 483 nnoremap ]oa :set formatoptions-=a<CR>
 484
 485 " space will toggle current fold in normal mode
 486 nnoremap <leader><Space> za
 487 " create folds around visual selection
 488 vnoremap <leader><Space> zf
 489
 490 autocmd BufWinLeave *.* mkview
 491 autocmd BufWinEnter *.* silent loadview
 492
 493 " save with sudo
 494 cabbrev w!! w !sudo tee % > /dev/null
 495
 496 " uppercase previous word
 497 inoremap <C-C> <Esc>gUiwgi
 498
 499 " http://git.io/v3ZeU
 500 nmap <silent> <leader>qq :echo "hi<" . synIDattr(synID(line("."),col("."),1),"name") . '> trans<' . synIDattr(synID(line("."),col("."),0),"name") . "> lo<" . synIDattr(synIDtrans(synID(line("."),col("."),1)),"name") . ">"<CR>
 501
 502 " plugins options {{{1
 503 " airline {{{2
 504 let g:airline#extensions#whitespace#enabled = 1
 505 let g:airline#extensions#tabline#enabled = 1
 506 let g:airline_powerline_fonts = 1
 507
 508 " checkattach {{{2
 509 let g:checkattach_filebrowser = 'ranger'
 510 let g:checkattach_once = 'y'
 511
 512 " delimitmate {{{2
 513 let delimitMate_expand_cr = 2
 514 let g:delimitMate_expand_space = 1
 515
 516 " fswitch {{{2
 517 nnoremap <silent> <Leader>ff :FSHere<CR>
 518 nnoremap <silent> <Leader>fl :FSRight<CR>
 519 nnoremap <silent> <Leader>fh :FSLeft<CR>
 520 nnoremap <silent> <Leader>fj :FSBelow<CR>
 521 nnoremap <silent> <Leader>fk :FSAbove<CR>
 522 nnoremap <silent> <Leader>fL :FSSplitRight<CR>
 523 nnoremap <silent> <Leader>fH :FSSplitLeft<CR>
 524 nnoremap <silent> <Leader>fJ :FSSplitBelow<CR>
 525 nnoremap <silent> <Leader>fK :FSSplitAbove<CR>
 526
 527 " fugitive {{{2
 528 nmap <silent> <leader>dd :tab split \| Gdiff \| wincmd h<CR>
 529 " delete fugitive buffers when closed
 530 autocmd BufReadPost fugitive://* set bufhidden=delete
 531
 532 nnoremap <silent> <leader>gs :Gstatus<CR>
 533 nnoremap <silent> <leader>gd :Gdiff<CR>
 534 nnoremap <silent> <leader>gc :Gcommit -v<CR>
 535 nnoremap <silent> <leader>ga :Gwrite<cr>
 536 nnoremap <silent> <leader>gb :Gblame<cr>
 537
 538 " Gundo {{{2
 539 nnoremap <F7> :GundoToggle<CR>
 540
 541 " indent-guides {{{2
 542 let g:indent_guides_default_mapping = 0
 543 let g:indent_guides_guide_size = 1
 544 nmap <silent> cog <Plug>IndentGuidesToggle
 545 nmap <silent> [og <Plug>IndentGuidesEnable
 546 nmap <silent> ]og <Plug>IndentGuidesDisable
 547
 548 " close-another-window {{{2
 549 nnoremap <silent> <C-W>c  <NOP>
 550 nnoremap <silent> <C-W>cc <C-W>c
 551 nnoremap <silent> <C-W>ch :CloseLeftWindow<CR>
 552 nnoremap <silent> <C-W>cl :CloseRightWindow<CR>
 553 nnoremap <silent> <C-W>cj :CloseBelowWindow<CR>
 554 nnoremap <silent> <C-W>ck :CloseAboveWindow<CR>
 555
 556 " python-mode {{{2
 557
 558 let g:pymode_rope_completion = 0
 559 let g:pymode_rope = 0
 560 let g:pymode_run = 0
 561 let g:pymode_folding = 1
 562 let g:pymode_lint_ignore = "E221,E266,E501"
 563 let g:pymode_lint_cwindow = 0           " don't open cwindow when linting
 564 let g:pymode_syntax_space_errors = 0    " don't bother me when I'm typing
 565
 566 " signature {{{2
 567 " disable '[ mappings
 568
 569 let g:SignatureMap = {
 570   \ 'GotoNextLineAlpha'  :  "",
 571   \ 'GotoPrevLineAlpha'  :  "",
 572   \ 'GotoNextSpotAlpha'  :  "",
 573   \ 'GotoPrevSpotAlpha'  :  "",
 574   \ }
 575
 576 " switch
 577 let g:switch_mapping = "<Leader>s"
 578
 579 " spellrotate
 580 nmap <silent> z] <Plug>(SpellRotateForward)
 581 nmap <silent> z[ <Plug>(SpellRotateBackward)
 582 vmap <silent> z] <Plug>(SpellRotateForwardV)
 583 vmap <silent> z[ <Plug>(SpellRotateBackwardV)
 584
 585 " synastic {{{2
 586 let g:syntastic_enable_highlighting = 0
 587 let g:syntastic_error_symbol='E'
 588 let g:syntastic_style_error_symbol='S'
 589 let g:syntastic_warning_symbol='W'
 590 let g:syntastic_style_warning_symbol='S'
 591 let g:syntastic_always_populate_loc_list=1
 592 nmap <silent> <leader>y :SyntasticCheck<cr>
 593
 594 if ! &diff
 595   let g:syntastic_check_on_open=1
 596 endif
 597
 598 " tagbar {{{2
 599 map <F5> :TagbarToggle<cr>
 600 let g:tagbar_sort = 0
 601 let g:tagbar_compact = 1
 602 let g:tagbar_autoshowtag = 1
 603 let g:tagbar_width = 25
 604 let g:tagbar_iconchars = ['+', '-']
 605
 606 " tcomments {{{2
 607 let g:tcommentTextObjectInlineComment = 'gic'
 608
 609 " ultisnips {{{2
 610 let g:UltiSnipsEditSplit = 'vertical'
 611 let g:UltiSnipsSnippetsDir = expand("$XDG_CONFIG_HOME/vim/ultisnips")
 612 if has('fname_case')
 613   let g:UltiSnipsSnippetDirectories = ["UltiSnips", "ultisnips"]
 614 endif
 615 let g:UltiSnipsExpandTrigger       = "<tab>"
 616 let g:UltiSnipsJumpForwardTrigger  = "<tab>"
 617 let g:UltiSnipsJumpBackwardTrigger = "<s-tab>"
 618
 619 " UltiSnips completion function that tries to expand a snippet. If there's no
 620 " snippet for expanding, it checks for completion window and if it's shown,
 621 " selects first element. If there's no completion window it tries to jump to
 622 " next placeholder. If there's no placeholder it just returns TAB key
 623 " https://github.com/Valloric/YouCompleteMe/issues/36#issuecomment-15451411
 624 function! g:UltiSnips_Complete()
 625     call UltiSnips#ExpandSnippet()
 626     if g:ulti_expand_res == 0
 627         if pumvisible()
 628             return "\<C-n>"
 629         else
 630             call UltiSnips#JumpForwards()
 631             if g:ulti_jump_forwards_res == 0
 632                return "\<TAB>"
 633             endif
 634         endif
 635     endif
 636     return ""
 637 endfunction
 638 au InsertEnter * exec "inoremap <silent> " . g:UltiSnipsExpandTrigger . " <C-R>=g:UltiSnips_Complete()<cr>"
 639 let g:UltiSnipsListSnippets="<c-e>"
 640
 641 " unite {{{2
 642 call unite#filters#matcher_default#use(['matcher_fuzzy'])
 643 call unite#custom#profile('default', 'context', {
 644             \ 'winheight': 20,
 645             \ 'direction': 'botright'
 646             \ })
 647
 648 nnoremap [unite] <Nop>
 649 nmap <leader>u [unite]
 650 nnoremap [unite]u :UniteResume<CR>
 651
 652 " unite-grep {{{3
 653 " seems not respected
 654 let g:unite_source_grep_max_candidates = 2000
 655 if executable('ag')
 656     " Use ag in unite grep source.
 657     let g:unite_source_grep_command = 'ag'
 658     let g:unite_source_grep_default_opts = '--smart-case --vimgrep --hidden --ignore ''.hg'' --ignore ''.svn'' --ignore ''.git'' --ignore ''.bzr'''
 659     let g:unite_source_grep_recursive_opt = ''
 660 end
 661 nnoremap <silent> [unite]a :<C-u>Unite grep:.::\12\17<CR>
 662 command! -nargs=1 Ag Unite grep:.::<args>
 663
 664 " unite-file_rec {{{3
 665 if executable('ag')
 666     " Use ag in unite rec source
 667     let g:unite_source_rec_async_command = 'ag --follow --nocolor --nogroup --hidden -g ""'
 668 end
 669 nnoremap <silent> [unite]f :<C-u>Unite -start-insert file_rec/async<CR>
 670 call unite#custom#source('file_rec/async', 'sorters', 'sorter_selecta')
 671
 672 " unite-buffer {{{3
 673 call unite#custom#default_action('buffer', 'open')
 674 nnoremap <silent> [unite]b :<C-u>Unite buffer:-<CR>
 675
 676 " unite-menu {{{3
 677 let g:unite_source_menu_menus = {}
 678 let g:unite_source_menu_menus.fugitive = { 'description' : 'fugitive menu'}
 679 let g:unite_source_menu_menus.fugitive.command_candidates = {
 680             \ 'Gstatus <Leader>gs' : 'Gstatus',
 681             \ 'Gcommit -v <Leader>gc' : 'Gcommit -v',
 682             \ 'Glog' : 'Glog',
 683             \}
 684
 685 nnoremap <silent> <leader>gg :<C-u>Unite menu:fugitive<CR>
 686
 687 let g:unite_source_history_yank_enable = 1
 688 nnoremap <silent> [unite]p :<C-u>Unite history/yank<CR>
 689
 690 " yankring {{{2
 691 nnoremap <silent> <leader>p :YRShow<cr>
 692 let g:yankring_history_dir = expand('$XDG_CACHE_HOME/vim')
 693 let g:yankring_replace_n_pkey = ''
 694 let g:yankring_replace_n_nkey = ''
 695
 696 " map Y to y$ for the yank ring
 697 function! YRRunAfterMaps()
 698     nnoremap Y   :<C-U>YRYankCount 'y$'<CR>
 699 endfunction
 700
 701 " youcompleteme {{{2
 702 let g:ycm_extra_conf_globlist = ['~/src/*','/mnt/data/src/*']
 703 let g:ycm_global_ycm_extra_conf = expand('$XDG_CONFIG_HOME/vim/ycm_extra_conf.py')
 704 let g:ycm_extra_conf_vim_data = ['getcwd()']
 705 let g:ycm_add_preview_to_completeopt = 1
 706 let g:ycm_complete_in_comments = 1
 707 let g:ycm_complete_in_strings  = 1
 708 let g:ycm_autoclose_preview_window_after_insertion = 0
 709 "let g:ycm_extra_conf_vim_data = ['%:p']
 710
 711 " vim-easy-align {{{2
 712 " start interactive EasyAlign in visual mode
 713 vmap <Enter> <Plug>(EasyAlign)
 714 nmap ga <Plug>(EasyAlign)
 715
 716 " vim-json {{{2
 717 let g:vim_json_syntax_conceal = 0
 718
 719 " vim-latex {{{2
 720 let g:tex_flavor='latex'
 721 let g:Tex_DefaultTargetFormat='pdf'
 722 let g:Tex_MultipleCompileFormats='pdf'
 723
 724 " vim-sneak {{{2
 725 let g:sneak#streak = 1
 726 let g:sneak#target_labels = "aoeuisnthdpylrcgfqjkxzmwvz" " dvorak
 727 let g:sneak#use_ic_scs = 1  " follow 'ignorecase' and 'smartcase'
 728
 729 " sneaky f and t
 730 nmap f <Plug>Sneak_f
 731 nmap F <Plug>Sneak_F
 732 xmap f <Plug>Sneak_f
 733 xmap F <Plug>Sneak_F
 734 omap f <Plug>Sneak_f
 735 omap F <Plug>Sneak_F
 736 nmap t <Plug>Sneak_t
 737 nmap T <Plug>Sneak_T
 738 xmap t <Plug>Sneak_t
 739 xmap T <Plug>Sneak_T
 740 omap t <Plug>Sneak_t
 741 omap T <Plug>Sneak_T
 742
 743 " functions {{{1
 744
 745 " Convenient command to see the difference between the current buffer and the
 746 " file it was loaded from, thus the changes you made.
 747 " Only define it when not defined already.
 748 if !exists(":DiffOrig")
 749   command DiffOrig vert new | set bt=nofile | r # | 0d_ | diffthis
 750                   \ | wincmd p | diffthis
 751 endif
 752
 753 " sort operator {{{2
 754 function! SortLinesOpFunc(...)
 755   '[,']sort
 756 endfunction
 757 nnoremap <silent> gs :<C-U>set operatorfunc=SortLinesOpFunc<CR>g@
 758 vnoremap <silent> gs :sort<cr>
 759
 760 " edit configs  {{{2
 761 function! EditConfig(what)
 762     let l:dir = split(&runtimepath,',')[0]
 763     if a:what == 'vimrc'
 764         let l:file = expand($MYVIMRC)
 765     elseif ! isdirectory(globpath(l:dir, a:what))
 766         echoe a:what." is not valid!"
 767     elseif empty(&filetype)
 768         echoe 'filetype is empty!'
 769     else
 770         let l:file = l:dir.'/'.a:what.'/'.&filetype.'.vim'
 771     endif
 772
 773     execute ':vsplit '.file
 774     execute ':lcd %:p:h'
 775 endf
 776 nmap <leader>ev :call EditConfig('vimrc')<CR>
 777 nmap <leader>ef :call EditConfig('ftplugin')<CR>
 778 nmap <leader>es :call EditConfig('syntax')<CR>
 779 nmap <leader>ei :call EditConfig('indent')<CR>
 780 nmap <leader>eu :UltiSnipsEdit<CR>:lcd %:p:h<CR>
 781
 782 " spell check {{{2
 783 " http://tex.stackexchange.com/a/52932
 784 let g:myLangList=["en_gb","en_us","de","fr"]
 785
 786 function! ToggleSpell()
 787   if !exists("b:myLang")
 788     let b:myLang=0
 789   endif
 790   execute "setlocal spell!"
 791   if (&spell)
 792     echo "setlocal spelllang=" g:myLangList[b:myLang]
 793   endif
 794 endfunction
 795
 796 function! SwitchSpell()
 797   if !exists("b:myLang")
 798     let b:myLang=0
 799   endif
 800   if (&spell)
 801     let b:myLang=b:myLang+1
 802     if b:myLang>=len(g:myLangList) | let b:myLang=0 | endif
 803   endif
 804   execute "setlocal spell spelllang=".get(g:myLangList, b:myLang)
 805   echo "setlocal spelllang=" g:myLangList[b:myLang]
 806 endfunction
 807
 808 nnoremap <silent> coS :call SwitchSpell()<CR>
 809 " fix spelling with first choice
 810 nnoremap <Leader>f 1z=
 811
 812 " gitdir or home {{{2
 813 " from derek wyatt:
 814 " http://git.io/v3GAV
 815 function! FindGitDirOrHome()
 816   let filedir = expand('%:p:h')
 817   if isdirectory(filedir)
 818     let cmd = 'bash -c "(cd ' . filedir . '; git rev-parse --show-toplevel 2>/dev/null)"'
 819     let gitdir = system(cmd)
 820     if strlen(gitdir) == 0
 821       return '~'
 822     else
 823       return gitdir[:-2]
 824     endif
 825   else
 826     return '~'
 827   endif
 828 endfunction
 829 command! Cd cd %:h
 830 command! Cr execute('cd ' . FindGitDirOrHome())
 831 command! LCd lcd %:h
 832 command! LCr execute('lcd ' . FindGitDirOrHome())
 833
 834 " vim:set et sw=2 ts=2 tw=78: