vim/vimrc

   1 " force python3
   2 if has('python3') | endif
   3
   4 " space is leader
   5 let g:mapleader = " "
   6
   7 " runtimepath {{{1
   8 set runtimepath ^=$XDG_CONFIG_HOME/vim
   9 set runtimepath +=$XDG_CONFIG_HOME/vim/after
  10
  11 " plugins {{{1
  12 call plug#begin('$XDG_DATA_HOME/vim')
  13 " This does not update vim-plug, use PlugUpgrade instead
  14 Plug 'junegunn/vim-plug'
  15
  16 Plug 'airblade/vim-gitgutter' " {{{
  17 " prefer other signs such as ycm diags
  18 let g:gitgutter_sign_priority = 1
  19 " don't clobber other signs
  20 let g:gitgutter_sign_allow_clobber = 0
  21 "}}}
  22 Plug 'alepez/vim-gtest'
  23 Plug 'alx741/vinfo'
  24 Plug 'andrewradev/sideways.vim' " {{{2
  25 nnoremap <silent> ,h :SidewaysLeft<CR>:delmarks z<CR>
  26 nnoremap <silent> ,l :SidewaysRight<CR>:delmarks z<CR>
  27 "}}}
  28 Plug 'andrewradev/switch.vim'
  29 if !has('nvim')
  30   Plug 'bling/vim-airline' "{{{2
  31   let g:airline#extensions#whitespace#enabled = 1
  32   let g:airline#extensions#tabline#enabled = 1
  33   let g:airline#extensions#searchcount#enabled = 0
  34   let g:airline_powerline_fonts = 1
  35
  36   let g:asyncrun_status = "stopped"
  37   " let g:airline_section_error = airline#section#create_right(['%{g:asyncrun_status}'])
  38   "}}}
  39 endif
  40
  41 Plug 'chrisbra/checkattach'
  42 Plug 'derekwyatt/vim-fswitch'
  43 Plug 'elzr/vim-json'
  44 Plug 'firef0x/pkgbuild.vim'
  45 Plug 'junegunn/vim-easy-align'
  46 Plug 'justinmk/vim-sneak'
  47 Plug 'klen/python-mode'
  48 Plug 'kshenoy/vim-signature'
  49 Plug 'majutsushi/tagbar'
  50 Plug 'octol/vim-cpp-enhanced-highlight'
  51 if !has('nvim')
  52   Plug 'raimondi/delimitmate' " {{{2
  53   let delimitMate_expand_cr = 2
  54   let g:delimitMate_expand_space = 1
  55   "}}}
  56 end
  57 Plug 'sgeb/vim-diff-fold'
  58 Plug 'skywind3000/asyncrun.vim' " {{{2
  59 command! -bang -nargs=* -complete=file Make AsyncRun -save=2 -program=make @ <args>
  60 let g:asyncrun_open = 10
  61 "}}}
  62 Plug 'shougo/unite.vim'
  63 Plug 'shougo/vimproc.vim', {'do': 'make'}
  64 Plug 'sjl/gundo.vim'
  65 Plug 'thinca/vim-qfreplace'
  66 Plug 'tomtom/tcomment_vim'
  67 Plug 'tpope/vim-abolish'
  68 Plug 'tpope/vim-characterize'
  69 Plug 'tpope/vim-endwise'
  70 Plug 'tpope/vim-eunuch'
  71 Plug 'tpope/vim-fugitive'
  72 Plug 'tpope/vim-repeat'
  73 Plug 'tpope/vim-scriptease'
  74 Plug 'tpope/vim-speeddating'
  75 if !has('nvim')
  76   Plug 'tpope/vim-surround'  "investigate vim-sandwich
  77 endif
  78 Plug 'tpope/vim-unimpaired'
  79 Plug 'tweekmonster/spellrotate.vim'
  80 if !has("nvim")
  81   " Plug 'valloric/youcompleteme' {{{2
  82   Plug 'valloric/youcompleteme',
  83         \{ 'do': './install.py --clangd-completer --clang-completer' }
  84   let g:ycm_clangd_binary_path = 'clangd'   " use clangd in path
  85   let g:ycm_clangd_args = ['--clang-tidy']
  86   let g:ycm_extra_conf_vim_data = ['getcwd()']
  87   let g:ycm_add_preview_to_completeopt = 1
  88   let g:ycm_complete_in_comments = 1
  89   let g:ycm_complete_in_strings  = 1
  90   let g:ycm_autoclose_preview_window_after_insertion = 0
  91
  92   let g:ycm_language_server =
  93         \ [
  94         \   {
  95         \     'name': 'haskell',
  96         \     'cmdline': [ 'haskell-language-server-wrapper', '--lsp' ],
  97         \     'filetypes': [ 'haskell', 'lhaskell'  ]
  98         \   },
  99         \ ]
 100   " }}}
 101 endif
 102 Plug 'vim-scripts/mediawiki.vim'
 103 Plug 'vim-scripts/replacewithregister'
 104 Plug 'vim-scripts/yankring.vim'
 105 Plug 'wincent/loupe'
 106
 107 " colorschemes
 108 Plug 'morhetz/gruvbox' " {{{2
 109 let g:gruvbox_contrast_dark  = 'hard'
 110 let g:gruvbox_contrast_light = 'soft'
 111
 112 if !has('nvim')
 113   Plug 'arcticicestudio/nord-vim' " {{{2
 114   let g:nord_bold = 1
 115   let g:nord_italic = 1
 116   let g:nord_italic_comments = 1
 117   let g:nord_underline = 1
 118   let g:nord_uniform_status_lines = 0
 119   let g:nord_uniform_diff_background = 0
 120   let g:nord_cursor_line_number_background = 0
 121   let g:nord_bold_vertical_split_line = 0
 122 endif
 123
 124 "}}}
 125
 126 if !has("nvim")
 127   Plug 'sirver/ultisnips' " {{{
 128   Plug 'honza/vim-snippets'
 129
 130   let g:UltiSnipsEditSplit = 'vertical'
 131   let g:UltiSnipsSnippetDirectories = [ expand("$XDG_CONFIG_HOME/vim/ultisnips") ]
 132   if has('fname_case')
 133     let g:UltiSnipsSnippetDirectories = ["UltiSnips", "ultisnips"]
 134   endif
 135   let g:UltiSnipsExpandTrigger       = "<tab>"
 136   let g:UltiSnipsJumpForwardTrigger  = "<tab>"
 137   let g:UltiSnipsJumpBackwardTrigger = "<s-tab>"
 138
 139   " UltiSnips completion function that tries to expand a snippet. If there's no
 140   " snippet for expanding, it checks for completion window and if it's shown,
 141   " selects first element. If there's no completion window it tries to jump to
 142   " next placeholder. If there's no placeholder it just returns TAB key
 143   " https://github.com/Valloric/YouCompleteMe/issues/36#issuecomment-15451411
 144   function! g:UltiSnips_Complete()
 145       call UltiSnips#ExpandSnippet()
 146       if g:ulti_expand_res == 0
 147           if pumvisible()
 148               return "\<C-n>"
 149           else
 150               call UltiSnips#JumpForwards()
 151               if g:ulti_jump_forwards_res == 0
 152                  return "\<TAB>"
 153               endif
 154           endif
 155       endif
 156       return ""
 157   endfunction
 158   au InsertEnter * exec "inoremap <silent> " . g:UltiSnipsExpandTrigger . " <C-R>=g:UltiSnips_Complete()<cr>"
 159   let g:UltiSnipsListSnippets="<c-e>"
 160 "}}}
 161 endif
 162
 163 " text objects
 164 Plug 'kana/vim-textobj-user'
 165 Plug 'julian/vim-textobj-variable-segment'
 166 Plug 'sgur/vim-textobj-parameter'
 167 Plug 'kana/vim-operator-user'
 168
 169 " staging
 170 " Check LucHermites plugins: https://github.com/LucHermitte/lh-cpp
 171 Plug 'imsnif/kdl.vim'
 172
 173 Plug 'puremourning/vimspector'
 174 Plug 'ilyachur/cmake4vim'
 175 Plug 'ilyachur/gtest-vim'
 176
 177 Plug 'git@github.com:/ram-z/vim-orgmode', { 'branch': 'dev' } " {{{2
 178 Plug 'vim-scripts/syntaxrange'
 179
 180 let g:org_agenda_files = ['~/org/*.org']
 181
 182 Plug 'neovimhaskell/haskell-vim'  " {{{2
 183 let g:haskell_enable_quantification = 1   " to enable highlighting of `forall`
 184 let g:haskell_enable_recursivedo = 1      " to enable highlighting of `mdo` and `rec`
 185 let g:haskell_enable_arrowsyntax = 1      " to enable highlighting of `proc`
 186 let g:haskell_enable_pattern_synonyms = 1 " to enable highlighting of `pattern`
 187 let g:haskell_enable_typeroles = 1        " to enable highlighting of type roles
 188 let g:haskell_enable_static_pointers = 1  " to enable highlighting of `static`
 189 let g:haskell_backpack = 1                " to enable highlighting of backpack keywords
 190
 191 let g:haskell_indent_before_where = 2
 192 " }}}
 193
 194 Plug 'aklt/plantuml-syntax'
 195
 196 Plug 'mtth/scratch.vim'  " {{{2
 197   let g:scratch_no_mappings = 1
 198   let g:scratch_autohide = 0
 199 "}}}
 200
 201 let g:man_hardwrap = 80
 202 if !has('nvim')
 203   Plug 'vim-utils/vim-man'  " {{{2
 204   let g:man_width = 80
 205 "}}}
 206 endif
 207
 208 Plug 'jenterkin/vim-autosource'  " {{{2
 209   let g:autosource_hashdir = $XDG_CACHE_HOME . '/vim/vim-autosource'
 210   let g:autosource_conf_names = ['.vimrc', '.vimrc.lua']
 211 "}}}
 212 call plug#end()
 213
 214 filetype plugin indent on
 215 syntax on
 216
 217 " colorscheme {{{1
 218 set background=dark
 219 let &t_8f = "\<Esc>[38;2;%lu;%lu;%lum"
 220 let &t_8b = "\<Esc>[48;2;%lu;%lu;%lum"
 221 set termguicolors
 222 if !has('nvim')
 223   colorscheme $THEME
 224 endif
 225 "TODO see how I can integrate this into a theme that customises upstream Nord
 226 hi debugPC term=reverse ctermbg=8
 227
 228 " options {{{1
 229 " moving around, searching and patterns {{{2
 230 set incsearch           " show match for partly typed search command
 231 set ignorecase          " ignore case when using a search pattern
 232 set smartcase           " override 'ignorecase' when pattern has upper case characters
 233 set hlsearch            " highlight all matches for the last used search pattern
 234
 235 set nostartofline       " don't move the cursor to the first non-blank char of a line
 236 set path+=.
 237 set path+=include/
 238 set path+=../include/
 239 set path+=/usr/include/c++/*
 240
 241 " displaying text {{{2
 242 set nowrap                      " long lines wrap
 243 set linebreak                   " wrap long lines at a character in 'breakat'
 244 set showbreak=↪                 " show these chars for wrapped lines
 245 set breakindent                 " preserve indentation in wrapped text
 246
 247 set list                        " show chars defined in 'listchars'
 248 set listchars=tab:❭\            " list of strings used for list mode
 249 set listchars+=extends:❯,precedes:❮
 250 set listchars+=nbsp:␣
 251 " Only shown when not in insert mode
 252 set listchars+=trail:·
 253 augroup trailing
 254     au!
 255     au FileType qf setlocal listchars-=trail:·
 256     au InsertEnter * set listchars-=trail:·
 257     au InsertLeave * set listchars+=trail:·
 258 augroup END
 259
 260 set scrolloff=5                 " number of screen lines to show around the cursor
 261 set sidescroll=1                " number of collumns to scroll
 262 set sidescrolloff=1             " don't scroll over the listchars
 263 set display+=lastline           " display as much as possible of last line
 264
 265 set fillchars=diff:⣿,vert:│
 266
 267 set nonumber                    " show the line number for each line
 268 set norelativenumber            " show the relative line number for each line
 269
 270 " syntax, highlighting and spelling {{{2
 271 set synmaxcol=800               " don't highlight long lines
 272
 273 set dictionary=spell            " list of dictionary files for keyword completion
 274
 275 set colorcolumn=+1
 276
 277 " multiple windows {{{2
 278 set laststatus=2                " 0, 1 or 2; when to use a status line for the last window
 279
 280 set previewheight=20            " default height for the preview window
 281
 282 set hidden
 283
 284 " set splitbelow                  " a new window is put below of the current one
 285 set splitright                  " a new window is put right of the current one
 286
 287 " terminal {{{2
 288 set ttyfast
 289
 290 " using the mouse {{{2
 291 set mouse=rnv                   " list of flags for using the mouse
 292 if !has('nvim')
 293   set ttymouse=xterm              " type of mouse
 294 endif
 295
 296 " messages and info {{{2
 297 set showcmd         " Show (partial) command in status line.
 298 set ruler           " show the cursor position all the time
 299 set confirm         " Ask what to do when closing unsaved documents
 300 set shortmess=      " reset option
 301 set shortmess+=a    " all abbreviations
 302 set shortmess+=o    " overwrite file-written message
 303 set shortmess+=O    " file-read message overrides previous
 304 set shortmess+=t    " truncate file message at start
 305 set shortmess+=T    " truncate other messages in the middle
 306 set shortmess+=W    " don't give 'written' or '[w]' when writing a file
 307 set shortmess+=A    " ignore swapfile warning
 308 set shortmess+=I    " no splash screen
 309 set shortmess+=c    " don't give |ins-completion-menu| messages
 310
 311 " editing text {{{2
 312 set backspace=indent,eol,start  " allow backspacing over everything in insert mode
 313
 314 set showmatch                   " Show matching brackets.
 315
 316 set nojoinspaces                " don't use two spaces after '.' when joining a line
 317 set formatoptions+=j    " Delete comment leader when joining lines
 318 set formatoptions+=c    " Autowrap comments using textwidth
 319 set formatoptions+=r    " Insert comment leader after hitting <Enter>
 320 set formatoptions+=n    " Recognize numbered lists
 321 set formatoptions+=q    " Allow formatting of comments with "gq".
 322 set formatoptions+=l    " do not wrap lines that have been longer when starting insert mode already
 323 set formatoptions+=t    " Auto-wrap text using textwidth
 324 set formatoptions-=o    " Do not insert comment leader after hitting o or O in normal mode
 325
 326 set nrformats-=octal    " don't inc/dec octal numbers with ^[AX]
 327 set nrformats+=unsigned " treat all numbers as unsigned
 328
 329 set complete=.       " scan the current buffer ( 'wrapscan' is ignored)
 330 set complete+=w      " scan buffers from other windows
 331 set complete+=b      " scan other loaded buffers that are in the buffer list
 332 set complete+=u      " scan the unloaded buffers that are in the buffer list
 333 set complete+=t      " scan tags
 334 set complete+=i      " scan current and included files
 335 set complete+=kspell " use the currently active spell checking |spell|
 336
 337 " whether to use a popup menu for Insert mode completion
 338 set completeopt=longest,menuone,preview
 339
 340 " tabs and indent {{{2
 341 set shiftwidth=4                " number of spaces used for each step of (auto)indent
 342 set smarttab                    " a <Tab> in an indent inserts 'shiftwidth' spaces
 343 set softtabstop=4               " if non-zero, number of spaces to insert for a <Tab>
 344 set shiftround                  " round to 'shiftwidth' for "<<" and ">>"
 345 set expandtab                   " expand <Tab> to spaces in Insert mode
 346 set autoindent
 347
 348 set pastetoggle=<F11>           " key sequence to toggle paste mode
 349
 350 " folding {{{2
 351 set foldmethod=marker           " folding type
 352 set foldlevelstart=0            " value for 'foldlevel' when starting to edit a file
 353
 354 " open folds when jumping to line
 355 set foldopen+=jump
 356
 357 set viewoptions=cursor          " save cursor position
 358 set viewoptions+=folds          " save folds
 359
 360 " diff mode {{{2
 361 set diffopt+=filler         " show filler lines
 362 set diffopt+=vertical       " always vertical split
 363 set diffopt+=context:10     " 10 lines context between changes
 364 set diffopt+=internal
 365 set diffopt+=algorithm:patience
 366
 367 " reading and writing files {{{2
 368 set modeline                    " read modelines
 369 set modelines=2                 " only check first/last 2 lines
 370
 371 set writebackup                 " write a backup file before overwriting a file
 372 set backup                      " keep a backup after owerwriting a file
 373 set backupdir=$XDG_CACHE_HOME/vim/backup//
 374
 375 set backupskip+=.netrc          " skip netrc
 376 set backupskip+=/dev/shm/pass*  " skip passwordstore files
 377
 378 set undofile                    " persistent undo history
 379 set undolevels=10000            " moar undos
 380 if !has('nvim')
 381   set undodir=$XDG_CACHE_HOME/vim/undo//
 382 endif
 383
 384 augroup undoskip
 385     au!
 386     au BufWritePre .netrc         setlocal noundofile
 387     au BufWritePre /dev/shm/pass* setlocal noundofile
 388     au BufWritePre /tmp/*         setlocal noundofile
 389 augroup END
 390
 391 set autowrite                   " automatically write a file when leaving a modified buffer
 392 set autoread                    " automatically read a file that has been modified
 393
 394 " the swap file {{{2
 395 set noswapfile
 396 set directory=$XDG_CACHE_HOME/vim/swap//
 397
 398 " command line editing {{{2
 399 set history=5000                " how many command lines are remembered
 400 set wildmenu                    " command-line completion shows a list of matches
 401 set wildmode=longest:full,full  " specifies how command line completion works
 402 set wildignorecase              " ignore case when completing file names
 403
 404 set wildignore+=.hg,.git,.svn                    " Version control
 405 set wildignore+=*.aux,*.out,*.toc                " LaTeX intermediate files
 406 set wildignore+=*.jpg,*.bmp,*.gif,*.png,*.jpeg   " binary images
 407 set wildignore+=*.o,*.obj,*.exe,*.dll,*.manifest " compiled object files
 408 set wildignore+=*.spl                            " compiled spelling word lists
 409 set wildignore+=*.sw?                            " Vim swap files
 410 set wildignore+=*.luac                           " Lua byte code
 411 set wildignore+=*.pyc                            " Python byte code
 412 set wildignore+=*.orig                           " Merge resolution files
 413
 414 " running make and jumping to errors {{{2
 415 set makeprg=make\ -w     " print changing directories
 416
 417 set grepformat=%f:%l:%c:%m
 418 set grepprg=ag\ --vimgrep\ $*
 419
 420 " language specific {{{2
 421 set isfname-==    " don't treat `=` as being part of filenames
 422
 423 " various {{{2
 424 set virtualedit+=block     " let cursor move past last char in <C-V> mode
 425 set virtualedit+=onemore   " allow the cursor to move just past the end of the line
 426 if !has('nvim')
 427   " viminfo defaults but save file in .cache
 428   set viminfo='100,<50,s10,h,n$XDG_CACHE_HOME/vim/viminfo
 429 else
 430   " shada is the replacement format for viminfo
 431   " this setting is probably not needed as it's most likely the default
 432   " the default path is in XDG_DATA_HOME, which is fine
 433   set shada='100,<50,s10,h
 434 endif
 435
 436 set viewdir=$XDG_CACHE_HOME/vim/view//
 437
 438 set sessionoptions+=unix,slash  " damn windows and it's silly ways
 439
 440 " autocmds {{{1
 441 " Resize splits when the window is resized {{{2
 442 augroup resize_splits
 443     au!
 444     autocmd VimResized * :tabdo wincmd =
 445 augroup END
 446
 447 " Only show cursorline in the current window and in normal mode {{{2
 448 augroup cline
 449     au!
 450     au WinLeave,InsertEnter * set nocursorline
 451     au WinEnter,InsertLeave * set cursorline
 452 augroup END
 453
 454 " Treat buffers from stdin (e.g.: echo foo | vim -) as scratch {{{2
 455 augroup ft_stdin
 456     au!
 457     au StdinReadPost * :set buftype=nofile
 458 augroup END
 459
 460 " Jump to last known cursor position {{{2
 461 augroup last_loc
 462     au!
 463     " blacklist certain filetype
 464     let blacklist = ['gitcommit']
 465     autocmd BufReadPost *
 466                 \ if index(blacklist, &ft) < 0 && line("'\"") > 1 && line("'\"") <= line("$") |
 467                 \   exe "normal! g`\"" |
 468                 \ endif
 469 augroup END
 470
 471 " Check for file modifications automatically {{{2
 472 " (current buffer only)
 473 " Use :NoAutoChecktime to disable it (uses b:autochecktime)
 474 fun! MyAutoCheckTime()
 475   " only check timestamp for normal files
 476   if &buftype != '' | return | endif
 477   if ! exists('b:autochecktime') || b:autochecktime
 478     checktime %
 479     let b:autochecktime = 1
 480   endif
 481 endfun
 482 augroup MyAutoChecktime
 483   au!
 484   au FocusGained,BufEnter,CursorHold,InsertEnter * call MyAutoCheckTime()
 485 augroup END
 486 command! NoAutoChecktime let b:autochecktime=0
 487 command! ToggleAutoChecktime let b:autochecktime=!get(b:, 'autochecktime', 0) | echom "b:autochecktime:" b:autochecktime
 488
 489 " bindings {{{1
 490
 491 " make
 492 function! MakeWithOpt()
 493   " TODO only do this if makeprg matches make
 494   " if &makeprg =~ "make"
 495   let l:make_dir = ""
 496   if exists("b:make_dir")
 497     let l:make_dir = "-C ".b:make_dir
 498   elseif exists("t:make_dir")
 499     let l:make_dir = "-C ".t:make_dir
 500   elseif exists("g:make_dir")
 501     let l:make_dir = "-C ".g:make_dir
 502   endif
 503
 504   let l:make_targets = ""
 505   if exists("g:make_targets")
 506     let l:make_targets = g:make_targets
 507   endif
 508   execute "Make ".l:make_dir." ".l:make_targets
 509 endf
 510 nnoremap <silent> <leader>r :call MakeWithOpt()<cr>
 511
 512 " unhighlight search
 513 nnoremap <silent> <Leader>/ :silent nohl<CR>
 514
 515 " Tabs
 516 nnoremap <leader>[ :tabprev<cr>
 517 nnoremap <leader>] :tabnext<cr>
 518
 519 " paste from selection
 520 nnoremap <leader>p* :silent! set paste<CR>"*p:set nopaste<CR>
 521 " paste from clipboard
 522 nnoremap <leader>p+ :silent! set paste<CR>"+p:set nopaste<CR>
 523
 524 " strip trailing whitespace
 525 function! StripWhitespace(line1, line2, ...)  " {{{2
 526   let s_report = &report
 527   let &report=0
 528   let pattern = a:0 ? a:1 : '\s\+$'
 529   let oldview = winsaveview()
 530   exe 'keepjumps keeppatterns '.a:line1.','.a:line2.'substitute/'.pattern.'//e'
 531   if oldview != winsaveview()
 532     redraw
 533   endif
 534   call winrestview(oldview)
 535   let &report = s_report
 536 endfunction  " }}}2
 537 command! -range=% -nargs=0 -bar Untrail keepjumps call StripWhitespace(<line1>,<line2>)
 538 nnoremap <silent> <leader>ww :Untrail<CR>
 539
 540 " Source
 541 vnoremap <leader>S y:execute @@<cr>:echo 'Sourced selection.'<cr>
 542 nnoremap <leader>S ^vg_y:execute @@<cr>:echo 'Sourced line.'<cr>
 543
 544 " jump to last cursor position
 545 noremap ' `
 546
 547 " Select (charwise) the contents of the current line, excluding indentation.
 548 nnoremap vv ^vg_
 549
 550 " Unfuck my screen
 551 nnoremap U
 552       \ :syntax sync fromstart<cr>
 553       \ :AirlineRefresh<cr>
 554       \ :call popup_clear(1)<cr>
 555       \ :redraw!<cr>
 556
 557 " Ranger
 558 " nnoremap <leader>r :silent !ranger %:h<cr>:redraw!<cr>
 559 " nnoremap <leader>R :silent !ranger<cr>:redraw!<cr>
 560
 561 " Use sane regexes.
 562 nnoremap / /\v
 563 vnoremap / /\v
 564 cnoremap s/ s/\v
 565
 566 " display the number of matches for the last search
 567 nmap <Leader># :%s:<C-R>/::gn<CR>
 568
 569 " center cursor after search and open folds
 570 nnoremap n nzzzv
 571 nnoremap N Nzzzv
 572
 573 " same when jumping around
 574 nnoremap g; g;zzzv
 575 nnoremap g, g,zzzv
 576 nnoremap <c-o> <c-o>zzzv
 577 nnoremap <c-i> <c-i>zzzv
 578
 579 " Not using the default mappings of 'To line from top/bottom'
 580 noremap H ^
 581 noremap L $
 582 vnoremap H ^
 583 vnoremap L g_
 584
 585 " Heresy, emacs insert bindings
 586 inoremap <C-A> <Esc>I
 587 inoremap <C-E> <Esc>A
 588 cnoremap <C-A> <Home>
 589 cnoremap <C-E> <End>
 590
 591 " proper movement when lines are wrapped
 592 noremap <silent><expr> j (v:count == 0 ? 'gj' : 'j')
 593 noremap <silent><expr> k (v:count == 0 ? 'gk' : 'k')
 594
 595 " disable arrows
 596 noremap  <Up>    <NOP>
 597 noremap  <Down>  <NOP>
 598 noremap  <Left>  <NOP>
 599 noremap  <Right> <NOP>
 600 inoremap <Up>    <NOP>
 601 inoremap <Down>  <NOP>
 602 inoremap <Left>  <NOP>
 603 inoremap <Right> <NOP>
 604 cnoremap <Up>    <NOP>
 605 cnoremap <Down>  <NOP>
 606 cnoremap <Left>  <NOP>
 607 cnoremap <Right> <NOP>
 608 cnoremap <C-K>   <Up>
 609 cnoremap <C-J>   <Down>
 610 cnoremap <C-H>   <Left>
 611 cnoremap <C-L>   <Right>
 612
 613 " close all folds open fold in cursor
 614 nnoremap zx zMzxzt
 615
 616 map <F1> :ls<CR>:b<space>
 617
 618 " move between windows (skip previewwindow)
 619 nnoremap <silent> <C-L> <C-W>w<C-W>:if &previewwindow \| wincmd w \| endif<CR>
 620 nnoremap <silent> <C-H> <C-W>W<C-W>:if &previewwindow \| wincmd W \| endif<CR>
 621 tnoremap <silent> <C-L> <C-W>w<C-W>:if &previewwindow \| wincmd w \| endif<CR>
 622 tnoremap <silent> <C-H> <C-W>W<C-W>:if &previewwindow \| wincmd W \| endif<CR>
 623
 624 "xterm mouse with middleclick paste
 625 nnoremap <MiddleMouse> i<MiddleMouse>
 626 vnoremap <MiddleMouse> s<MiddleMouse>
 627
 628 " fix legacy vi inconsistency
 629 nnoremap Y y$
 630 " copy to clipboard
 631 xnoremap Y "+y
 632
 633 " allow repeat operator on visual
 634 vnoremap . :normal .<CR>
 635
 636 " add line without changing position or leaving mode
 637 noremap <silent> <Leader>o :set paste<CR>m`o<ESC>``:set nopaste<CR>
 638 noremap <silent> <Leader>O :set paste<CR>m`O<ESC>``:set nopaste<CR>
 639
 640 " Don't use Ex mode, use Q for formatting
 641 map Q gq
 642
 643 " break undo sequence before removing word
 644 inoremap <C-W> <C-G>u<C-W>
 645
 646 nnoremap coe :set <C-R>=&expandtab ? 'noexpandtab' : 'expandtab'<CR><CR>
 647 nnoremap [oe :set expandtab<CR>
 648 nnoremap ]oe :set noexpandtab<CR>
 649
 650 for idt in range(1,8)
 651   exe 'nnoremap co'.idt.' :setlocal tabstop='.idt.' shiftwidth='.idt.' softtabstop='.idt.'<CR>'
 652 endfor
 653
 654 " toggle auto format of text
 655 nnoremap coa :set <C-R>=&formatoptions =~ "a" ? 'formatoptions-=a' : 'formatoptions+=a'<CR><CR>
 656 nnoremap [oa :set formatoptions+=a<CR>
 657 nnoremap ]oa :set formatoptions-=a<CR>
 658
 659 " space will toggle current fold in normal mode
 660 nnoremap <leader><Space> za
 661 " create folds around visual selection
 662 vnoremap <leader><Space> zf
 663
 664 " save with sudo
 665 cabbrev w!! SudoWrite
 666
 667 " uppercase previous word
 668 inoremap <C-C> <Esc>gUiwgi
 669
 670 " http://git.io/v3ZeU
 671 nmap <silent> <leader>qq :echo "hi<" . synIDattr(synID(line("."),col("."),1),"name") . '> trans<' . synIDattr(synID(line("."),col("."),0),"name") . "> lo<" . synIDattr(synIDtrans(synID(line("."),col("."),1)),"name") . ">"<CR>
 672
 673 " plugins options {{{1
 674 " checkattach {{{2
 675 let g:checkattach_filebrowser = 'ranger'
 676 let g:checkattach_once = 'y'
 677
 678 " close-another-window {{{2
 679 nnoremap <silent> <C-W>c  <NOP>
 680 nnoremap <silent> <C-W>cc <C-W>c
 681 nnoremap <silent> <C-W>ch :CloseLeftWindow<CR>
 682 nnoremap <silent> <C-W>cl :CloseRightWindow<CR>
 683 nnoremap <silent> <C-W>cj :CloseBelowWindow<CR>
 684 nnoremap <silent> <C-W>ck :CloseAboveWindow<CR>
 685
 686
 687 " fswitch {{{2
 688 nnoremap <silent> <Leader>ff :FSHere<CR>
 689 nnoremap <silent> <Leader>fl :FSRight<CR>
 690 nnoremap <silent> <Leader>fh :FSLeft<CR>
 691 nnoremap <silent> <Leader>fj :FSBelow<CR>
 692 nnoremap <silent> <Leader>fk :FSAbove<CR>
 693 nnoremap <silent> <Leader>fL :FSSplitRight<CR>
 694 nnoremap <silent> <Leader>fH :FSSplitLeft<CR>
 695 nnoremap <silent> <Leader>fJ :FSSplitBelow<CR>
 696 nnoremap <silent> <Leader>fK :FSSplitAbove<CR>
 697
 698 " fugitive {{{2
 699 nmap <silent> <leader>dd :tab split \| Gdiff \| wincmd h<CR>
 700 " delete fugitive buffers when closed
 701 autocmd BufReadPost fugitive://* set bufhidden=delete
 702
 703 function! GitToggle()
 704   let l:status_buffer = bufname('^fugitive:///*/.git{/worktrees/*,}//$')
 705   if buflisted(l:status_buffer)
 706     execute 'bdelete '.l:status_buffer
 707   else
 708     execute 'Git'
 709     if !empty(FugitiveGitDir())
 710       " only resize status if Git was sucessful
 711       16wincmd_
 712     endif
 713   endif
 714 endfunction
 715 command! GitToggle :call GitToggle()
 716 command! GToggle GitToggle
 717 nnoremap <silent> <leader>gs :GitToggle<CR>
 718
 719 nnoremap <silent> <leader>gd :Gdiffsplit<CR>
 720 nnoremap <silent> <leader>gc :echohl WarningMsg \| echo "use \<leader>gcc instead" \| echohl None<CR>
 721 nnoremap <silent> <leader>gcc :tab G commit -v<CR>
 722 nnoremap <silent> <leader>gca :tab G commit -v --amend<CR>
 723 nnoremap          <leader>gcf :tab G commit -v --fixup=
 724 nnoremap <silent> <leader>gp :echohl WarningMsg \| echo "use \<leader>gpp instead" \| echohl None<CR>
 725 nnoremap <silent> <leader>gpp :Git push \| copen<CR>
 726 nnoremap <silent> <leader>gpf :Git push --force-with-lease \| copen<CR>
 727 nnoremap <silent> <leader>gll :Git pull<CR>
 728 nnoremap <silent> <leader>gru :Git rebase --interactive @{upstream}<CR>
 729 nnoremap <silent> <leader>grp :Git rebase --interactive @{push}<CR>
 730 nnoremap <silent> <leader>ga :Gwrite<cr>
 731 nnoremap <silent> <leader>gb :G blame<cr>
 732
 733 augroup fugitive_gstatus
 734     au!
 735     autocmd User FugitiveIndex setlocal winfixheight
 736     autocmd User FugitiveIndex nmap <buffer> <leader><space> =
 737 augroup end
 738
 739 " Gundo {{{2
 740 nnoremap <F7> :GundoToggle<CR>
 741 let g:gundo_prefer_python3 = 1
 742
 743 " indent-guides {{{2
 744 let g:indent_guides_default_mapping = 0
 745 let g:indent_guides_guide_size = 1
 746 nmap <silent> cog <Plug>IndentGuidesToggle
 747 nmap <silent> [og <Plug>IndentGuidesEnable
 748 nmap <silent> ]og <Plug>IndentGuidesDisable
 749
 750 " python-mode {{{2
 751
 752 let g:pymode_rope_completion = 0
 753 let g:pymode_rope = 0
 754 let g:pymode_run = 0
 755 let g:pymode_folding = 1
 756 let g:pymode_lint_ignore = "E221,E266,E501"
 757 let g:pymode_lint_cwindow = 0           " don't open cwindow when linting
 758 let g:pymode_syntax_space_errors = 0    " don't bother me when I'm typing
 759
 760 " signature {{{2
 761 " disable '[ mappings
 762
 763 let g:SignatureMap = {
 764   \ 'GotoNextLineAlpha'  :  "",
 765   \ 'GotoPrevLineAlpha'  :  "",
 766   \ 'GotoNextSpotAlpha'  :  "",
 767   \ 'GotoPrevSpotAlpha'  :  "",
 768   \ }
 769
 770 " switch
 771 let g:switch_mapping = "<Leader>s"
 772 let g:switch_custom_definitions = [
 773       \   ['yes', 'no']
 774       \ ]
 775
 776 " spellrotate
 777 nmap <silent> z] <Plug>(SpellRotateForward)
 778 nmap <silent> z[ <Plug>(SpellRotateBackward)
 779 vmap <silent> z] <Plug>(SpellRotateForwardV)
 780 vmap <silent> z[ <Plug>(SpellRotateBackwardV)
 781
 782 " synastic {{{2
 783 let g:syntastic_enable_highlighting = 0
 784 let g:syntastic_error_symbol='E'
 785 let g:syntastic_style_error_symbol='S'
 786 let g:syntastic_warning_symbol='W'
 787 let g:syntastic_style_warning_symbol='S'
 788 let g:syntastic_always_populate_loc_list=1
 789 nmap <silent> <leader>y :SyntasticCheck<cr>
 790
 791 let g:syntastic_cpp_clang_tidy_post_args = "-p build*"
 792
 793 if ! &diff
 794   let g:syntastic_check_on_open=1
 795 endif
 796
 797 " tagbar {{{2
 798 map <F5> :TagbarToggle<cr>
 799 let g:tagbar_sort = 0
 800 let g:tagbar_compact = 1
 801 let g:tagbar_autoshowtag = 1
 802 let g:tagbar_width = 25
 803 let g:tagbar_iconchars = ['+', '-']
 804
 805 " tcomments {{{2
 806 let g:tcomment_textobject_inlinecomment = 'gic'
 807 let g:tcomment#filetype#guess = 0
 808 "let g:tcomment#options = {'whitespace' : 'no'}
 809
 810 " unite {{{2
 811 call unite#filters#matcher_default#use(['matcher_fuzzy'])
 812 call unite#custom#profile('default', 'context', {
 813             \ 'winheight': 20,
 814             \ 'direction': 'botright'
 815             \ })
 816
 817 nnoremap [unite] <Nop>
 818 nmap <leader>u [unite]
 819 nnoremap [unite]u :UniteResume<CR>
 820 nnoremap <silent> [u :UnitePrevious<CR>
 821 nnoremap <silent> ]u :UniteNext<CR>
 822
 823 " unite-grep {{{3
 824 " seems not respected
 825 let g:unite_source_grep_max_candidates = 2000
 826 if executable('ag')
 827     " Use ag in unite grep source.
 828     let g:unite_source_grep_command = 'ag'
 829     let g:unite_source_grep_default_opts = '--smart-case --vimgrep --ignore ''.hg'' --ignore ''.svn'' --ignore ''.git'' --ignore ''.bzr'''
 830     let g:unite_source_grep_recursive_opt = ''
 831 end
 832 nnoremap <silent> [unite]a :<C-u>Unite grep:.::\12\17<CR>
 833 nnoremap <silent> [unite]A :<C-u>Unite grep:.:-w:\12\17<CR>
 834 command! -nargs=+ Ag Unite grep:.::<args>
 835
 836 " unite-file_rec {{{3
 837 if executable('ag')
 838     " Use ag in unite rec source
 839     let g:unite_source_rec_async_command = ['ag', '--follow', '--nocolor', '--nogroup', '-g', '']
 840 end
 841 nnoremap <silent> [unite]f :<C-u>Unite -start-insert file_rec/async<CR>
 842 call unite#custom#source('file_rec/async', 'sorters', 'sorter_selecta')
 843
 844 " unite-buffer {{{3
 845 call unite#custom#default_action('buffer', 'open')
 846 nnoremap <silent> [unite]b :<C-u>Unite buffer:-<CR>
 847
 848 " unite-jumplist {{{3
 849 nnoremap <silent> [unite]j :<C-u>Unite output:jumps:<CR>
 850
 851 " unite-menu {{{3
 852 let g:unite_source_menu_menus = {}
 853 let g:unite_source_menu_menus.fugitive = { 'description' : 'fugitive menu'}
 854 let g:unite_source_menu_menus.fugitive.command_candidates = {
 855             \ 'Gstatus <Leader>gs' : 'Gstatus',
 856             \ 'Gcommit -v <Leader>gc' : 'Gcommit -v',
 857             \ 'Glog' : 'Glog',
 858             \}
 859
 860 nnoremap <silent> <leader>gg :<C-u>Unite menu:fugitive<CR>
 861
 862 let g:unite_source_history_yank_enable = 1
 863 nnoremap <silent> [unite]p :<C-u>Unite history/yank<CR>
 864
 865 " yankring {{{2
 866 nnoremap <silent> <leader>p :YRShow<cr>
 867 let g:yankring_history_dir = expand('$XDG_CACHE_HOME/vim')
 868 let g:yankring_replace_n_pkey = ''
 869 let g:yankring_replace_n_nkey = ''
 870
 871 " map Y to y$ for the yank ring
 872 function! YRRunAfterMaps()
 873     nnoremap Y   :<C-U>YRYankCount 'y$'<CR>
 874 endfunction
 875
 876 " vim-easy-align {{{2
 877 " start interactive EasyAlign in visual mode
 878 vmap <Enter>   <Esc>:echohl WarningMsg \| echo "EasyAlign mapped to \16<leader>a now" \| echohl None<CR>
 879 vmap <leader>a <Plug>(EasyAlign)
 880 nmap <leader>a <Plug>(EasyAlign)
 881
 882 " vim-gtest {{{2
 883 let g:gtest#highlight_failing_tests = 0
 884
 885 nnoremap <silent> <Leader>tt :GTestRun<CR>
 886 nnoremap          <Leader>tc :GTestCase<space>
 887 nnoremap          <Leader>tn :GTestName<space>
 888 nnoremap <silent> <Leader>ta :GTestCase *<CR>:GTestName *<CR>:GTestRun<CR>
 889 nnoremap <silent> <Leader>tu :GTestRunUnderCursor<CR>
 890
 891 " vim-json {{{2
 892 let g:vim_json_syntax_conceal = 0
 893
 894 " vim-sneak {{{2
 895 let g:sneak#streak = 1
 896 let g:sneak#target_labels = "aoeuisnthdpylrcgfqjkxzmwvz" " dvorak
 897 let g:sneak#use_ic_scs = 1  " follow 'ignorecase' and 'smartcase'
 898
 899 " sneaky f and t
 900 nmap f <Plug>Sneak_f
 901 nmap F <Plug>Sneak_F
 902 xmap f <Plug>Sneak_f
 903 xmap F <Plug>Sneak_F
 904 omap f <Plug>Sneak_f
 905 omap F <Plug>Sneak_F
 906 nmap t <Plug>Sneak_t
 907 nmap T <Plug>Sneak_T
 908 xmap t <Plug>Sneak_t
 909 xmap T <Plug>Sneak_T
 910 omap t <Plug>Sneak_t
 911 omap T <Plug>Sneak_T
 912
 913 " functions {{{1
 914
 915 " Convenient command to see the difference between the current buffer and the
 916 " file it was loaded from, thus the changes you made.
 917 " Only define it when not defined already.
 918 if !exists(":DiffOrig")
 919   command DiffOrig vert new | set bt=nofile | r # | 0d_ | diffthis
 920                   \ | wincmd p | diffthis
 921 endif
 922
 923 " sort operator {{{2
 924 function! SortLinesOpFunc(...)
 925   '[,']sort
 926 endfunction
 927 nnoremap <silent> gs :<C-U>set operatorfunc=SortLinesOpFunc<CR>g@
 928 vnoremap <silent> gs :sort<cr>
 929
 930 " edit configs  {{{2
 931 function! EditConfig(what, ext = '.vim')
 932     let l:dir = split(&runtimepath,',')[0]
 933     if a:what == 'vimrc'
 934         let l:file = expand($MYVIMRC)
 935     elseif ! isdirectory(globpath(l:dir, a:what))
 936         echoe a:what." is not valid!"
 937     elseif empty(&filetype)
 938         echoe 'filetype is empty!'
 939     else
 940         let l:file = l:dir.'/'.a:what.'/'.&filetype.a:ext
 941     endif
 942
 943     execute ':vsplit '.file
 944     execute ':lcd %:p:h'
 945 endf
 946 nmap <leader>ev :call EditConfig('vimrc')<CR>
 947 nmap <leader>ef :call EditConfig('ftplugin')<CR>
 948 nmap <leader>es :call EditConfig('syntax')<CR>
 949 nmap <leader>ei :call EditConfig('indent')<CR>
 950 nmap <leader>eu :call EditConfig('ultisnips', '.snippets')<CR>
 951
 952 " spell check {{{2
 953 " http://tex.stackexchange.com/a/52932
 954 let g:myLangList=["en_gb","en_us","de","fr"]
 955
 956 function! ToggleSpell()
 957   if !exists("b:myLang")
 958     let b:myLang=0
 959   endif
 960   execute "setlocal spell!"
 961   if (&spell)
 962     echo "setlocal spelllang=" g:myLangList[b:myLang]
 963   endif
 964 endfunction
 965
 966 function! SwitchSpell()
 967   if !exists("b:myLang")
 968     let b:myLang=0
 969   endif
 970   if (&spell)
 971     let b:myLang=b:myLang+1
 972     if b:myLang>=len(g:myLangList) | let b:myLang=0 | endif
 973   endif
 974   execute "setlocal spell spelllang=".get(g:myLangList, b:myLang)
 975   echo "setlocal spelllang=" g:myLangList[b:myLang]
 976 endfunction
 977
 978 nnoremap <silent> coS :call SwitchSpell()<CR>
 979
 980 " gitdir or home {{{2
 981 " from derek wyatt:
 982 " http://git.io/v3GAV
 983 function! FindGitDirOrHome()
 984   let filedir = expand('%:p:h')
 985   if isdirectory(filedir)
 986     let cmd = 'bash -c "(cd ' . filedir . '; git rev-parse --show-toplevel 2>/dev/null)"'
 987     let gitdir = system(cmd)
 988     if strlen(gitdir) == 0
 989       return '~'
 990     else
 991       return gitdir[:-2]
 992     endif
 993   else
 994     return '~'
 995   endif
 996 endfunction
 997 command! Cd cd %:h
 998 command! Cdr execute('cd ' . FindGitDirOrHome())
 999 command! LCd lcd %:h
1000 command! LCdr execute('lcd ' . FindGitDirOrHome())
1001
1002 " vim:set et sw=2 ts=2 tw=78: