vim/vimrc

   1 " force python3
   2 if has('python3') | endif
   3
   4 " space is leader
   5 let g:mapleader = " "
   6
   7 " disable netrw
   8 "FIXME: it currently breaks vim-fugitive 2023-04-11
   9 " instead of opening Git status, a netrw buffer opens instead
  10 let g:loaded_netrwPlugin = 1
  11
  12 " runtimepath {{{1
  13 set runtimepath ^=$XDG_CONFIG_HOME/vim
  14 set runtimepath +=$XDG_CONFIG_HOME/vim/after
  15
  16 " plugins {{{1
  17 call plug#begin('$XDG_DATA_HOME/vim')
  18 " This does not update vim-plug, use PlugUpgrade instead
  19 Plug 'junegunn/vim-plug'
  20
  21 if !has("nvim")
  22   Plug 'bling/vim-airline' " {{{2
  23     let g:airline#extensions#whitespace#enabled = 1
  24     let g:airline#extensions#tabline#enabled = 1
  25     let g:airline#extensions#searchcount#enabled = 0
  26     let g:airline_powerline_fonts = 1
  27
  28     let g:asyncrun_status = "stopped"
  29     " let g:airline_section_error = airline#section#create_right(['%{g:asyncrun_status}'])
  30   "}}}
  31   Plug 'raimondi/delimitmate' " {{{2
  32     let delimitMate_expand_cr = 2
  33     let g:delimitMate_expand_space = 1
  34   "}}}
  35   Plug 'tpope/vim-surround' "{{{2
  36   "}}}
  37   " Plug 'valloric/youcompleteme' {{{2
  38   Plug 'valloric/youcompleteme',
  39         \{ 'do': './install.py --clangd-completer --clang-completer' }
  40     let g:ycm_clangd_binary_path = 'clangd'   " use clangd in path
  41     let g:ycm_clangd_args = ['--clang-tidy']
  42     let g:ycm_extra_conf_vim_data = ['getcwd()']
  43     let g:ycm_add_preview_to_completeopt = 1
  44     let g:ycm_complete_in_comments = 1
  45     let g:ycm_complete_in_strings  = 1
  46     let g:ycm_autoclose_preview_window_after_insertion = 0
  47
  48     let g:ycm_language_server =
  49           \ [
  50           \   {
  51           \     'name': 'haskell',
  52           \     'cmdline': [ 'haskell-language-server-wrapper', '--lsp' ],
  53           \     'filetypes': [ 'haskell', 'lhaskell'  ]
  54           \   },
  55           \ ]
  56   " }}}
  57   Plug 'svermeulen/vim-yoink' " {{{2
  58   ""}}}
  59   Plug 'arcticicestudio/nord-vim' " {{{2
  60     let g:nord_bold = 1
  61     let g:nord_italic = 1
  62     let g:nord_italic_comments = 1
  63     let g:nord_underline = 1
  64     let g:nord_uniform_status_lines = 0
  65     let g:nord_uniform_diff_background = 0
  66     let g:nord_cursor_line_number_background = 0
  67     let g:nord_bold_vertical_split_line = 0
  68   "}}}
  69   Plug 'sirver/ultisnips' " replaced by lua-snip {{{2
  70   Plug 'honza/vim-snippets'
  71     let g:UltiSnipsEditSplit = 'vertical'
  72     let g:UltiSnipsSnippetDirectories = [ expand("$XDG_CONFIG_HOME/vim/ultisnips") ]
  73     if has('fname_case')
  74       let g:UltiSnipsSnippetDirectories = ["UltiSnips", "ultisnips"]
  75     endif
  76     let g:UltiSnipsExpandTrigger       = "<tab>"
  77     let g:UltiSnipsJumpForwardTrigger  = "<tab>"
  78     let g:UltiSnipsJumpBackwardTrigger = "<s-tab>"
  79
  80     " UltiSnips completion function that tries to expand a snippet. If there's no
  81     " snippet for expanding, it checks for completion window and if it's shown,
  82     " selects first element. If there's no completion window it tries to jump to
  83     " next placeholder. If there's no placeholder it just returns TAB key
  84     " https://github.com/Valloric/YouCompleteMe/issues/36#issuecomment-15451411
  85     function! g:UltiSnips_Complete()
  86         call UltiSnips#ExpandSnippet()
  87         if g:ulti_expand_res == 0
  88             if pumvisible()
  89                 return "\<C-n>"
  90             else
  91                 call UltiSnips#JumpForwards()
  92                 if g:ulti_jump_forwards_res == 0
  93                   return "\<TAB>"
  94                 endif
  95             endif
  96         endif
  97         return ""
  98     endfunction
  99     au InsertEnter * exec "inoremap <silent> " . g:UltiSnipsExpandTrigger . " <C-R>=g:UltiSnips_Complete()<cr>"
 100     let g:UltiSnipsListSnippets="<c-e>"
 101   "}}}
 102   Plug 'vim-utils/vim-man'  " replaced by builtin {{{2
 103     let g:man_width = 80
 104   "}}}
 105   Plug 'airblade/vim-gitgutter' " replaced by gitsigns {{{
 106   " prefer other signs such as ycm diags
 107   let g:gitgutter_sign_priority = 1
 108   " don't clobber other signs
 109   let g:gitgutter_sign_allow_clobber = 0
 110   "}}}
 111   Plug 'justinmk/vim-sneak' " replaced by leap {{{2
 112   let g:sneak#streak = 1
 113   let g:sneak#target_labels = "aoeuisnthdpylrcgfqjkxzmwvz" " dvorak
 114   let g:sneak#use_ic_scs = 1  " follow 'ignorecase' and 'smartcase'
 115
 116   " sneaky f and t
 117   nmap f <Plug>Sneak_f
 118   nmap F <Plug>Sneak_F
 119   xmap f <Plug>Sneak_f
 120   xmap F <Plug>Sneak_F
 121   omap f <Plug>Sneak_f
 122   omap F <Plug>Sneak_F
 123   nmap t <Plug>Sneak_t
 124   nmap T <Plug>Sneak_T
 125   xmap t <Plug>Sneak_t
 126   xmap T <Plug>Sneak_T
 127   omap t <Plug>Sneak_t
 128   omap T <Plug>Sneak_T
 129   "}}}
 130   Plug 'shougo/unite.vim' " replaced by telescope {{{2
 131     function! UniteSetup()
 132       call unite#filters#matcher_default#use(['matcher_fuzzy'])
 133       call unite#custom#profile('default', 'context', {
 134             \ 'winheight': 20,
 135             \ 'direction': 'botright'
 136             \ })
 137
 138       nnoremap [unite] <Nop>
 139       nmap <leader>u [unite]
 140       nnoremap [unite]u :UniteResume<CR>
 141       nnoremap <silent> [u :UnitePrevious<CR>
 142       nnoremap <silent> ]u :UniteNext<CR>
 143
 144       " unite-grep {{{3
 145       " seems not respected
 146       let g:unite_source_grep_max_candidates = 2000
 147       if executable('ag')
 148         " Use ag in unite grep source.
 149         let g:unite_source_grep_command = 'ag'
 150         let g:unite_source_grep_default_opts = '--smart-case --vimgrep --ignore ''.hg'' --ignore ''.svn'' --ignore ''.git'' --ignore ''.bzr'''
 151         let g:unite_source_grep_recursive_opt = ''
 152       end
 153       nnoremap <silent> [unite]a :<C-u>Unite grep:.::\12\17<CR>
 154       nnoremap <silent> [unite]A :<C-u>Unite grep:.:-w:\12\17<CR>
 155       command! -nargs=+ Ag Unite grep:.::<args>
 156
 157       " unite-file_rec {{{3
 158       if executable('ag')
 159         " Use ag in unite rec source
 160         let g:unite_source_rec_async_command = ['ag', '--follow', '--nocolor', '--nogroup', '-g', '']
 161       end
 162       nnoremap <silent> [unite]f :<C-u>Unite -start-insert file_rec/async<CR>
 163
 164       " unite-buffer {{{3
 165       call unite#custom#default_action('buffer', 'open')
 166       nnoremap <silent> [unite]b :<C-u>Unite buffer:-<CR>
 167
 168       " unite-jumplist {{{3
 169       nnoremap <silent> [unite]j :<C-u>Unite output:jumps:<CR>
 170
 171       " unite-menu {{{3
 172       let g:unite_source_menu_menus = {}
 173       let g:unite_source_menu_menus.fugitive = { 'description' : 'fugitive menu'}
 174       let g:unite_source_menu_menus.fugitive.command_candidates = {
 175             \ 'Gstatus <Leader>gs' : 'Gstatus',
 176             \ 'Gcommit -v <Leader>gc' : 'Gcommit -v',
 177             \ 'Glog' : 'Glog',
 178             \}
 179
 180       nnoremap <silent> <leader>gg :<C-u>Unite menu:fugitive<CR>
 181
 182       let g:unite_source_history_yank_enable = 1
 183       nnoremap <silent> [unite]p :<C-u>Unite history/yank<CR>
 184     endfunction
 185     augroup unit_setup
 186       autocmd VimEnter * ++once call UniteSetup()
 187     augroup END
 188   "}}}2
 189   Plug 'shougo/vimproc.vim', {'do': 'make'} " {{{2
 190   "}}}2
 191   Plug 'tomtom/tcomment_vim' " replaced by comment.nvim {{{2
 192     let g:tcomment_textobject_inlinecomment = 'gic'
 193     let g:tcomment#filetype#guess = 0
 194     "let g:tcomment#options = {'whitespace' : 'no'}
 195   "}}}2
 196   " colorschemes
 197   Plug 'morhetz/gruvbox' " {{{2
 198     let g:gruvbox_contrast_dark  = 'hard'
 199     let g:gruvbox_contrast_light = 'soft'
 200   " }}}2
 201   " staging
 202   Plug 'puremourning/vimspector' " replaced by lsp {{{2
 203     let g:vimspector_enable_mappings = 'HUMAN'
 204   " }}}
 205   Plug 'vim-scripts/syntaxrange' " replaced by treesitter {{{2
 206   " }}}
 207 endif
 208
 209 Plug 'alepez/vim-gtest'
 210 Plug 'alx741/vinfo'
 211 Plug 'andrewradev/sideways.vim' " {{{2
 212 nnoremap <silent> ,h :SidewaysLeft<CR>:delmarks z<CR>
 213 nnoremap <silent> ,l :SidewaysRight<CR>:delmarks z<CR>
 214 "}}}
 215 Plug 'andrewradev/switch.vim'
 216 Plug 'chrisbra/checkattach'
 217 Plug 'derekwyatt/vim-fswitch'
 218 Plug 'elzr/vim-json'
 219 Plug 'firef0x/pkgbuild.vim'
 220 Plug 'junegunn/vim-easy-align'
 221 Plug 'kshenoy/vim-signature'
 222 " Plug 'majutsushi/tagbar' " TODO: delete? {{{2
 223 "   map <F5> :TagbarToggle<cr>
 224 "   let g:tagbar_sort = 0
 225 "   let g:tagbar_compact = 1
 226 "   let g:tagbar_autoshowtag = 1
 227 "   let g:tagbar_width = 25
 228 "   let g:tagbar_iconchars = ['+', '-']
 229 "}}}
 230 Plug 'octol/vim-cpp-enhanced-highlight'
 231 Plug 'sgeb/vim-diff-fold'
 232 Plug 'skywind3000/asyncrun.vim' " {{{2
 233 command! -bang -nargs=* -complete=file Make AsyncRun -save=2 -program=make @ <args>
 234 let g:asyncrun_open = 10
 235 "}}}
 236 Plug 'sjl/gundo.vim'
 237 " Plug 'thinca/vim-qfreplace' " TODO: delete?
 238 Plug 'tpope/vim-abolish'
 239 Plug 'tpope/vim-characterize'
 240 " Plug 'tpope/vim-endwise' " TODO: delete?
 241 Plug 'tpope/vim-eunuch'
 242 Plug 'tpope/vim-fugitive'
 243 Plug 'tpope/vim-repeat'
 244 Plug 'tpope/vim-scriptease'
 245 Plug 'tpope/vim-speeddating'
 246 Plug 'tpope/vim-unimpaired'
 247 Plug 'tweekmonster/spellrotate.vim'
 248 " Plug 'vim-scripts/mediawiki.vim' " TODO: delete?
 249 Plug 'vim-scripts/replacewithregister' " FIXME: is overridden by lsp
 250 Plug 'wincent/loupe'
 251
 252 " text objects
 253 Plug 'kana/vim-textobj-user'
 254 Plug 'julian/vim-textobj-variable-segment'
 255 Plug 'sgur/vim-textobj-parameter'
 256 Plug 'kana/vim-operator-user'
 257
 258 " staging
 259 " Check LucHermites plugins: https://github.com/LucHermitte/lh-cpp
 260 Plug 'imsnif/kdl.vim'
 261
 262 Plug 'ilyachur/cmake4vim'
 263 Plug 'ilyachur/gtest-vim'
 264
 265 Plug 'junegunn/vim-peekaboo' "{{{2
 266   " issue with having it at the bottom is that it doesn't leave much
 267   let g:peekaboo_window = 'bo 16new'
 268   let g:peekaboo_compact = 1
 269   let g:peekaboo_delay = 500
 270 "}}}
 271
 272 " Plug 'vim-scripts/ansiesc.vim' " TODO: delete? {{{2
 273 "   nmap corwp <Plug>RestoreWinPosn
 274 "   nmap coswp <Plug>SaveWinPosn
 275 " "}}}
 276
 277 Plug 'neovimhaskell/haskell-vim'  " {{{2
 278 let g:haskell_enable_quantification = 1   " to enable highlighting of `forall`
 279 let g:haskell_enable_recursivedo = 1      " to enable highlighting of `mdo` and `rec`
 280 let g:haskell_enable_arrowsyntax = 1      " to enable highlighting of `proc`
 281 let g:haskell_enable_pattern_synonyms = 1 " to enable highlighting of `pattern`
 282 let g:haskell_enable_typeroles = 1        " to enable highlighting of type roles
 283 let g:haskell_enable_static_pointers = 1  " to enable highlighting of `static`
 284 let g:haskell_backpack = 1                " to enable highlighting of backpack keywords
 285
 286 let g:haskell_indent_before_where = 2
 287 " }}}
 288
 289 Plug 'aklt/plantuml-syntax'
 290
 291 Plug 'mtth/scratch.vim'  " {{{2
 292   let g:scratch_no_mappings = 1
 293   let g:scratch_autohide = 0
 294 "}}}
 295
 296 Plug 'vim-pandoc/vim-pandoc'  " {{{2
 297 Plug 'vim-pandoc/vim-pandoc-syntax'
 298 let g:pandoc#syntax#conceal#use = 1
 299 let g:pandoc#syntax#conceal#blacklist = [
 300     \ 'titleblock',
 301     \ 'codeblock_start',
 302     \ 'codeblock_delim',
 303     \ 'atx',
 304     \ ]
 305 let g:pandoc#syntax#codeblocks#embeds#langs = [
 306     \ 'plantuml',
 307     \ ]
 308 let g:pandoc#keyboard#blacklist_submodule_mappings = [
 309     \ 'para',
 310     \ ]
 311 "}}}
 312
 313 " Plug 'jenterkin/vim-autosource'  " TODO: delete? {{{2
 314 "   let g:autosource_hashdir = $XDG_CACHE_HOME . '/vim/vim-autosource'
 315 "   let g:autosource_conf_names = ['.vimrc', '.vimrc.lua']
 316 " "}}}
 317
 318 call plug#end()
 319
 320 filetype plugin indent on
 321 syntax on
 322
 323 " colorscheme {{{1
 324 set background=dark
 325 let &t_8f = "\<Esc>[38;2;%lu;%lu;%lum"
 326 let &t_8b = "\<Esc>[48;2;%lu;%lu;%lum"
 327 set termguicolors
 328 if !has('nvim')
 329   colorscheme $THEME
 330 endif
 331 "TODO see how I can integrate this into a theme that customises upstream Nord
 332 hi debugPC term=reverse ctermbg=8
 333
 334 " options {{{1
 335 " moving around, searching and patterns {{{2
 336 set incsearch           " show match for partly typed search command
 337 set ignorecase          " ignore case when using a search pattern
 338 set smartcase           " override 'ignorecase' when pattern has upper case characters
 339 set hlsearch            " highlight all matches for the last used search pattern
 340
 341 set nostartofline       " don't move the cursor to the first non-blank char of a line
 342 set path+=.
 343 set path+=include/
 344 set path+=../include/
 345 set path+=/usr/include/c++/*
 346
 347 " displaying text {{{2
 348 set nowrap                      " long lines wrap
 349 set linebreak                   " wrap long lines at a character in 'breakat'
 350 set showbreak=↪                 " show these chars for wrapped lines
 351 set breakindent                 " preserve indentation in wrapped text
 352
 353 set list                        " show chars defined in 'listchars'
 354 set listchars=tab:❭\            " list of strings used for list mode
 355 set listchars+=extends:❯,precedes:❮
 356 set listchars+=nbsp:␣
 357 " Only shown when not in insert mode
 358 set listchars+=trail:·
 359 augroup trailing
 360     au!
 361     au FileType qf setlocal listchars-=trail:·
 362     au InsertEnter * set listchars-=trail:·
 363     au InsertLeave * set listchars+=trail:·
 364 augroup END
 365
 366 set scrolloff=5                 " number of screen lines to show around the cursor
 367 set sidescroll=1                " number of collumns to scroll
 368 set sidescrolloff=1             " don't scroll over the listchars
 369 set display+=lastline           " display as much as possible of last line
 370
 371 set fillchars=diff:⣿,vert:│
 372
 373 set nonumber                    " show the line number for each line
 374 set norelativenumber            " show the relative line number for each line
 375
 376 " syntax, highlighting and spelling {{{2
 377 set synmaxcol=800               " don't highlight long lines
 378
 379 set dictionary=spell            " list of dictionary files for keyword completion
 380
 381 set colorcolumn=+1
 382
 383 " multiple windows {{{2
 384 set laststatus=2                " 0, 1 or 2; when to use a status line for the last window
 385
 386 set previewheight=20            " default height for the preview window
 387
 388 set hidden
 389
 390 " set splitbelow                  " a new window is put below of the current one
 391 set splitright                  " a new window is put right of the current one
 392
 393 " terminal {{{2
 394 set ttyfast
 395
 396 " using the mouse {{{2
 397 set mouse=rnv                   " list of flags for using the mouse
 398 if !has('nvim')
 399   set ttymouse=xterm              " type of mouse
 400 endif
 401
 402 " messages and info {{{2
 403 set showcmd         " Show (partial) command in status line.
 404 set ruler           " show the cursor position all the time
 405 set confirm         " Ask what to do when closing unsaved documents
 406 set shortmess+=a    " all abbreviations
 407 set shortmess+=o    " overwrite file-written message
 408 set shortmess+=O    " file-read message overrides previous
 409 set shortmess+=t    " truncate file message at start
 410 set shortmess+=T    " truncate other messages in the middle
 411 set shortmess+=W    " don't give 'written' or '[w]' when writing a file
 412 set shortmess+=A    " ignore swapfile warning
 413 set shortmess+=I    " no splash screen
 414 set shortmess+=F    " don't give the file info when editing a file
 415 set shortmess+=c    " don't give |ins-completion-menu| messages
 416
 417 " editing text {{{2
 418 set backspace=indent,eol,start  " allow backspacing over everything in insert mode
 419
 420 set showmatch                   " Show matching brackets.
 421
 422 set nojoinspaces                " don't use two spaces after '.' when joining a line
 423 set formatoptions+=j    " Delete comment leader when joining lines
 424 set formatoptions+=c    " Autowrap comments using textwidth
 425 set formatoptions+=r    " Insert comment leader after hitting <Enter>
 426 set formatoptions+=n    " Recognize numbered lists
 427 set formatoptions+=q    " Allow formatting of comments with "gq".
 428 set formatoptions+=l    " do not wrap lines that have been longer when starting insert mode already
 429 set formatoptions+=t    " Auto-wrap text using textwidth
 430 set formatoptions-=o    " Do not insert comment leader after hitting o or O in normal mode
 431
 432 set nrformats-=octal    " don't inc/dec octal numbers with ^[AX]
 433 set nrformats+=unsigned " treat all numbers as unsigned
 434
 435 set complete=.       " scan the current buffer ( 'wrapscan' is ignored)
 436 set complete+=w      " scan buffers from other windows
 437 set complete+=b      " scan other loaded buffers that are in the buffer list
 438 set complete+=u      " scan the unloaded buffers that are in the buffer list
 439 set complete+=t      " scan tags
 440 set complete+=i      " scan current and included files
 441 set complete+=kspell " use the currently active spell checking |spell|
 442
 443 " whether to use a popup menu for Insert mode completion
 444 set completeopt=longest,menuone,preview
 445
 446 " tabs and indent {{{2
 447 set shiftwidth=4                " number of spaces used for each step of (auto)indent
 448 set smarttab                    " a <Tab> in an indent inserts 'shiftwidth' spaces
 449 set softtabstop=4               " if non-zero, number of spaces to insert for a <Tab>
 450 set shiftround                  " round to 'shiftwidth' for "<<" and ">>"
 451 set expandtab                   " expand <Tab> to spaces in Insert mode
 452 set autoindent
 453
 454 set pastetoggle=<F11>           " key sequence to toggle paste mode
 455
 456 " folding {{{2
 457 set foldmethod=marker           " folding type
 458 set foldlevelstart=0            " value for 'foldlevel' when starting to edit a file
 459
 460 " open folds when jumping to line
 461 set foldopen+=jump
 462
 463 set viewoptions=cursor          " save cursor position
 464 set viewoptions+=folds          " save folds
 465
 466 " diff mode {{{2
 467 set diffopt+=filler         " show filler lines
 468 set diffopt+=vertical       " always vertical split
 469 set diffopt+=context:10     " 10 lines context between changes
 470 set diffopt+=internal
 471 set diffopt+=algorithm:patience
 472
 473 " reading and writing files {{{2
 474 set modeline                    " read modelines
 475 set modelines=2                 " only check first/last 2 lines
 476
 477 set writebackup                 " write a backup file before overwriting a file
 478 set backup                      " keep a backup after owerwriting a file
 479 set backupdir=$XDG_CACHE_HOME/vim/backup//
 480
 481 set backupskip+=.netrc          " skip netrc
 482 set backupskip+=/dev/shm/pass*  " skip passwordstore files
 483
 484 set undofile                    " persistent undo history
 485 set undolevels=10000            " moar undos
 486 if !has('nvim')
 487   set undodir=$XDG_CACHE_HOME/vim/undo//
 488 endif
 489
 490 augroup undoskip
 491     au!
 492     au BufWritePre .netrc         setlocal noundofile
 493     au BufWritePre /dev/shm/pass* setlocal noundofile
 494     au BufWritePre /tmp/*         setlocal noundofile
 495 augroup END
 496
 497 set autowrite                   " automatically write a file when leaving a modified buffer
 498 set autoread                    " automatically read a file that has been modified
 499
 500 " the swap file {{{2
 501 set noswapfile
 502 set directory=$XDG_CACHE_HOME/vim/swap//
 503
 504 " command line editing {{{2
 505 set history=5000                " how many command lines are remembered
 506 set wildmenu                    " command-line completion shows a list of matches
 507 set wildmode=longest:full,full  " specifies how command line completion works
 508 set wildignorecase              " ignore case when completing file names
 509
 510 set wildignore+=.hg,.git,.svn                    " Version control
 511 set wildignore+=*.aux,*.out,*.toc                " LaTeX intermediate files
 512 set wildignore+=*.jpg,*.bmp,*.gif,*.png,*.jpeg   " binary images
 513 set wildignore+=*.o,*.obj,*.exe,*.dll,*.manifest " compiled object files
 514 set wildignore+=*.spl                            " compiled spelling word lists
 515 set wildignore+=*.sw?                            " Vim swap files
 516 set wildignore+=*.luac                           " Lua byte code
 517 set wildignore+=*.pyc                            " Python byte code
 518 set wildignore+=*.orig                           " Merge resolution files
 519
 520 " running make and jumping to errors {{{2
 521 set makeprg=make\ -w     " print changing directories
 522
 523 set grepformat=%f:%l:%c:%m
 524 set grepprg=ag\ --vimgrep\ $*
 525
 526 " language specific {{{2
 527 set isfname-==    " don't treat `=` as being part of filenames
 528
 529 " various {{{2
 530 set virtualedit+=block     " let cursor move past last char in <C-V> mode
 531 set virtualedit+=onemore   " allow the cursor to move just past the end of the line
 532 if !has('nvim')
 533   " viminfo defaults but save file in .cache
 534   set viminfo='100,<50,s10,h,n$XDG_CACHE_HOME/vim/viminfo
 535 else
 536   " shada is the replacement format for viminfo
 537   " this setting is probably not needed as it's most likely the default
 538   " the default path is in XDG_DATA_HOME, which is fine
 539   set shada='100,<50,s10,h
 540 endif
 541
 542 set viewdir=$XDG_CACHE_HOME/vim/view//
 543
 544 set sessionoptions+=unix,slash  " damn windows and it's silly ways
 545
 546 " autocmds {{{1
 547 " Resize splits when the window is resized {{{2
 548 augroup resize_splits
 549     au!
 550     autocmd VimResized * :tabdo wincmd =
 551 augroup END
 552
 553 " Only show cursorline in the current window and in normal mode {{{2
 554 augroup cline
 555     au!
 556     au WinLeave,InsertEnter * set nocursorline
 557     au WinEnter,InsertLeave * set cursorline
 558 augroup END
 559
 560 " Treat buffers from stdin (e.g.: echo foo | vim -) as scratch {{{2
 561 augroup ft_stdin
 562     au!
 563     au StdinReadPost * :set buftype=nofile
 564 augroup END
 565
 566 " Jump to last known cursor position {{{2
 567 augroup last_loc
 568     au!
 569     " blacklist certain filetype
 570     let blacklist = ['gitcommit']
 571     autocmd BufReadPost *
 572                 \ if index(blacklist, &ft) < 0 && line("'\"") > 1 && line("'\"") <= line("$") |
 573                 \   exe "normal! g`\"" |
 574                 \ endif
 575 augroup END
 576
 577 " Check for file modifications automatically {{{2
 578 " (current buffer only)
 579 " Use :NoAutoChecktime to disable it (uses b:autochecktime)
 580 fun! MyAutoCheckTime()
 581   " only check timestamp for normal files
 582   if &buftype != '' | return | endif
 583   if ! exists('b:autochecktime') || b:autochecktime
 584     checktime %
 585     let b:autochecktime = 1
 586   endif
 587 endfun
 588 augroup MyAutoChecktime
 589   au!
 590   au FocusGained,BufEnter,CursorHold,InsertEnter * call MyAutoCheckTime()
 591 augroup END
 592 command! NoAutoChecktime let b:autochecktime=0
 593 command! ToggleAutoChecktime let b:autochecktime=!get(b:, 'autochecktime', 0) | echom "b:autochecktime:" b:autochecktime
 594
 595 " bindings {{{1
 596
 597 " make
 598 function! MakeWithOpt()
 599   " TODO only do this if makeprg matches make
 600   " if &makeprg =~ "make"
 601   let l:make_dir = ""
 602   if exists("b:make_dir")
 603     let l:make_dir = "-C ".b:make_dir
 604   elseif exists("t:make_dir")
 605     let l:make_dir = "-C ".t:make_dir
 606   elseif exists("g:make_dir")
 607     let l:make_dir = "-C ".g:make_dir
 608   endif
 609
 610   let l:make_targets = ""
 611   if exists("g:make_targets")
 612     let l:make_targets = g:make_targets
 613   endif
 614   execute "Make ".l:make_dir." ".l:make_targets
 615 endf
 616 nnoremap <silent> <leader>r :call MakeWithOpt()<cr>
 617
 618 " unhighlight search
 619 nnoremap <silent> <Leader>/ :silent nohl<CR>
 620
 621 " Tabs
 622 nnoremap <leader>[ :tabprev<cr>
 623 nnoremap <leader>] :tabnext<cr>
 624
 625 " paste from selection
 626 nnoremap <leader>p* :silent! set paste<CR>"*p:set nopaste<CR>
 627 " paste from clipboard
 628 nnoremap <leader>p+ :silent! set paste<CR>"+p:set nopaste<CR>
 629
 630 " strip trailing whitespace
 631 function! StripWhitespace(line1, line2, ...)  " {{{2
 632   let s_report = &report
 633   let &report=0
 634   let pattern = a:0 ? a:1 : '\s\+$'
 635   let oldview = winsaveview()
 636   exe 'keepjumps keeppatterns '.a:line1.','.a:line2.'substitute/'.pattern.'//e'
 637   if oldview != winsaveview()
 638     redraw
 639   endif
 640   call winrestview(oldview)
 641   let &report = s_report
 642 endfunction  " }}}2
 643 command! -range=% -nargs=0 -bar Untrail keepjumps call StripWhitespace(<line1>,<line2>)
 644 nnoremap <silent> <leader>ww :Untrail<CR>
 645
 646 " Source
 647 vnoremap <leader>S y:execute @@<cr>:echo 'Sourced selection.'<cr>
 648 nnoremap <leader>S ^vg_y:execute @@<cr>:echo 'Sourced line.'<cr>
 649 " Technically this is similar to execute this file, which is usually mapped to
 650 " <leader>r and it would make sense to have that for lua files in nvim folder
 651 nnoremap <leader>SS :source %<cr>:echo 'Sourced file.'<cr>
 652
 653 " jump to last cursor position
 654 noremap ' `
 655
 656 " Select (charwise) the contents of the current line, excluding indentation.
 657 nnoremap vv ^vg_
 658
 659 " Unfuck my screen
 660 nnoremap U
 661       \ :syntax sync fromstart<cr>
 662       \ :AirlineRefresh<cr>
 663       \ :call popup_clear(1)<cr>
 664       \ :redraw!<cr>
 665
 666 " Ranger
 667 " nnoremap <leader>r :silent !ranger %:h<cr>:redraw!<cr>
 668 " nnoremap <leader>R :silent !ranger<cr>:redraw!<cr>
 669
 670 " display the number of matches for the last search
 671 nmap <Leader># :%s:<C-R>/::gn<CR>
 672
 673 " center cursor after search and open folds
 674 nnoremap n nzzzv
 675 nnoremap N Nzzzv
 676
 677 " same when jumping around
 678 nnoremap g; g;zzzv
 679 nnoremap g, g,zzzv
 680 nnoremap <c-o> <c-o>zzzv
 681 nnoremap <c-i> <c-i>zzzv
 682
 683 " Not using the default mappings of 'To line from top/bottom'
 684 noremap H ^
 685 noremap L $
 686 vnoremap H ^
 687 vnoremap L g_
 688
 689 " Heresy, emacs insert bindings
 690 inoremap <C-A> <Esc>I
 691 inoremap <C-E> <Esc>A
 692 cnoremap <C-A> <Home>
 693 cnoremap <C-E> <End>
 694
 695 " proper movement when lines are wrapped
 696 noremap <silent><expr> j (v:count == 0 ? 'gj' : 'j')
 697 noremap <silent><expr> k (v:count == 0 ? 'gk' : 'k')
 698
 699 " disable arrows
 700 noremap  <Up>    <NOP>
 701 noremap  <Down>  <NOP>
 702 noremap  <Left>  <NOP>
 703 noremap  <Right> <NOP>
 704 inoremap <Up>    <NOP>
 705 inoremap <Down>  <NOP>
 706 inoremap <Left>  <NOP>
 707 inoremap <Right> <NOP>
 708 cnoremap <Up>    <NOP>
 709 cnoremap <Down>  <NOP>
 710 cnoremap <Left>  <NOP>
 711 cnoremap <Right> <NOP>
 712 cnoremap <C-K>   <Up>
 713 cnoremap <C-J>   <Down>
 714 cnoremap <C-H>   <Left>
 715 cnoremap <C-L>   <Right>
 716
 717 " close all folds open fold in cursor
 718 nnoremap zx zMzxzt
 719
 720 map <F1> :ls<CR>:b<space>
 721
 722 " move between windows (skip previewwindow)
 723 nnoremap <silent> <C-L> <C-W>w<C-W>:if &previewwindow \| wincmd w \| endif<CR>
 724 nnoremap <silent> <C-H> <C-W>W<C-W>:if &previewwindow \| wincmd W \| endif<CR>
 725 tnoremap <silent> <C-L> <C-W>w<C-W>:if &previewwindow \| wincmd w \| endif<CR>
 726 tnoremap <silent> <C-H> <C-W>W<C-W>:if &previewwindow \| wincmd W \| endif<CR>
 727
 728 "xterm mouse with middleclick paste
 729 nnoremap <MiddleMouse> i<MiddleMouse>
 730 vnoremap <MiddleMouse> s<MiddleMouse>
 731
 732 " fix legacy vi inconsistency
 733 nnoremap Y y$
 734 " copy to clipboard
 735 xnoremap Y "+y
 736
 737 " allow repeat operator on visual
 738 vnoremap . :normal .<CR>
 739
 740 " add line without changing position or leaving mode
 741 noremap <silent> <Leader>o :set paste<CR>m`o<ESC>``:set nopaste<CR>
 742 noremap <silent> <Leader>O :set paste<CR>m`O<ESC>``:set nopaste<CR>
 743
 744 " Don't use Ex mode, use Q for formatting
 745 map Q gq
 746
 747 " break undo sequence before removing word
 748 inoremap <C-W> <C-G>u<C-W>
 749
 750 nnoremap coe :set <C-R>=&expandtab ? 'noexpandtab' : 'expandtab'<CR><CR>
 751 nnoremap [oe :set expandtab<CR>
 752 nnoremap ]oe :set noexpandtab<CR>
 753
 754 for idt in range(1,8)
 755   exe 'nnoremap co'.idt.' :setlocal tabstop='.idt.' shiftwidth='.idt.' softtabstop='.idt.'<CR>'
 756 endfor
 757
 758 " toggle auto format of text
 759 nnoremap coa :set <C-R>=&formatoptions =~ "a" ? 'formatoptions-=a' : 'formatoptions+=a'<CR><CR>
 760 nnoremap [oa :set formatoptions+=a<CR>
 761 nnoremap ]oa :set formatoptions-=a<CR>
 762
 763 " space will toggle current fold in normal mode
 764 nnoremap <leader><Space> za
 765 " create folds around visual selection
 766 vnoremap <leader><Space> zf
 767
 768 " save with sudo
 769 cabbrev w!! SudoWrite
 770
 771 " uppercase previous word
 772 inoremap <C-C> <C-G>u<Esc>gUiwgi
 773
 774 " http://git.io/v3ZeU
 775 nmap <silent> <leader>qq :echo "hi<" . synIDattr(synID(line("."),col("."),1),"name") . '> trans<' . synIDattr(synID(line("."),col("."),0),"name") . "> lo<" . synIDattr(synIDtrans(synID(line("."),col("."),1)),"name") . ">"<CR>
 776
 777 " plugins options {{{1
 778 " checkattach {{{2
 779 let g:checkattach_filebrowser = 'ranger'
 780 let g:checkattach_once = 'y'
 781
 782 " close-another-window {{{2
 783 nnoremap <silent> <C-W>c  <NOP>
 784 nnoremap <silent> <C-W>cc <C-W>c
 785 nnoremap <silent> <C-W>ch :CloseLeftWindow<CR>
 786 nnoremap <silent> <C-W>cl :CloseRightWindow<CR>
 787 nnoremap <silent> <C-W>cj :CloseBelowWindow<CR>
 788 nnoremap <silent> <C-W>ck :CloseAboveWindow<CR>
 789
 790
 791 " fswitch {{{2
 792 nnoremap <silent> <Leader>ff :FSHere<CR>
 793 nnoremap <silent> <Leader>fl :FSRight<CR>
 794 nnoremap <silent> <Leader>fh :FSLeft<CR>
 795 nnoremap <silent> <Leader>fj :FSBelow<CR>
 796 nnoremap <silent> <Leader>fk :FSAbove<CR>
 797 nnoremap <silent> <Leader>fL :FSSplitRight<CR>
 798 nnoremap <silent> <Leader>fH :FSSplitLeft<CR>
 799 nnoremap <silent> <Leader>fJ :FSSplitBelow<CR>
 800 nnoremap <silent> <Leader>fK :FSSplitAbove<CR>
 801
 802 " fugitive {{{2
 803 nmap <silent> <leader>dd :tab split \| Gdiff \| wincmd h<CR>
 804 " delete fugitive buffers when closed
 805 autocmd BufReadPost fugitive://* set bufhidden=delete
 806
 807 function! GitToggle()
 808   let l:status_buffer = bufname('^fugitive:///*/.git{/worktrees/*,}//$')
 809   if buflisted(l:status_buffer)
 810     execute 'bdelete '.l:status_buffer
 811   else
 812     execute 'Git'
 813     if !empty(FugitiveGitDir())
 814       " only resize status if Git was sucessful
 815       16wincmd_
 816     endif
 817   endif
 818 endfunction
 819 command! GitToggle :call GitToggle()
 820 command! GToggle GitToggle
 821 nnoremap <silent> <leader>gs :GitToggle<CR>
 822
 823 nnoremap <silent> <leader>gd :Gdiffsplit<CR>
 824 nnoremap <silent> <leader>gcc :tab G commit -v<CR>
 825 nnoremap <silent> <leader>gca :tab G commit -v --amend<CR>
 826 nnoremap          <leader>gcf :tab G commit -v --fixup=
 827 nnoremap <silent> <leader>gpp :Git push \| copen<CR>
 828 nnoremap <silent> <leader>gpf :Git push --force-with-lease \| copen<CR>
 829 nnoremap <silent> <leader>gll :Git pull<CR>
 830 nnoremap <silent> <leader>gru :Git rebase --interactive @{upstream}<CR>
 831 nnoremap <silent> <leader>grp :Git rebase --interactive @{push}<CR>
 832 nnoremap <silent> <leader>ga :Gwrite<cr>
 833 nnoremap <silent> <leader>gb :G blame<cr>
 834
 835 augroup fugitive_gstatus
 836     au!
 837     autocmd User FugitiveIndex setlocal winfixheight
 838     autocmd User FugitiveIndex nmap <buffer> <leader><space> =
 839 augroup end
 840
 841 " Gundo {{{2
 842 nnoremap <F7> :GundoToggle<CR>
 843 let g:gundo_prefer_python3 = 1
 844
 845 " indent-guides {{{2
 846 let g:indent_guides_default_mapping = 0
 847 let g:indent_guides_guide_size = 1
 848 nmap <silent> cog <Plug>IndentGuidesToggle
 849 nmap <silent> [og <Plug>IndentGuidesEnable
 850 nmap <silent> ]og <Plug>IndentGuidesDisable
 851
 852 " netrw {{{2
 853 let g:netrw_sort_sequence = '[\/]$,\.\%(h\|hpp\)$,\.c$,\.cpp$,\~\=\*$,*,\.o$,\.obj$,\.info$,\.swp$,\.bak$,\~$'
 854
 855 " signature {{{2
 856 " disable '[ mappings
 857
 858 let g:SignatureMap = {
 859   \ 'GotoNextLineAlpha'  :  "",
 860   \ 'GotoPrevLineAlpha'  :  "",
 861   \ 'GotoNextSpotAlpha'  :  "",
 862   \ 'GotoPrevSpotAlpha'  :  "",
 863   \ }
 864
 865 " switch
 866 let g:switch_mapping = "<Leader>s"
 867 let g:switch_custom_definitions = [
 868       \   ['yes', 'no']
 869       \ ]
 870
 871 " spellrotate
 872 nmap <silent> z] <Plug>(SpellRotateForward)
 873 nmap <silent> z[ <Plug>(SpellRotateBackward)
 874 vmap <silent> z] <Plug>(SpellRotateForwardV)
 875 vmap <silent> z[ <Plug>(SpellRotateBackwardV)
 876
 877 " synastic {{{2
 878 let g:syntastic_enable_highlighting = 0
 879 let g:syntastic_error_symbol='E'
 880 let g:syntastic_style_error_symbol='S'
 881 let g:syntastic_warning_symbol='W'
 882 let g:syntastic_style_warning_symbol='S'
 883 let g:syntastic_always_populate_loc_list=1
 884 nmap <silent> <leader>y :SyntasticCheck<cr>
 885
 886 let g:syntastic_cpp_clang_tidy_post_args = "-p build*"
 887
 888 if ! &diff
 889   let g:syntastic_check_on_open=1
 890 endif
 891
 892
 893 " vim-easy-align {{{2
 894 " start interactive EasyAlign in visual mode
 895 vmap <Enter>   <Esc>:echohl WarningMsg \| echo "EasyAlign mapped to \16<leader>a now" \| echohl None<CR>
 896 vmap <leader>a <Plug>(EasyAlign)
 897 nmap <leader>a <Plug>(EasyAlign)
 898
 899 " vim-gtest {{{2
 900 let g:gtest#highlight_failing_tests = 0
 901
 902 nnoremap <silent> <Leader>tt :GTestRun<CR>
 903 nnoremap          <Leader>tc :GTestCase<space>
 904 nnoremap          <Leader>tn :GTestName<space>
 905 nnoremap <silent> <Leader>ta :GTestCase *<CR>:GTestName *<CR>:GTestRun<CR>
 906 nnoremap <silent> <Leader>tu :GTestRunUnderCursor<CR>
 907
 908 " vim-json {{{2
 909 let g:vim_json_syntax_conceal = 0
 910
 911 " functions {{{1
 912
 913 " Convenient command to see the difference between the current buffer and the
 914 " file it was loaded from, thus the changes you made.
 915 " Only define it when not defined already.
 916 if !exists(":DiffOrig")
 917   command DiffOrig vert new | set bt=nofile | r # | 0d_ | diffthis
 918                   \ | wincmd p | diffthis
 919 endif
 920
 921 " sort operator {{{2
 922 function! SortLinesOpFunc(...)
 923   '[,']sort
 924 endfunction
 925 nnoremap <silent> gs :<C-U>set operatorfunc=SortLinesOpFunc<CR>g@
 926 vnoremap <silent> gs :sort<cr>
 927
 928 " edit configs  {{{2
 929 " TODO: populate location list with both .vim and .lua files
 930 " TODO: create file if it doesn't exist in nvim or vim rtps
 931 function! EditConfig(what, ext = '.vim')
 932     if a:what == 'vimrc' || a:what == 'init.lua'
 933         let l:file = a:what
 934     elseif empty(&filetype)
 935         echoe 'filetype is empty!'
 936         return
 937     else
 938         let l:file = a:what.'/'.&filetype.a:ext
 939     endif
 940
 941     execute ':Vvsplit! '.file
 942 endf
 943 nmap <leader>en :call EditConfig('init.lua')<CR>
 944 nmap <leader>ev :call EditConfig('vimrc')<CR>
 945 nmap <leader>ef :call EditConfig('ftplugin')<CR>
 946 nmap <leader>es :call EditConfig('syntax')<CR>
 947 nmap <leader>ei :call EditConfig('indent')<CR>
 948 nmap <leader>eu :call EditConfig('ultisnips', '.snippets')<CR>
 949
 950 " spell check {{{2
 951 " http://tex.stackexchange.com/a/52932
 952 let g:myLangList=["en_gb","en_us","de","fr"]
 953
 954 function! ToggleSpell()
 955   if !exists("b:myLang")
 956     let b:myLang=0
 957   endif
 958   execute "setlocal spell!"
 959   if (&spell)
 960     echo "setlocal spelllang=" g:myLangList[b:myLang]
 961   endif
 962 endfunction
 963
 964 function! SwitchSpell()
 965   if !exists("b:myLang")
 966     let b:myLang=0
 967   endif
 968   if (&spell)
 969     let b:myLang=b:myLang+1
 970     if b:myLang>=len(g:myLangList) | let b:myLang=0 | endif
 971   endif
 972   execute "setlocal spell spelllang=".get(g:myLangList, b:myLang)
 973   echo "setlocal spelllang=" g:myLangList[b:myLang]
 974 endfunction
 975
 976 nnoremap <silent> coS :call SwitchSpell()<CR>
 977
 978 " gitdir or home {{{2
 979 " from derek wyatt:
 980 " http://git.io/v3GAV
 981 function! FindGitDirOrHome()
 982   let filedir = expand('%:p:h')
 983   if isdirectory(filedir)
 984     let cmd = 'bash -c "(cd ' . filedir . '; git rev-parse --show-toplevel 2>/dev/null)"'
 985     let gitdir = system(cmd)
 986     if strlen(gitdir) == 0
 987       return '~'
 988     else
 989       return gitdir[:-2]
 990     endif
 991   else
 992     return '~'
 993   endif
 994 endfunction
 995 command! Cd cd %:h
 996 command! Cdr execute('cd ' . FindGitDirOrHome())
 997 command! LCd lcd %:h
 998 command! LCdr execute('lcd ' . FindGitDirOrHome())
 999
1000 " vim:set et sw=2 ts=2 tw=78: