vim/vimrc

   1 " My vimrc.
   2 "
   3 " Author:   Samir Benmendil <samir.benmendil[at]gmail[dot]com>
   4 "
   5
   6 " plugins {{{1
   7 filetype off
   8 set runtimepath& " reset rtp
   9 " remove all autocommands
  10 autocmd!
  11
  12 set runtimepath+=$XDG_DATA_HOME/vim/vundle
  13 call vundle#rc('$XDG_DATA_HOME/vim')
  14
  15 Plugin 'gmarik/vundle'
  16
  17 Plugin 'airblade/vim-gitgutter'
  18 Plugin 'bling/vim-airline'
  19 Plugin 'derekwyatt/vim-fswitch'
  20 Plugin 'elzr/vim-json'
  21 Plugin 'firef0x/pkgbuild.vim'
  22 Plugin 'junegunn/vim-easy-align'
  23 " Plugin 'kien/ctrlp.vim'
  24 " Plugin 'klen/python-mode'
  25 Plugin 'wilywampa/python-mode'
  26 Plugin 'kshenoy/vim-signature'
  27 Plugin 'majutsushi/tagbar'
  28 Plugin 'raimondi/delimitmate'
  29 " Plugin 'rking/ag.vim'
  30 Plugin 'scrooloose/syntastic'
  31 Plugin 'shougo/vimproc.vim'
  32 Plugin 'shougo/unite.vim'
  33 Plugin 'sjl/gundo.vim'
  34 Plugin 'tomtom/tcomment_vim'
  35 Plugin 'tpope/vim-endwise'
  36 Plugin 'tpope/vim-fugitive'
  37 Plugin 'tpope/vim-repeat'
  38 Plugin 'tpope/vim-surround'
  39 Plugin 'tpope/vim-unimpaired'
  40 Plugin 'valloric/youcompleteme'
  41 Plugin 'vim-scripts/yankring.vim'
  42
  43 " snippets
  44 Plugin 'sirver/ultisnips'
  45 Plugin 'honza/vim-snippets'
  46
  47 " text objects
  48 Plugin 'kana/vim-textobj-user'
  49 Plugin 'julian/vim-textobj-variable-segment'
  50 Plugin 'sgur/vim-textobj-parameter'
  51
  52 " ros
  53 Plugin 'ompugao/ros.vim'
  54 Plugin 'ompugao/ctrlp-ros'
  55
  56 " seems to have problems right now... may be add later?
  57 " Plugin 'jalcine/cmake.vim'
  58 " Plugin 'powerman/vim-plugin-viewdoc'
  59
  60 " staging
  61 " find an alternative (latex-box? Automatic Latex Plugin?)
  62 Plugin 'http://git.code.sf.net/p/vim-latex/vim-latex'
  63 " Plugin 'lokaltog/vim-easymotion'
  64 Plugin 'justinmk/vim-sneak'
  65 Plugin 'chrisbra/checkattach'
  66 Plugin 'nathanaelkane/vim-indent-guides'
  67 Plugin 'alx741/vinfo'
  68 Plugin 'octol/vim-cpp-enhanced-highlight'
  69 Plugin 'vim-scripts/mediawiki.vim'
  70 Plugin 'vim-scripts/replacewithregister'
  71 Plugin 'tpope/vim-abolish'
  72 Plugin 'derekwyatt/vim-protodef'
  73
  74 " remove entries first
  75 set runtimepath -=$HOME/.vim
  76 set runtimepath -=$HOME/.vim/after
  77 set runtimepath -=$XDG_CONFIG_HOME/vim
  78 set runtimepath -=$XDG_CONFIG_HOME/vim/after
  79 " then prepend and append them
  80 set runtimepath ^=$XDG_CONFIG_HOME/vim
  81 set runtimepath +=$XDG_CONFIG_HOME/vim/after
  82
  83 filetype plugin indent on
  84
  85 " colorscheme {{{1
  86 syntax on
  87 colorscheme badwolf
  88
  89 " options {{{1
  90 " put $ and the end of text to be replaced with 'cw' and the likes
  91 set cpoptions+=$
  92
  93 " moving around, searching and patterns {{{2
  94 set incsearch           " show match for partly typed search command
  95 set ignorecase          " ignore case when using a search pattern
  96 set smartcase           " override 'ignorecase' when pattern has upper case characters
  97 set hlsearch            " highlight all matches for the last used search pattern
  98
  99 set nostartofline       " don't move the cursor to the first non-blank char of a line
 100 set path+=.
 101 set path+=include/
 102 set path+=../include/
 103 set path+=/usr/include/c++/*
 104
 105 " displaying text {{{2
 106 set nowrap                      " long lines wrap
 107 set linebreak                   " wrap long lines at a character in 'breakat'
 108 set showbreak=↪                 " show these chars for wrapped lines
 109 set breakindent                 " preserve indentation in wrapped text
 110
 111 set lazyredraw                  " don't redraw while executing macros
 112
 113 set list                        " show chars defined in 'listchars'
 114 set listchars=tab:❭\            " list of strings used for list mode
 115 set listchars+=extends:❯,precedes:❮
 116 " Only shown when not in insert mode
 117 au InsertLeave * :set listchars+=trail:·
 118 augroup trailing
 119     au!
 120     au InsertEnter * :set listchars-=trail:·
 121     au InsertLeave * :set listchars+=trail:·
 122 augroup END
 123
 124 set scrolloff=5                 " number of screen lines to show around the cursor
 125 set sidescroll=1                " number of collumns to scroll
 126 set sidescrolloff=1             " don't scroll over the listchars
 127
 128 set fillchars=diff:⣿,vert:│
 129
 130 set nonumber                    " show the line number for each line
 131 set norelativenumber            " show the relative line number for each line
 132
 133 " syntax, highlighting and spelling {{{2
 134 set synmaxcol=800               " don't highlight long lines
 135
 136 set dictionary=spell            " list of dictionary files for keyword completion
 137
 138 set colorcolumn=+1
 139
 140 " multiple windows {{{2
 141 set laststatus=2                " 0, 1 or 2; when to use a status line for the last window
 142
 143 set previewheight=20            " default height for the preview window
 144
 145 set hidden
 146
 147 " set splitbelow                  " a new window is put below of the current one
 148 set splitright                  " a new window is put right of the current one
 149
 150 " terminal {{{2
 151 set ttyfast
 152
 153 " using the mouse {{{2
 154 set mouse=rnv                   " list of flags for using the mouse
 155 set ttymouse=xterm              " type of mouse
 156
 157 " messages and info {{{2
 158 set showcmd                     " Show (partial) command in status line.
 159 set ruler                       " show the cursor position all the time
 160 set confirm                     " Ask what to do when closing unsaved documents
 161 set shortmess=filnxtoOI         " don't show intro message
 162
 163 " editing text {{{2
 164 set backspace=indent,eol,start  " allow backspacing over everything in insert mode
 165
 166 set showmatch                   " Show matching brackets.
 167
 168 set nojoinspaces                " don't use two spaces after '.' when joining a line
 169 set formatoptions+=j    " Delete comment leader when joining lines
 170 set formatoptions+=c    " Autowrap comments using textwidth
 171 set formatoptions+=r    " Insert comment leader after hitting <Enter>
 172 set formatoptions+=n    " Recognize numbered lists
 173 set formatoptions+=q    " Allow formatting of comments with "gq".
 174 set formatoptions+=l    " do not wrap lines that have been longer when starting insert mode already
 175 set formatoptions+=t    " Auto-wrap text using textwidth
 176 set formatoptions-=o    " Do not insert comment leader after hitting o or O in normal mode
 177
 178 set nrformats=hex               " number formats recognized for CTRL-A and CTRL-X commands
 179
 180 set complete=.       " scan the current buffer ( 'wrapscan' is ignored)
 181 set complete+=w      " scan buffers from other windows
 182 set complete+=b      " scan other loaded buffers that are in the buffer list
 183 set complete+=u      " scan the unloaded buffers that are in the buffer list
 184 set complete+=t      " scan tags
 185 set complete+=i      " scan current and included files
 186 set complete+=kspell " use the currently active spell checking |spell|
 187
 188 " whether to use a popup menu for Insert mode completion
 189 set completeopt=longest,menuone,preview
 190
 191 " tabs and indent {{{2
 192 set shiftwidth=4                " number of spaces used for each step of (auto)indent
 193 set smarttab                    " a <Tab> in an indent inserts 'shiftwidth' spaces
 194 set softtabstop=4               " if non-zero, number of spaces to insert for a <Tab>
 195 set shiftround                  " round to 'shiftwidth' for "<<" and ">>"
 196 set expandtab                   " expand <Tab> to spaces in Insert mode
 197 set autoindent
 198
 199 set pastetoggle=<F11>           " key sequence to toggle paste mode
 200
 201 " folding {{{2
 202 set foldmethod=marker           " folding type
 203 set foldlevelstart=0            " value for 'foldlevel' when starting to edit a file
 204
 205 " open folds when jumping to line
 206 set foldopen+=jump
 207
 208 " save and restore folds
 209 set viewoptions=cursor          " only save cursor position
 210
 211 " diff mode {{{2
 212 set diffopt+=filler         " show filler lines
 213 set diffopt+=vertical       " always vertical split
 214 set diffopt+=iwhite         " ignore white space
 215
 216 " reading and writing files {{{2
 217 set modeline                    " read modelines
 218 set modelines=2                 " only check first/last 2 lines
 219
 220 set writebackup                 " write a backup file before overwriting a file
 221 set backup                      " keep a backup after owerwriting a file
 222 set backupdir=$XDG_CACHE_HOME/vim/backup//
 223
 224 set backupskip+=.netrc          " skip netrc
 225 set backupskip+=/dev/shm/pass*  " skip passwordstore files
 226
 227 set undofile                    " persistent undo history
 228 set undodir=$XDG_CACHE_HOME/vim/undo//
 229
 230 augroup undoskip
 231     au!
 232     au BufWritePre .netrc         setlocal noundofile
 233     au BufWritePre /dev/shm/pass* setlocal noundofile
 234     au BufWritePre /tmp/*         setlocal noundofile
 235 augroup END
 236
 237 set autowrite                   " automatically write a file when leaving a modified buffer
 238 set autoread                    " automatically read a file that has been modified
 239
 240 " the swap file {{{2
 241 set noswapfile
 242 set directory=$XDG_CACHE_HOME/vim/swap//
 243
 244 " command line editing {{{2
 245 set history=5000                " how many command lines are remembered
 246 set wildmenu                    " command-line completion shows a list of matches
 247 set wildmode=longest:full,full  " specifies how command line completion works
 248
 249 set wildignore+=.hg,.git,.svn                    " Version control
 250 set wildignore+=*.aux,*.out,*.toc                " LaTeX intermediate files
 251 set wildignore+=*.jpg,*.bmp,*.gif,*.png,*.jpeg   " binary images
 252 set wildignore+=*.o,*.obj,*.exe,*.dll,*.manifest " compiled object files
 253 set wildignore+=*.spl                            " compiled spelling word lists
 254 set wildignore+=*.sw?                            " Vim swap files
 255 set wildignore+=*.luac                           " Lua byte code
 256 set wildignore+=*.pyc                            " Python byte code
 257 set wildignore+=*.orig                           " Merge resolution files
 258
 259 " various {{{2
 260 set virtualedit=all             " let cursor move past last char in <C-V> mode
 261 set viminfo='100,<50,s10,h,n$XDG_CACHE_HOME/vim/viminfo " viminfo defaults but save file in .cache
 262
 263 set viewdir=$XDG_CACHE_HOME/vim/view//
 264
 265 " autocmds {{{1
 266 " Resize splits when the window is resized {{{2
 267 augroup resize
 268     au!
 269     autocmd VimResized * :wincmd =
 270 augroup END
 271
 272 " Only show cursorline in the current window and in normal mode {{{2
 273 augroup cline
 274     au!
 275     au WinLeave,InsertEnter * set nocursorline
 276     au WinEnter,InsertLeave * set cursorline
 277 augroup END
 278
 279 " Treat buffers from stdin (e.g.: echo foo | vim -) as scratch {{{2
 280 augroup ft_stdin
 281     au!
 282     au StdinReadPost * :set buftype=nofile
 283 augroup END
 284
 285 " Jump to last known cursor position {{{2
 286 augroup cursor_pos
 287     au!
 288     " blacklist certain filetype
 289     let blacklist = ['gitcommit']
 290     autocmd BufReadPost *
 291                 \ if index(blacklist, &ft) < 0 && line("'\"") > 1 && line("'\"") <= line("$") |
 292                 \   exe "normal! g`\"" |
 293                 \ endif
 294 augroup END
 295
 296 " bindings {{{1
 297
 298 " allow both <space> and / to be <leader>
 299 map <space> <leader>
 300
 301 " make
 302 nnoremap <leader>r :make<cr>
 303 nnoremap <leader><cr> :make<cr>
 304
 305 " unhighlight search
 306 nnoremap <silent> <Leader>/ :silent nohl<CR>
 307
 308 " Tabs
 309 nnoremap <leader>[ :tabprev<cr>
 310 nnoremap <leader>] :tabnext<cr>
 311
 312 " paste from selection
 313 nnoremap <leader>p* :silent! set paste<CR>"*p:set nopaste<CR>
 314 " paste from clipboard
 315 nnoremap <leader>p+ :silent! set paste<CR>"+p:set nopaste<CR>
 316
 317 " Clean trailing whitespace
 318 nnoremap <silent> <leader>ww m':%s/\s\+$//<cr>:let @/=''<cr>``zz
 319
 320 " Source
 321 vnoremap <leader>S y:execute @@<cr>:echo 'Sourced selection.'<cr>
 322 nnoremap <leader>S ^vg_y:execute @@<cr>:echo 'Sourced line.'<cr>
 323
 324 " jump to last cursor position
 325 noremap ' `
 326
 327 " Select (charwise) the contents of the current line, excluding indentation.
 328 nnoremap vv ^vg_
 329
 330 " Unfuck my screen
 331 nnoremap U :syntax sync fromstart<cr>:AirlineRefresh<cr>:redraw!<cr>
 332
 333 " Ranger
 334 " nnoremap <leader>r :silent !ranger %:h<cr>:redraw!<cr>
 335 " nnoremap <leader>R :silent !ranger<cr>:redraw!<cr>
 336
 337 " Use sane regexes.
 338 nnoremap / /\v
 339 vnoremap / /\v
 340 cnoremap s/ s/\v
 341
 342 " display the number of matches for the last search
 343 nmap <Leader># :%s:<C-R>/::gn<CR>
 344
 345 " center cursor after search and open folds
 346 nnoremap n nzzzv
 347 nnoremap N Nzzzv
 348
 349 " same when jumping around
 350 nnoremap g; g;zzzv
 351 nnoremap g, g,zzzv
 352 nnoremap <c-o> <c-o>zzzv
 353 nnoremap <c-i> <c-i>zzzv
 354
 355 " Not using the default mappings of 'To line from top/bottom'
 356 noremap H ^
 357 noremap L $
 358 vnoremap H ^
 359 vnoremap L g_
 360
 361 " Heresy, emacs insert bindings
 362 inoremap <C-A> <Esc>I
 363 inoremap <C-E> <Esc>A
 364 cnoremap <C-A> <Home>
 365 cnoremap <C-E> <End>
 366
 367 " proper movement when lines are wrapped
 368 noremap <expr> j (v:count == 0 ? 'gj' : 'j')
 369 noremap <expr> k (v:count == 0 ? 'gk' : 'k')
 370
 371 " disable arrows
 372 noremap  <Up>    <NOP>
 373 noremap  <Down>  <NOP>
 374 noremap  <Left>  <NOP>
 375 noremap  <Right> <NOP>
 376 inoremap <Up>    <NOP>
 377 inoremap <Down>  <NOP>
 378 inoremap <Left>  <NOP>
 379 inoremap <Right> <NOP>
 380 cnoremap <Up>    <NOP>
 381 cnoremap <Down>  <NOP>
 382 cnoremap <Left>  <NOP>
 383 cnoremap <Right> <NOP>
 384 cnoremap <C-K>   <Up>
 385 cnoremap <C-J>   <Down>
 386 cnoremap <C-H>   <Left>
 387 cnoremap <C-L>   <Right>
 388
 389 " close all folds open fold in cursor
 390 nnoremap zx zMzxzt
 391
 392 map <F1> :ls<CR>:b<space>
 393
 394 nnoremap <C-L> <C-W>w
 395 nnoremap <C-H> <C-W>W
 396
 397 "xterm mouse with middleclick paste
 398 nnoremap <MiddleMouse> i<MiddleMouse>
 399 vnoremap <MiddleMouse> s<MiddleMouse>
 400
 401 " fix legacy vi inconsistency
 402 map Y y$
 403
 404 " allow repeat operator on visual
 405 vnoremap . :normal .<CR>
 406
 407 " add line without changing position or leaving mode
 408 noremap <silent> <Leader>o :set paste<CR>m`o<ESC>``:set nopaste<CR>
 409 noremap <silent> <Leader>O :set paste<CR>m`O<ESC>``:set nopaste<CR>
 410
 411 " Don't use Ex mode, use Q for formatting
 412 map Q gq
 413
 414 " break undo sequence before removing word
 415 inoremap <C-W> <C-G>u<C-W>
 416
 417 nnoremap coe :set <C-R>=&expandtab ? 'noexpandtab' : 'expandtab'<CR><CR>
 418 nnoremap [oe :set expandtab<CR>
 419 nnoremap ]oe :set noexpandtab<CR>
 420
 421 for idt in range(1,8)
 422   exe 'nnoremap co'.idt.' :set tabstop='.idt.' shiftwidth='.idt.' softtabstop='.idt.'<CR>'
 423 endfor
 424
 425 " space will toggle current fold in normal mode
 426 nnoremap <leader><Space> za
 427 " create folds around visual selection
 428 vnoremap <leader><Space> zf
 429
 430 autocmd BufWinLeave *.* mkview
 431 autocmd BufWinEnter *.* silent loadview
 432
 433 " save with sudo
 434 cabbrev w!! w !sudo tee % > /dev/null
 435
 436 " uppercase previous word
 437 inoremap <C-C> <Esc>gUiwgi
 438
 439 " http://git.io/v3ZeU
 440 nmap <silent> <leader>qq :echo "hi<" . synIDattr(synID(line("."),col("."),1),"name") . '> trans<' . synIDattr(synID(line("."),col("."),0),"name") . "> lo<" . synIDattr(synIDtrans(synID(line("."),col("."),1)),"name") . ">"<CR>
 441
 442 " commands {{{1
 443 command! Cd lcd %:h
 444 command! Cr execute('lcd ' . FindGitDirOrHome())
 445
 446 " plugins options {{{1
 447 " airline {{{2
 448 let g:airline#extensions#whitespace#enabled = 1
 449 let g:airline#extensions#tabline#enabled = 1
 450 let g:airline_powerline_fonts = 1
 451
 452 " checkattach {{{2
 453 let g:checkattach_filebrowser = 'ranger'
 454 let g:checkattach_once = 'y'
 455
 456 " delimitmate {{{2
 457 let delimitMate_expand_cr = 2
 458 let g:delimitMate_expand_space = 1
 459
 460 " fswitch {{{2
 461 nnoremap <silent> <Leader>ff :FSHere<CR>
 462 nnoremap <silent> <Leader>fl :FSRight<CR>
 463 nnoremap <silent> <Leader>fh :FSLeft<CR>
 464 nnoremap <silent> <Leader>fj :FSBelow<CR>
 465 nnoremap <silent> <Leader>fk :FSAbove<CR>
 466 nnoremap <silent> <Leader>fL :FSSplitRight<CR>
 467 nnoremap <silent> <Leader>fH :FSSplitLeft<CR>
 468 nnoremap <silent> <Leader>fJ :FSSplitBelow<CR>
 469 nnoremap <silent> <Leader>fK :FSSplitAbove<CR>
 470
 471 " fugitive {{{2
 472 nmap <silent> <leader>dd :tab split \| Gdiff \| wincmd h<CR>
 473 " delete fugitive buffers when closed
 474 autocmd BufReadPost fugitive://* set bufhidden=delete
 475
 476 nnoremap <silent> <leader>gs :Gstatus<CR>
 477 nnoremap <silent> <leader>gd :Gdiff<CR>
 478 nnoremap <silent> <leader>gc :Gcommit -v<CR>
 479 nnoremap <silent> <leader>ga :Gwrite<cr>
 480 nnoremap <silent> <leader>gb :Gblame<cr>
 481
 482 " Gundo {{{2
 483 nnoremap <F7> :GundoToggle<CR>
 484
 485 " indent-guides {{{2
 486 let g:indent_guides_default_mapping = 0
 487 let g:indent_guides_guide_size = 1
 488 nmap <silent> cog <Plug>IndentGuidesToggle
 489 nmap <silent> [og <Plug>IndentGuidesEnable
 490 nmap <silent> ]og <Plug>IndentGuidesDisable
 491
 492 " python-mode {{{2
 493
 494 let g:pymode_rope_completion = 0
 495 let g:pymode_rope = 0
 496 let g:pymode_folding = 1
 497 let g:pymode_lint_ignore = "E221,E266,E501"
 498 let g:pymode_syntax_space_errors = 0    " don't bother me when I'm typing
 499
 500 " synastic {{{2
 501 let g:syntastic_enable_highlighting = 0
 502 let g:syntastic_error_symbol='E'
 503 let g:syntastic_style_error_symbol='S'
 504 let g:syntastic_warning_symbol='W'
 505 let g:syntastic_style_warning_symbol='S'
 506 let g:syntastic_always_populate_loc_list=1
 507 nmap <silent> <leader>y :SyntasticCheck<cr>
 508
 509 if ! &diff
 510   let g:syntastic_check_on_open=1
 511 endif
 512
 513 " tagbar {{{2
 514 map <F5> :TagbarToggle<cr>
 515 let g:tagbar_sort = 0
 516 let g:tagbar_compact = 1
 517 let g:tagbar_autoshowtag = 1
 518 let g:tagbar_width = 25
 519 let g:tagbar_iconchars = ['+', '-']
 520
 521 " ultisnips {{{2
 522 let g:UltiSnipsEditSplit = 'vertical'
 523 let g:UltiSnipsSnippetsDir = expand("$XDG_CONFIG_HOME/vim/ultisnips")
 524 let g:UltiSnipsSnippetDirectories = ["UltiSnips", "ultisnips"]
 525 let g:UltiSnipsExpandTrigger       = "<tab>"
 526 let g:UltiSnipsJumpForwardTrigger  = "<tab>"
 527 let g:UltiSnipsJumpBackwardTrigger = "<s-tab>"
 528
 529 " UltiSnips completion function that tries to expand a snippet. If there's no
 530 " snippet for expanding, it checks for completion window and if it's shown,
 531 " selects first element. If there's no completion window it tries to jump to
 532 " next placeholder. If there's no placeholder it just returns TAB key
 533 " https://github.com/Valloric/YouCompleteMe/issues/36#issuecomment-15451411
 534 function! g:UltiSnips_Complete()
 535     call UltiSnips#ExpandSnippet()
 536     if g:ulti_expand_res == 0
 537         if pumvisible()
 538             return "\<C-n>"
 539         else
 540             call UltiSnips#JumpForwards()
 541             if g:ulti_jump_forwards_res == 0
 542                return "\<TAB>"
 543             endif
 544         endif
 545     endif
 546     return ""
 547 endfunction
 548 au InsertEnter * exec "inoremap <silent> " . g:UltiSnipsExpandTrigger . " <C-R>=g:UltiSnips_Complete()<cr>"
 549 let g:UltiSnipsListSnippets="<c-e>"
 550
 551 " unite {{{2
 552 call unite#filters#matcher_default#use(['matcher_fuzzy'])
 553 call unite#custom#profile('default', 'context', {
 554             \ 'winheight': 20,
 555             \ 'direction': 'botright'
 556             \ })
 557
 558 nnoremap [unite] <Nop>
 559 nmap <leader>u [unite]
 560
 561 " unite-grep {{{3
 562 " seems not respected
 563 let g:unite_source_grep_max_candidates = 2000
 564 if executable('ag')
 565     " Use ag in unite grep source.
 566     let g:unite_source_grep_command = 'ag'
 567     let g:unite_source_grep_default_opts = '--smart-case -w --vimgrep --hidden --ignore ''.hg'' --ignore ''.svn'' --ignore ''.git'' --ignore ''.bzr'''
 568     let g:unite_source_grep_recursive_opt = ''
 569 end
 570 nnoremap <silent> [unite]a :<C-u>Unite grep -input=\12\17<CR>
 571 command! -nargs=1 Ag Unite grep -input=<args>
 572
 573 " unite-file_rec {{{3
 574 if executable('ag')
 575     " Use ag in unite rec source
 576     let g:unite_source_rec_async_command = 'ag --follow --nocolor --nogroup --hidden -g ""'
 577 end
 578 nnoremap <silent> [unite]f :<C-u>Unite -start-insert file_rec/async<CR>
 579
 580 " unite-buffer {{{3
 581 call unite#custom#default_action('buffer', 'goto')
 582 nnoremap <silent> [unite]b :<C-u>Unite buffer<CR>
 583
 584 " unite-menu {{{3
 585 let g:unite_source_menu_menus = {}
 586 let g:unite_source_menu_menus.fugitive = { 'description' : 'fugitive menu'}
 587 let g:unite_source_menu_menus.fugitive.command_candidates = {
 588             \ 'Gstatus <Leader>gs' : 'Gstatus',
 589             \ 'Gcommit -v <Leader>gc' : 'Gcommit -v',
 590             \ 'Glog' : 'Glog',
 591             \}
 592
 593 nnoremap <silent> <leader>gg :<C-u>Unite menu:fugitive<CR>
 594
 595 let g:unite_source_history_yank_enable = 1
 596 nnoremap <silent> [unite]p :<C-u>Unite history/yank<CR>
 597
 598 " yankring {{{2
 599 nnoremap <silent> <leader>p :YRShow<cr>
 600 let g:yankring_history_dir = expand('$XDG_CACHE_HOME/vim')
 601 let g:yankring_replace_n_pkey = ''
 602 let g:yankring_replace_n_nkey = ''
 603
 604 " map Y to y$ for the yank ring
 605 function! YRRunAfterMaps()
 606     nnoremap Y   :<C-U>YRYankCount 'y$'<CR>
 607 endfunction
 608
 609 " youcompleteme {{{2
 610 let g:ycm_extra_conf_globlist = ['~/src/*','/mnt/data/src/*']
 611 let g:ycm_global_ycm_extra_conf = expand('$XDG_CONFIG_HOME/vim/ycm_extra_conf.py')
 612 let g:ycm_extra_conf_vim_data = ['getcwd()']
 613 let g:ycm_add_preview_to_completeopt = 1
 614 let g:ycm_autoclose_preview_window_after_insertion = 0
 615 "let g:ycm_extra_conf_vim_data = ['%:p']
 616 nnoremap <leader>jd :YcmCompleter GoTo<CR>
 617
 618 " vim-easy-align {{{2
 619 " start interactive EasyAlign in visual mode
 620 vmap <Enter> <Plug>(EasyAlign)
 621 nmap ga <Plug>(EasyAlign)
 622
 623 " vim-json {{{2
 624 let g:vim_json_syntax_conceal = 0
 625
 626 " vim-latex {{{2
 627 let g:tex_flavor='latex'
 628 let g:Tex_DefaultTargetFormat='pdf'
 629 let g:Tex_MultipleCompileFormats='pdf'
 630
 631 " vim-sneak {{{2
 632 let g:sneak#streak = 1
 633 let g:sneak#target_labels = "aoeuisnthdpylrcgfqjkxzmwvz" " dvorak
 634 let g:sneak#use_ic_scs = 1  " follow 'ignorecase' and 'smartcase'
 635
 636 " sneaky f and t
 637 nmap f <Plug>Sneak_f
 638 nmap F <Plug>Sneak_F
 639 xmap f <Plug>Sneak_f
 640 xmap F <Plug>Sneak_F
 641 omap f <Plug>Sneak_f
 642 omap F <Plug>Sneak_F
 643 nmap t <Plug>Sneak_t
 644 nmap T <Plug>Sneak_T
 645 xmap t <Plug>Sneak_t
 646 xmap T <Plug>Sneak_T
 647 omap t <Plug>Sneak_t
 648 omap T <Plug>Sneak_T
 649
 650 " functions {{{1
 651
 652 " Convenient command to see the difference between the current buffer and the
 653 " file it was loaded from, thus the changes you made.
 654 " Only define it when not defined already.
 655 if !exists(":DiffOrig")
 656   command DiffOrig vert new | set bt=nofile | r # | 0d_ | diffthis
 657                   \ | wincmd p | diffthis
 658 endif
 659
 660 " edit configs  {{{2
 661 function! EditConfig(what)
 662     let l:dir = split(&runtimepath,',')[0]
 663     if a:what == 'vimrc'
 664         let l:file = expand($MYVIMRC)
 665     elseif ! isdirectory(globpath(l:dir, a:what))
 666         echoe a:what." is not valid!"
 667     elseif empty(&filetype)
 668         echoe 'filetype is empty!'
 669     else
 670         let l:file = l:dir.'/'.a:what.'/'.&filetype.'.vim'
 671     endif
 672
 673     execute ':vsplit '.file
 674     execute ':lcd %:p:h'
 675 endf
 676 nmap <leader>ev :call EditConfig('vimrc')<CR>
 677 nmap <leader>ef :call EditConfig('ftplugin')<CR>
 678 nmap <leader>es :call EditConfig('syntax')<CR>
 679 nmap <leader>ei :call EditConfig('indent')<CR>
 680 nmap <leader>eu :UltiSnipsEdit<CR>:lcd %:p:h<CR>
 681
 682 " spell check {{{2
 683 " http://tex.stackexchange.com/a/52932
 684 let g:myLangList=["en_gb","en_us","de","fr"]
 685
 686 function! ToggleSpell()
 687   if !exists("b:myLang")
 688     let b:myLang=0
 689   endif
 690   execute "setlocal spell!"
 691   if (&spell)
 692     echo "setlocal spelllang=" g:myLangList[b:myLang]
 693   endif
 694 endfunction
 695
 696 function! SwitchSpell()
 697   if !exists("b:myLang")
 698     let b:myLang=0
 699   endif
 700   if (&spell)
 701     let b:myLang=b:myLang+1
 702     if b:myLang>=len(g:myLangList) | let b:myLang=0 | endif
 703   endif
 704   execute "setlocal spell spelllang=".get(g:myLangList, b:myLang)
 705   echo "setlocal spelllang=" g:myLangList[b:myLang]
 706 endfunction
 707
 708 nnoremap <silent> coS :call SwitchSpell()<CR>
 709 " fix spelling with first choice
 710 nnoremap <Leader>f 1z=
 711
 712 " gitdir or home {{{2
 713 " from derek wyatt:
 714 " http://git.io/v3GAV
 715 function! FindGitDirOrHome()
 716   let filedir = expand('%:p:h')
 717   if isdirectory(filedir)
 718     let cmd = 'bash -c "(cd ' . filedir . '; git rev-parse --show-toplevel 2>/dev/null)"'
 719     let gitdir = system(cmd)
 720     if strlen(gitdir) == 0
 721       return '~'
 722     else
 723       return gitdir[:-2]
 724     endif
 725   else
 726     return '~'
 727   endif
 728 endfunction
 729
 730 " vim:set et sw=2 ts=2 tw=78: