vim/vimrc

   1 " My vimrc.
   2 "
   3 " Author:   Samir Benmendil <samir.benmendil[at]gmail[dot]com>
   4 "
   5
   6 " plugins {{{1
   7 filetype off
   8 set runtimepath& " reset rtp
   9 " remove all autocommands
  10 autocmd!
  11
  12 set runtimepath+=$XDG_DATA_HOME/vim/vundle
  13 call vundle#begin('$XDG_DATA_HOME/vim')
  14
  15 Plugin 'gmarik/vundle'
  16
  17 Plugin 'AndrewRadev/switch.vim'
  18 Plugin 'airblade/vim-gitgutter'
  19 Plugin 'alepez/vim-gtest'
  20 Plugin 'bling/vim-airline'
  21 Plugin 'chrisbra/checkattach'
  22 Plugin 'derekwyatt/vim-fswitch'
  23 Plugin 'elzr/vim-json'
  24 Plugin 'firef0x/pkgbuild.vim'
  25 Plugin 'junegunn/vim-easy-align'
  26 Plugin 'justinmk/vim-sneak'
  27 Plugin 'klen/python-mode'
  28 Plugin 'kshenoy/vim-signature'
  29 Plugin 'majutsushi/tagbar'
  30 Plugin 'octol/vim-cpp-enhanced-highlight'
  31 Plugin 'raimondi/delimitmate'
  32 Plugin 'ram-z/vim-clang-format'
  33 Plugin 'ram-z/vimwiki'
  34 Plugin 'rdnetto/ycm-generator'
  35 Plugin 'scrooloose/syntastic'
  36 Plugin 'sgeb/vim-diff-fold'
  37 Plugin 'shougo/unite.vim'
  38 Plugin 'shougo/vimproc.vim'
  39 Plugin 'sjl/gundo.vim'
  40 Plugin 'tomtom/tcomment_vim'
  41 Plugin 'tpope/vim-abolish'
  42 Plugin 'tpope/vim-endwise'
  43 Plugin 'tpope/vim-eunuch'
  44 Plugin 'tpope/vim-fugitive'
  45 Plugin 'tpope/vim-repeat'
  46 Plugin 'tpope/vim-surround'  "investigate vim-sandwich
  47 Plugin 'tpope/vim-unimpaired'
  48 Plugin 'tweekmonster/spellrotate.vim'
  49 Plugin 'valloric/youcompleteme'
  50 Plugin 'vim-scripts/mediawiki.vim'
  51 Plugin 'vim-scripts/replacewithregister'
  52 Plugin 'vim-scripts/yankring.vim'
  53
  54 " colorschemes
  55 Plugin 'flazz/vim-colorschemes'
  56
  57 " snippets
  58 Plugin 'sirver/ultisnips'
  59 Plugin 'honza/vim-snippets'
  60
  61 " text objects
  62 Plugin 'kana/vim-textobj-user'
  63 Plugin 'julian/vim-textobj-variable-segment'
  64 Plugin 'sgur/vim-textobj-parameter'
  65 Plugin 'kana/vim-operator-user'
  66
  67 " staging
  68 " find an alternative (latex-box? Automatic Latex Plugin?)
  69 Plugin 'vim-latex/vim-latex'
  70 Plugin 'alx741/vinfo'
  71 Plugin 'derekwyatt/vim-protodef'
  72 " needs editing colorscheme
  73 " Plugin 'jeaye/color_coded'
  74 " Check LucHermites plugins: https://github.com/LucHermitte/lh-cpp
  75 Plugin 'wincent/loupe'
  76
  77 call vundle#end()
  78
  79 " remove entries first
  80 set runtimepath -=$HOME/.vim
  81 set runtimepath -=$HOME/.vim/after
  82 set runtimepath -=$XDG_CONFIG_HOME/vim
  83 set runtimepath -=$XDG_CONFIG_HOME/vim/after
  84 " then prepend and append them
  85 set runtimepath ^=$XDG_CONFIG_HOME/vim
  86 set runtimepath +=$XDG_CONFIG_HOME/vim/after
  87
  88 filetype plugin indent on
  89
  90 " colorscheme {{{1
  91 syntax on
  92 colorscheme badfox
  93
  94 " options {{{1
  95 " moving around, searching and patterns {{{2
  96 set incsearch           " show match for partly typed search command
  97 set ignorecase          " ignore case when using a search pattern
  98 set smartcase           " override 'ignorecase' when pattern has upper case characters
  99 set hlsearch            " highlight all matches for the last used search pattern
 100
 101 set nostartofline       " don't move the cursor to the first non-blank char of a line
 102 set path+=.
 103 set path+=include/
 104 set path+=../include/
 105 set path+=/usr/include/c++/*
 106
 107 " displaying text {{{2
 108 set nowrap                      " long lines wrap
 109 set linebreak                   " wrap long lines at a character in 'breakat'
 110 set showbreak=↪                 " show these chars for wrapped lines
 111 set breakindent                 " preserve indentation in wrapped text
 112
 113 set lazyredraw                  " don't redraw while executing macros
 114
 115 set list                        " show chars defined in 'listchars'
 116 set listchars=tab:❭\            " list of strings used for list mode
 117 set listchars+=extends:❯,precedes:❮
 118 " Only shown when not in insert mode
 119 au InsertLeave * :set listchars+=trail:·
 120 augroup trailing
 121     au!
 122     au InsertEnter * :set listchars-=trail:·
 123     au InsertLeave * :set listchars+=trail:·
 124 augroup END
 125
 126 set scrolloff=5                 " number of screen lines to show around the cursor
 127 set sidescroll=1                " number of collumns to scroll
 128 set sidescrolloff=1             " don't scroll over the listchars
 129
 130 set fillchars=diff:⣿,vert:│
 131
 132 set nonumber                    " show the line number for each line
 133 set norelativenumber            " show the relative line number for each line
 134
 135 " syntax, highlighting and spelling {{{2
 136 set synmaxcol=800               " don't highlight long lines
 137
 138 set dictionary=spell            " list of dictionary files for keyword completion
 139
 140 set colorcolumn=+1
 141
 142 " multiple windows {{{2
 143 set laststatus=2                " 0, 1 or 2; when to use a status line for the last window
 144
 145 set previewheight=20            " default height for the preview window
 146
 147 set hidden
 148
 149 " set splitbelow                  " a new window is put below of the current one
 150 set splitright                  " a new window is put right of the current one
 151
 152 " terminal {{{2
 153 set ttyfast
 154
 155 " using the mouse {{{2
 156 set mouse=rnv                   " list of flags for using the mouse
 157 set ttymouse=xterm              " type of mouse
 158
 159 " messages and info {{{2
 160 set showcmd         " Show (partial) command in status line.
 161 set ruler           " show the cursor position all the time
 162 set confirm         " Ask what to do when closing unsaved documents
 163 set shortmess=      " reset option
 164 set shortmess+=a    " all abbreviations
 165 set shortmess+=o    " overwrite file-written message
 166 set shortmess+=O    " file-read message overrides previous
 167 set shortmess+=t    " truncate file message at start
 168 set shortmess+=T    " truncate other messages in the middle
 169 set shortmess+=W    " don't give 'written' or '[w]' when writing a file
 170 set shortmess+=A    " ignore swapfile warning
 171 set shortmess+=I    " no splash screen
 172
 173 " editing text {{{2
 174 set backspace=indent,eol,start  " allow backspacing over everything in insert mode
 175
 176 set showmatch                   " Show matching brackets.
 177
 178 set nojoinspaces                " don't use two spaces after '.' when joining a line
 179 set formatoptions+=j    " Delete comment leader when joining lines
 180 set formatoptions+=c    " Autowrap comments using textwidth
 181 set formatoptions+=r    " Insert comment leader after hitting <Enter>
 182 set formatoptions+=n    " Recognize numbered lists
 183 set formatoptions+=q    " Allow formatting of comments with "gq".
 184 set formatoptions+=l    " do not wrap lines that have been longer when starting insert mode already
 185 set formatoptions+=t    " Auto-wrap text using textwidth
 186 set formatoptions-=o    " Do not insert comment leader after hitting o or O in normal mode
 187
 188 set nrformats=hex               " number formats recognized for CTRL-A and CTRL-X commands
 189
 190 set complete=.       " scan the current buffer ( 'wrapscan' is ignored)
 191 set complete+=w      " scan buffers from other windows
 192 set complete+=b      " scan other loaded buffers that are in the buffer list
 193 set complete+=u      " scan the unloaded buffers that are in the buffer list
 194 set complete+=t      " scan tags
 195 set complete+=i      " scan current and included files
 196 set complete+=kspell " use the currently active spell checking |spell|
 197
 198 " whether to use a popup menu for Insert mode completion
 199 set completeopt=longest,menuone,preview
 200
 201 " tabs and indent {{{2
 202 set shiftwidth=4                " number of spaces used for each step of (auto)indent
 203 set smarttab                    " a <Tab> in an indent inserts 'shiftwidth' spaces
 204 set softtabstop=4               " if non-zero, number of spaces to insert for a <Tab>
 205 set shiftround                  " round to 'shiftwidth' for "<<" and ">>"
 206 set expandtab                   " expand <Tab> to spaces in Insert mode
 207 set autoindent
 208
 209 set pastetoggle=<F11>           " key sequence to toggle paste mode
 210
 211 " folding {{{2
 212 set foldmethod=marker           " folding type
 213 set foldlevelstart=0            " value for 'foldlevel' when starting to edit a file
 214
 215 " open folds when jumping to line
 216 set foldopen+=jump
 217
 218 set viewoptions=cursor          " save cursor position
 219 set viewoptions+=folds          " save folds
 220
 221 " diff mode {{{2
 222 set diffopt+=filler         " show filler lines
 223 set diffopt+=vertical       " always vertical split
 224 set diffopt+=context:10     " 10 lines context between changes
 225
 226 " reading and writing files {{{2
 227 set modeline                    " read modelines
 228 set modelines=2                 " only check first/last 2 lines
 229
 230 set writebackup                 " write a backup file before overwriting a file
 231 set backup                      " keep a backup after owerwriting a file
 232 set backupdir=$XDG_CACHE_HOME/vim/backup//
 233
 234 set backupskip+=.netrc          " skip netrc
 235 set backupskip+=/dev/shm/pass*  " skip passwordstore files
 236
 237 set undofile                    " persistent undo history
 238 set undodir=$XDG_CACHE_HOME/vim/undo//
 239
 240 augroup undoskip
 241     au!
 242     au BufWritePre .netrc         setlocal noundofile
 243     au BufWritePre /dev/shm/pass* setlocal noundofile
 244     au BufWritePre /tmp/*         setlocal noundofile
 245 augroup END
 246
 247 set autowrite                   " automatically write a file when leaving a modified buffer
 248 set autoread                    " automatically read a file that has been modified
 249
 250 " the swap file {{{2
 251 set noswapfile
 252 set directory=$XDG_CACHE_HOME/vim/swap//
 253
 254 " command line editing {{{2
 255 set history=5000                " how many command lines are remembered
 256 set wildmenu                    " command-line completion shows a list of matches
 257 set wildmode=longest:full,full  " specifies how command line completion works
 258 set wildignorecase              " ignore case when completing file names
 259
 260 set wildignore+=.hg,.git,.svn                    " Version control
 261 set wildignore+=*.aux,*.out,*.toc                " LaTeX intermediate files
 262 set wildignore+=*.jpg,*.bmp,*.gif,*.png,*.jpeg   " binary images
 263 set wildignore+=*.o,*.obj,*.exe,*.dll,*.manifest " compiled object files
 264 set wildignore+=*.spl                            " compiled spelling word lists
 265 set wildignore+=*.sw?                            " Vim swap files
 266 set wildignore+=*.luac                           " Lua byte code
 267 set wildignore+=*.pyc                            " Python byte code
 268 set wildignore+=*.orig                           " Merge resolution files
 269
 270 " running make and jumping to errors {{{2
 271 set makeprg=make\ -w     " print changing directories
 272
 273 set grepprg=ag\ --vimgrep\ $*
 274
 275 " language specific {{{2
 276 set isfname-==    " don't treat `=` as being part of filenames
 277
 278 " various {{{2
 279 set virtualedit+=block     " let cursor move past last char in <C-V> mode
 280 set virtualedit+=onemore   " allow the cursor to move just past the end of the line
 281 set viminfo='100,<50,s10,h,n$XDG_CACHE_HOME/vim/viminfo " viminfo defaults but save file in .cache
 282
 283 set viewdir=$XDG_CACHE_HOME/vim/view//
 284
 285 set sessionoptions+=unix,slash  " damn windows and it's silly ways
 286
 287 " autocmds {{{1
 288 " Resize splits when the window is resized {{{2
 289 augroup resize
 290     au!
 291     autocmd VimResized * :wincmd =
 292 augroup END
 293
 294 " Only show cursorline in the current window and in normal mode {{{2
 295 augroup cline
 296     au!
 297     au WinLeave,InsertEnter * set nocursorline
 298     au WinEnter,InsertLeave * set cursorline
 299 augroup END
 300
 301 " Treat buffers from stdin (e.g.: echo foo | vim -) as scratch {{{2
 302 augroup ft_stdin
 303     au!
 304     au StdinReadPost * :set buftype=nofile
 305 augroup END
 306
 307 " Jump to last known cursor position {{{2
 308 augroup cursor_pos
 309     au!
 310     " blacklist certain filetype
 311     let blacklist = ['gitcommit']
 312     autocmd BufReadPost *
 313                 \ if index(blacklist, &ft) < 0 && line("'\"") > 1 && line("'\"") <= line("$") |
 314                 \   exe "normal! g`\"" |
 315                 \ endif
 316 augroup END
 317
 318 " Check for file modifications automatically {{{2
 319 " (current buffer only)
 320 " Use :NoAutoChecktime to disable it (uses b:autochecktime)
 321 fun! MyAutoCheckTime()
 322   " only check timestamp for normal files
 323   if &buftype != '' | return | endif
 324   if ! exists('b:autochecktime') || b:autochecktime
 325     checktime %
 326     let b:autochecktime = 1
 327   endif
 328 endfun
 329 augroup MyAutoChecktime
 330   au!
 331   au FocusGained,BufEnter,CursorHold,InsertEnter * call MyAutoCheckTime()
 332 augroup END
 333 command! NoAutoChecktime let b:autochecktime=0
 334 command! ToggleAutoChecktime let b:autochecktime=!get(b:, 'autochecktime', 0) | echom "b:autochecktime:" b:autochecktime
 335
 336 " bindings {{{1
 337
 338 " allow both <space> and \ to be <leader>
 339 map <space> <leader>
 340
 341 " make
 342 nnoremap <leader>r :make!<cr>
 343 nnoremap <leader><cr> :make!<cr>
 344
 345 " unhighlight search
 346 nnoremap <silent> <Leader>/ :silent nohl<CR>
 347
 348 " Tabs
 349 nnoremap <leader>[ :tabprev<cr>
 350 nnoremap <leader>] :tabnext<cr>
 351
 352 " paste from selection
 353 nnoremap <leader>p* :silent! set paste<CR>"*p:set nopaste<CR>
 354 " paste from clipboard
 355 nnoremap <leader>p+ :silent! set paste<CR>"+p:set nopaste<CR>
 356
 357 " strip trailing whitespace
 358 function! StripWhitespace(line1, line2, ...)  " {{{2
 359   let s_report = &report
 360   let &report=0
 361   let pattern = a:0 ? a:1 : '\s\+$'
 362   let oldview = winsaveview()
 363   exe 'keepjumps keeppatterns '.a:line1.','.a:line2.'substitute/'.pattern.'//e'
 364   if oldview != winsaveview()
 365     redraw
 366   endif
 367   call winrestview(oldview)
 368   let &report = s_report
 369 endfunction  " }}}2
 370 command! -range=% -nargs=0 -bar Untrail keepjumps call StripWhitespace(<line1>,<line2>)
 371 nnoremap <silent> <leader>ww :Untrail<CR>
 372
 373 " Source
 374 vnoremap <leader>S y:execute @@<cr>:echo 'Sourced selection.'<cr>
 375 nnoremap <leader>S ^vg_y:execute @@<cr>:echo 'Sourced line.'<cr>
 376
 377 " jump to last cursor position
 378 noremap ' `
 379
 380 " Select (charwise) the contents of the current line, excluding indentation.
 381 nnoremap vv ^vg_
 382
 383 " Unfuck my screen
 384 nnoremap U :syntax sync fromstart<cr>:AirlineRefresh<cr>:redraw!<cr>
 385
 386 " Ranger
 387 " nnoremap <leader>r :silent !ranger %:h<cr>:redraw!<cr>
 388 " nnoremap <leader>R :silent !ranger<cr>:redraw!<cr>
 389
 390 " Use sane regexes.
 391 nnoremap / /\v
 392 vnoremap / /\v
 393 cnoremap s/ s/\v
 394
 395 " display the number of matches for the last search
 396 nmap <Leader># :%s:<C-R>/::gn<CR>
 397
 398 " center cursor after search and open folds
 399 nnoremap n nzzzv
 400 nnoremap N Nzzzv
 401
 402 " same when jumping around
 403 nnoremap g; g;zzzv
 404 nnoremap g, g,zzzv
 405 nnoremap <c-o> <c-o>zzzv
 406 nnoremap <c-i> <c-i>zzzv
 407
 408 " Not using the default mappings of 'To line from top/bottom'
 409 noremap H ^
 410 noremap L $
 411 vnoremap H ^
 412 vnoremap L g_
 413
 414 " Heresy, emacs insert bindings
 415 inoremap <C-A> <Esc>I
 416 inoremap <C-E> <Esc>A
 417 cnoremap <C-A> <Home>
 418 cnoremap <C-E> <End>
 419
 420 " proper movement when lines are wrapped
 421 noremap <expr> j (v:count == 0 ? 'gj' : 'j')
 422 noremap <expr> k (v:count == 0 ? 'gk' : 'k')
 423
 424 " disable arrows
 425 noremap  <Up>    <NOP>
 426 noremap  <Down>  <NOP>
 427 noremap  <Left>  <NOP>
 428 noremap  <Right> <NOP>
 429 inoremap <Up>    <NOP>
 430 inoremap <Down>  <NOP>
 431 inoremap <Left>  <NOP>
 432 inoremap <Right> <NOP>
 433 cnoremap <Up>    <NOP>
 434 cnoremap <Down>  <NOP>
 435 cnoremap <Left>  <NOP>
 436 cnoremap <Right> <NOP>
 437 cnoremap <C-K>   <Up>
 438 cnoremap <C-J>   <Down>
 439 cnoremap <C-H>   <Left>
 440 cnoremap <C-L>   <Right>
 441
 442 " close all folds open fold in cursor
 443 nnoremap zx zMzxzt
 444
 445 map <F1> :ls<CR>:b<space>
 446
 447 " move between windows (skip previewwindow)
 448 nnoremap <silent> <C-L> <C-W>w:if &previewwindow \| wincmd w \| endif<CR>
 449 nnoremap <silent> <C-H> <C-W>W:if &previewwindow \| wincmd W \| endif<CR>
 450
 451 "xterm mouse with middleclick paste
 452 nnoremap <MiddleMouse> i<MiddleMouse>
 453 vnoremap <MiddleMouse> s<MiddleMouse>
 454
 455 " fix legacy vi inconsistency
 456 nnoremap Y y$
 457 " copy to clipboard
 458 xnoremap Y "+y
 459
 460 " allow repeat operator on visual
 461 vnoremap . :normal .<CR>
 462
 463 " add line without changing position or leaving mode
 464 noremap <silent> <Leader>o :set paste<CR>m`o<ESC>``:set nopaste<CR>
 465 noremap <silent> <Leader>O :set paste<CR>m`O<ESC>``:set nopaste<CR>
 466
 467 " Don't use Ex mode, use Q for formatting
 468 map Q gq
 469
 470 " break undo sequence before removing word
 471 inoremap <C-W> <C-G>u<C-W>
 472
 473 nnoremap coe :set <C-R>=&expandtab ? 'noexpandtab' : 'expandtab'<CR><CR>
 474 nnoremap [oe :set expandtab<CR>
 475 nnoremap ]oe :set noexpandtab<CR>
 476
 477 for idt in range(1,8)
 478   exe 'nnoremap co'.idt.' :setlocal tabstop='.idt.' shiftwidth='.idt.' softtabstop='.idt.'<CR>'
 479 endfor
 480
 481 " toggle auto format of text
 482 nnoremap coa :set <C-R>=&formatoptions =~ "a" ? 'formatoptions-=a' : 'formatoptions+=a'<CR><CR>
 483 nnoremap [oa :set formatoptions+=a<CR>
 484 nnoremap ]oa :set formatoptions-=a<CR>
 485
 486 " space will toggle current fold in normal mode
 487 nnoremap <leader><Space> za
 488 " create folds around visual selection
 489 vnoremap <leader><Space> zf
 490
 491 " save with sudo
 492 cabbrev w!! SudoWrite
 493
 494 " uppercase previous word
 495 inoremap <C-C> <Esc>gUiwgi
 496
 497 " http://git.io/v3ZeU
 498 nmap <silent> <leader>qq :echo "hi<" . synIDattr(synID(line("."),col("."),1),"name") . '> trans<' . synIDattr(synID(line("."),col("."),0),"name") . "> lo<" . synIDattr(synIDtrans(synID(line("."),col("."),1)),"name") . ">"<CR>
 499
 500 " plugins options {{{1
 501 " airline {{{2
 502 let g:airline#extensions#whitespace#enabled = 1
 503 let g:airline#extensions#tabline#enabled = 1
 504 let g:airline_powerline_fonts = 1
 505
 506 " checkattach {{{2
 507 let g:checkattach_filebrowser = 'ranger'
 508 let g:checkattach_once = 'y'
 509
 510 " delimitmate {{{2
 511 let delimitMate_expand_cr = 2
 512 let g:delimitMate_expand_space = 1
 513
 514 " fswitch {{{2
 515 nnoremap <silent> <Leader>ff :FSHere<CR>
 516 nnoremap <silent> <Leader>fl :FSRight<CR>
 517 nnoremap <silent> <Leader>fh :FSLeft<CR>
 518 nnoremap <silent> <Leader>fj :FSBelow<CR>
 519 nnoremap <silent> <Leader>fk :FSAbove<CR>
 520 nnoremap <silent> <Leader>fL :FSSplitRight<CR>
 521 nnoremap <silent> <Leader>fH :FSSplitLeft<CR>
 522 nnoremap <silent> <Leader>fJ :FSSplitBelow<CR>
 523 nnoremap <silent> <Leader>fK :FSSplitAbove<CR>
 524
 525 " fugitive {{{2
 526 nmap <silent> <leader>dd :tab split \| Gdiff \| wincmd h<CR>
 527 " delete fugitive buffers when closed
 528 autocmd BufReadPost fugitive://* set bufhidden=delete
 529
 530 nnoremap <silent> <leader>gs :Gstatus<CR>
 531 nnoremap <silent> <leader>gd :Gdiff<CR>
 532 nnoremap <silent> <leader>gc :Gcommit -v<CR>
 533 nnoremap <silent> <leader>ga :Gwrite<cr>
 534 nnoremap <silent> <leader>gb :Gblame<cr>
 535
 536 " Gundo {{{2
 537 nnoremap <F7> :GundoToggle<CR>
 538
 539 " indent-guides {{{2
 540 let g:indent_guides_default_mapping = 0
 541 let g:indent_guides_guide_size = 1
 542 nmap <silent> cog <Plug>IndentGuidesToggle
 543 nmap <silent> [og <Plug>IndentGuidesEnable
 544 nmap <silent> ]og <Plug>IndentGuidesDisable
 545
 546 " close-another-window {{{2
 547 nnoremap <silent> <C-W>c  <NOP>
 548 nnoremap <silent> <C-W>cc <C-W>c
 549 nnoremap <silent> <C-W>ch :CloseLeftWindow<CR>
 550 nnoremap <silent> <C-W>cl :CloseRightWindow<CR>
 551 nnoremap <silent> <C-W>cj :CloseBelowWindow<CR>
 552 nnoremap <silent> <C-W>ck :CloseAboveWindow<CR>
 553
 554 " python-mode {{{2
 555
 556 let g:pymode_rope_completion = 0
 557 let g:pymode_rope = 0
 558 let g:pymode_run = 0
 559 let g:pymode_folding = 1
 560 let g:pymode_lint_ignore = "E221,E266,E501"
 561 let g:pymode_lint_cwindow = 0           " don't open cwindow when linting
 562 let g:pymode_syntax_space_errors = 0    " don't bother me when I'm typing
 563
 564 " signature {{{2
 565 " disable '[ mappings
 566
 567 let g:SignatureMap = {
 568   \ 'GotoNextLineAlpha'  :  "",
 569   \ 'GotoPrevLineAlpha'  :  "",
 570   \ 'GotoNextSpotAlpha'  :  "",
 571   \ 'GotoPrevSpotAlpha'  :  "",
 572   \ }
 573
 574 " switch
 575 let g:switch_mapping = "<Leader>s"
 576
 577 " spellrotate
 578 nmap <silent> z] <Plug>(SpellRotateForward)
 579 nmap <silent> z[ <Plug>(SpellRotateBackward)
 580 vmap <silent> z] <Plug>(SpellRotateForwardV)
 581 vmap <silent> z[ <Plug>(SpellRotateBackwardV)
 582
 583 " synastic {{{2
 584 let g:syntastic_enable_highlighting = 0
 585 let g:syntastic_error_symbol='E'
 586 let g:syntastic_style_error_symbol='S'
 587 let g:syntastic_warning_symbol='W'
 588 let g:syntastic_style_warning_symbol='S'
 589 let g:syntastic_always_populate_loc_list=1
 590 nmap <silent> <leader>y :SyntasticCheck<cr>
 591
 592 if ! &diff
 593   let g:syntastic_check_on_open=1
 594 endif
 595
 596 " tagbar {{{2
 597 map <F5> :TagbarToggle<cr>
 598 let g:tagbar_sort = 0
 599 let g:tagbar_compact = 1
 600 let g:tagbar_autoshowtag = 1
 601 let g:tagbar_width = 25
 602 let g:tagbar_iconchars = ['+', '-']
 603
 604 " tcomments {{{2
 605 let g:tcommentTextObjectInlineComment = 'gic'
 606
 607 " ultisnips {{{2
 608 let g:UltiSnipsEditSplit = 'vertical'
 609 let g:UltiSnipsSnippetsDir = expand("$XDG_CONFIG_HOME/vim/ultisnips")
 610 if has('fname_case')
 611   let g:UltiSnipsSnippetDirectories = ["UltiSnips", "ultisnips"]
 612 endif
 613 let g:UltiSnipsExpandTrigger       = "<tab>"
 614 let g:UltiSnipsJumpForwardTrigger  = "<tab>"
 615 let g:UltiSnipsJumpBackwardTrigger = "<s-tab>"
 616
 617 " UltiSnips completion function that tries to expand a snippet. If there's no
 618 " snippet for expanding, it checks for completion window and if it's shown,
 619 " selects first element. If there's no completion window it tries to jump to
 620 " next placeholder. If there's no placeholder it just returns TAB key
 621 " https://github.com/Valloric/YouCompleteMe/issues/36#issuecomment-15451411
 622 function! g:UltiSnips_Complete()
 623     call UltiSnips#ExpandSnippet()
 624     if g:ulti_expand_res == 0
 625         if pumvisible()
 626             return "\<C-n>"
 627         else
 628             call UltiSnips#JumpForwards()
 629             if g:ulti_jump_forwards_res == 0
 630                return "\<TAB>"
 631             endif
 632         endif
 633     endif
 634     return ""
 635 endfunction
 636 au InsertEnter * exec "inoremap <silent> " . g:UltiSnipsExpandTrigger . " <C-R>=g:UltiSnips_Complete()<cr>"
 637 let g:UltiSnipsListSnippets="<c-e>"
 638
 639 " unite {{{2
 640 call unite#filters#matcher_default#use(['matcher_fuzzy'])
 641 call unite#custom#profile('default', 'context', {
 642             \ 'winheight': 20,
 643             \ 'direction': 'botright'
 644             \ })
 645
 646 nnoremap [unite] <Nop>
 647 nmap <leader>u [unite]
 648 nnoremap [unite]u :UniteResume<CR>
 649
 650 " unite-grep {{{3
 651 " seems not respected
 652 let g:unite_source_grep_max_candidates = 2000
 653 if executable('ag')
 654     " Use ag in unite grep source.
 655     let g:unite_source_grep_command = 'ag'
 656     let g:unite_source_grep_default_opts = '--smart-case --vimgrep --ignore ''.hg'' --ignore ''.svn'' --ignore ''.git'' --ignore ''.bzr'''
 657     let g:unite_source_grep_recursive_opt = ''
 658 end
 659 nnoremap <silent> [unite]a :<C-u>Unite grep:.::\12\17<CR>
 660 nnoremap <silent> [unite]A :<C-u>Unite grep:.:-w:\12\17<CR>
 661 command! -nargs=1 Ag Unite grep:.::<args>
 662
 663 " unite-file_rec {{{3
 664 if executable('ag')
 665     " Use ag in unite rec source
 666     let g:unite_source_rec_async_command = ['ag', '--follow', '--nocolor', '--nogroup', '-g', '']
 667 end
 668 nnoremap <silent> [unite]f :<C-u>Unite -start-insert file_rec/async<CR>
 669 call unite#custom#source('file_rec/async', 'sorters', 'sorter_selecta')
 670
 671 " unite-buffer {{{3
 672 call unite#custom#default_action('buffer', 'open')
 673 nnoremap <silent> [unite]b :<C-u>Unite buffer:-<CR>
 674
 675 " unite-menu {{{3
 676 let g:unite_source_menu_menus = {}
 677 let g:unite_source_menu_menus.fugitive = { 'description' : 'fugitive menu'}
 678 let g:unite_source_menu_menus.fugitive.command_candidates = {
 679             \ 'Gstatus <Leader>gs' : 'Gstatus',
 680             \ 'Gcommit -v <Leader>gc' : 'Gcommit -v',
 681             \ 'Glog' : 'Glog',
 682             \}
 683
 684 nnoremap <silent> <leader>gg :<C-u>Unite menu:fugitive<CR>
 685
 686 let g:unite_source_history_yank_enable = 1
 687 nnoremap <silent> [unite]p :<C-u>Unite history/yank<CR>
 688
 689 " yankring {{{2
 690 nnoremap <silent> <leader>p :YRShow<cr>
 691 let g:yankring_history_dir = expand('$XDG_CACHE_HOME/vim')
 692 let g:yankring_replace_n_pkey = ''
 693 let g:yankring_replace_n_nkey = ''
 694
 695 " map Y to y$ for the yank ring
 696 function! YRRunAfterMaps()
 697     nnoremap Y   :<C-U>YRYankCount 'y$'<CR>
 698 endfunction
 699
 700 " youcompleteme {{{2
 701 let g:ycm_extra_conf_globlist = ['~/src/*','/mnt/data/src/*']
 702 let g:ycm_global_ycm_extra_conf = expand('$XDG_CONFIG_HOME/vim/ycm_extra_conf.py')
 703 let g:ycm_extra_conf_vim_data = ['getcwd()']
 704 let g:ycm_add_preview_to_completeopt = 1
 705 let g:ycm_complete_in_comments = 1
 706 let g:ycm_complete_in_strings  = 1
 707 let g:ycm_autoclose_preview_window_after_insertion = 0
 708
 709 " vim-easy-align {{{2
 710 " start interactive EasyAlign in visual mode
 711 vmap <Enter> <Plug>(EasyAlign)
 712 nmap ga <Plug>(EasyAlign)
 713
 714 " vim-gtest {{{2
 715 let g:gtest#highlight_failing_tests = 0
 716
 717 nnoremap <Leader>tt :GTestRun<CR>
 718 nnoremap <Leader>tu :GTestRunUnderCursor<CR>
 719
 720 " vim-json {{{2
 721 let g:vim_json_syntax_conceal = 0
 722
 723 " vim-latex {{{2
 724 let g:tex_flavor='latex'
 725 let g:Tex_DefaultTargetFormat='pdf'
 726 let g:Tex_MultipleCompileFormats='pdf'
 727
 728 " vim-sneak {{{2
 729 let g:sneak#streak = 1
 730 let g:sneak#target_labels = "aoeuisnthdpylrcgfqjkxzmwvz" " dvorak
 731 let g:sneak#use_ic_scs = 1  " follow 'ignorecase' and 'smartcase'
 732
 733 " sneaky f and t
 734 nmap f <Plug>Sneak_f
 735 nmap F <Plug>Sneak_F
 736 xmap f <Plug>Sneak_f
 737 xmap F <Plug>Sneak_F
 738 omap f <Plug>Sneak_f
 739 omap F <Plug>Sneak_F
 740 nmap t <Plug>Sneak_t
 741 nmap T <Plug>Sneak_T
 742 xmap t <Plug>Sneak_t
 743 xmap T <Plug>Sneak_T
 744 omap t <Plug>Sneak_t
 745 omap T <Plug>Sneak_T
 746
 747 " vimviki {{{2
 748 let g:vimwiki_list = [{'path': '$XDG_DATA_HOME/vimwiki'}]
 749 let g:vimwiki_auto_chdir = 1
 750 augroup myvimwiki
 751   au! BufRead            $XDG_DATA_HOME/vimwiki/index.wiki   !git -C "%:p:h" pull -q
 752   au! BufRead,BufNewFile $XDG_DATA_HOME/vimwiki/diary/*.wiki !git -C "%:p:h" pull -q
 753   au! BufWritePost       $XDG_DATA_HOME/vimwiki/*.wiki       exe '!git add "<afile>";git commit -qm"' . strftime("%FT%R") . '";git push -q'
 754 augroup END
 755
 756 " functions {{{1
 757
 758 " Convenient command to see the difference between the current buffer and the
 759 " file it was loaded from, thus the changes you made.
 760 " Only define it when not defined already.
 761 if !exists(":DiffOrig")
 762   command DiffOrig vert new | set bt=nofile | r # | 0d_ | diffthis
 763                   \ | wincmd p | diffthis
 764 endif
 765
 766 " sort operator {{{2
 767 function! SortLinesOpFunc(...)
 768   '[,']sort
 769 endfunction
 770 nnoremap <silent> gs :<C-U>set operatorfunc=SortLinesOpFunc<CR>g@
 771 vnoremap <silent> gs :sort<cr>
 772
 773 " edit configs  {{{2
 774 function! EditConfig(what)
 775     let l:dir = split(&runtimepath,',')[0]
 776     if a:what == 'vimrc'
 777         let l:file = expand($MYVIMRC)
 778     elseif ! isdirectory(globpath(l:dir, a:what))
 779         echoe a:what." is not valid!"
 780     elseif empty(&filetype)
 781         echoe 'filetype is empty!'
 782     else
 783         let l:file = l:dir.'/'.a:what.'/'.&filetype.'.vim'
 784     endif
 785
 786     execute ':vsplit '.file
 787     execute ':lcd %:p:h'
 788 endf
 789 nmap <leader>ev :call EditConfig('vimrc')<CR>
 790 nmap <leader>ef :call EditConfig('ftplugin')<CR>
 791 nmap <leader>es :call EditConfig('syntax')<CR>
 792 nmap <leader>ei :call EditConfig('indent')<CR>
 793 nmap <leader>eu :UltiSnipsEdit<CR>:lcd %:p:h<CR>
 794
 795 " spell check {{{2
 796 " http://tex.stackexchange.com/a/52932
 797 let g:myLangList=["en_gb","en_us","de","fr"]
 798
 799 function! ToggleSpell()
 800   if !exists("b:myLang")
 801     let b:myLang=0
 802   endif
 803   execute "setlocal spell!"
 804   if (&spell)
 805     echo "setlocal spelllang=" g:myLangList[b:myLang]
 806   endif
 807 endfunction
 808
 809 function! SwitchSpell()
 810   if !exists("b:myLang")
 811     let b:myLang=0
 812   endif
 813   if (&spell)
 814     let b:myLang=b:myLang+1
 815     if b:myLang>=len(g:myLangList) | let b:myLang=0 | endif
 816   endif
 817   execute "setlocal spell spelllang=".get(g:myLangList, b:myLang)
 818   echo "setlocal spelllang=" g:myLangList[b:myLang]
 819 endfunction
 820
 821 nnoremap <silent> coS :call SwitchSpell()<CR>
 822 " fix spelling with first choice
 823 nnoremap <Leader>f 1z=
 824
 825 " gitdir or home {{{2
 826 " from derek wyatt:
 827 " http://git.io/v3GAV
 828 function! FindGitDirOrHome()
 829   let filedir = expand('%:p:h')
 830   if isdirectory(filedir)
 831     let cmd = 'bash -c "(cd ' . filedir . '; git rev-parse --show-toplevel 2>/dev/null)"'
 832     let gitdir = system(cmd)
 833     if strlen(gitdir) == 0
 834       return '~'
 835     else
 836       return gitdir[:-2]
 837     endif
 838   else
 839     return '~'
 840   endif
 841 endfunction
 842 command! Cd cd %:h
 843 command! Cdr execute('cd ' . FindGitDirOrHome())
 844 command! LCd lcd %:h
 845 command! LCdr execute('lcd ' . FindGitDirOrHome())
 846
 847 " vim:set et sw=2 ts=2 tw=78: