vim/vimrc

   1 " My vimrc.
   2 "
   3 " Author:   Samir Benmendil <samir.benmendil[at]gmail[dot]com>
   4 "
   5
   6 " runtimepath {{{1
   7 set runtimepath ^=$XDG_CONFIG_HOME/vim
   8 set runtimepath +=$XDG_CONFIG_HOME/vim/after
   9
  10 " plugins {{{1
  11 " remove all autocommands
  12 autocmd!
  13
  14 call plug#begin('$XDG_DATA_HOME/vim')
  15 " This does not update vim-plug, use PlugUpgrade instead
  16 Plug 'junegunn/vim-plug'
  17
  18 Plug 'airblade/vim-gitgutter'
  19 Plug 'alepez/vim-gtest'
  20 Plug 'andrewradev/switch.vim'
  21 Plug 'bling/vim-airline'
  22 Plug 'chrisbra/checkattach'
  23 Plug 'derekwyatt/vim-fswitch'
  24 Plug 'elzr/vim-json'
  25 Plug 'firef0x/pkgbuild.vim'
  26 Plug 'junegunn/vim-easy-align'
  27 Plug 'justinmk/vim-sneak'
  28 Plug 'klen/python-mode'
  29 Plug 'kshenoy/vim-signature'
  30 Plug 'majutsushi/tagbar'
  31 Plug 'octol/vim-cpp-enhanced-highlight'
  32 Plug 'raimondi/delimitmate'
  33 Plug 'ram-z/vim-clang-format', { 'branch': 'fix-undo' }
  34 " fix some issue with vim-clang-format not finding .clang-format
  35 let g:clang_format#detect_style_file = 1
  36 Plug 'vimwiki/vimwiki', { 'branch': 'dev' }
  37 " Plug 'scrooloose/syntastic'
  38 Plug 'sgeb/vim-diff-fold'
  39 Plug 'shougo/unite.vim'
  40 Plug 'shougo/vimproc.vim', {'do': 'make'}
  41 Plug 'sjl/gundo.vim'
  42 Plug 'thinca/vim-qfreplace'
  43 Plug 'tomtom/tcomment_vim'
  44 Plug 'tpope/vim-abolish'
  45 Plug 'tpope/vim-endwise'
  46 Plug 'tpope/vim-eunuch'
  47 Plug 'tpope/vim-fugitive'
  48 Plug 'tpope/vim-repeat'
  49 Plug 'tpope/vim-speeddating'
  50 Plug 'tpope/vim-surround'  "investigate vim-sandwich
  51 Plug 'tpope/vim-unimpaired'
  52 Plug 'tweekmonster/spellrotate.vim'
  53 Plug 'valloric/youcompleteme', { 'do': './install.py --clangd-completer --clang-completer' }
  54 Plug 'vim-scripts/mediawiki.vim'
  55 Plug 'vim-scripts/replacewithregister'
  56 Plug 'vim-scripts/yankring.vim'
  57 Plug 'wincent/loupe'
  58
  59 " colorschemes
  60 Plug 'morhetz/gruvbox'
  61
  62 " snippets
  63 Plug 'sirver/ultisnips'
  64 Plug 'honza/vim-snippets'
  65
  66 " text objects
  67 Plug 'kana/vim-textobj-user'
  68 Plug 'julian/vim-textobj-variable-segment'
  69 Plug 'sgur/vim-textobj-parameter'
  70 Plug 'kana/vim-operator-user'
  71
  72 " staging
  73 " Check LucHermites plugins: https://github.com/LucHermitte/lh-cpp
  74 Plug 'dense-analysis/ale' " {{{2
  75 let g:ale_echo_msg_format = '[%linter%] %code: %%s'
  76 let g:ale_c_parse_compile_commands = 1
  77 let g:ale_cpp_parse_compile_commands = 1
  78 " don't use loclist as it's being populated by ycm
  79 " (might want to enable for other filetypes)
  80 let g:ale_set_loclist = 0
  81 let g:ale_linters_ignore = { 'cpp': ['clangd', 'clangtidy', 'clang'] }
  82
  83 Plug 'git@github.com:/ram-z/vim-orgmode', { 'branch': 'dev' } " {{{2
  84 Plug 'vim-scripts/syntaxrange'
  85
  86 let g:org_agenda_files = ['~/org/*.org']
  87
  88 call plug#end()
  89
  90 filetype plugin indent on
  91
  92 " colorscheme {{{1
  93 syntax on
  94 set background=dark
  95 let g:gruvbox_contrast_dark  = 'hard'
  96 let g:gruvbox_contrast_light = 'soft'
  97 colorscheme gruvbox
  98 " override the background to be black
  99 highligh Normal ctermbg=None
 100
 101 " options {{{1
 102 " moving around, searching and patterns {{{2
 103 set incsearch           " show match for partly typed search command
 104 set ignorecase          " ignore case when using a search pattern
 105 set smartcase           " override 'ignorecase' when pattern has upper case characters
 106 set hlsearch            " highlight all matches for the last used search pattern
 107
 108 set nostartofline       " don't move the cursor to the first non-blank char of a line
 109 set path+=.
 110 set path+=include/
 111 set path+=../include/
 112 set path+=/usr/include/c++/*
 113
 114 " displaying text {{{2
 115 set nowrap                      " long lines wrap
 116 set linebreak                   " wrap long lines at a character in 'breakat'
 117 set showbreak=↪                 " show these chars for wrapped lines
 118 set breakindent                 " preserve indentation in wrapped text
 119
 120 set lazyredraw                  " don't redraw while executing macros
 121
 122 set list                        " show chars defined in 'listchars'
 123 set listchars=tab:❭\            " list of strings used for list mode
 124 set listchars+=extends:❯,precedes:❮
 125 " Only shown when not in insert mode
 126 set listchars+=trail:·
 127 augroup trailing
 128     au!
 129     au InsertEnter * :set listchars-=trail:·
 130     au InsertLeave * :set listchars+=trail:·
 131 augroup END
 132
 133 set scrolloff=5                 " number of screen lines to show around the cursor
 134 set sidescroll=1                " number of collumns to scroll
 135 set sidescrolloff=1             " don't scroll over the listchars
 136
 137 set fillchars=diff:⣿,vert:│
 138
 139 set nonumber                    " show the line number for each line
 140 set norelativenumber            " show the relative line number for each line
 141
 142 " syntax, highlighting and spelling {{{2
 143 set synmaxcol=800               " don't highlight long lines
 144
 145 set dictionary=spell            " list of dictionary files for keyword completion
 146
 147 set colorcolumn=+1
 148
 149 " multiple windows {{{2
 150 set laststatus=2                " 0, 1 or 2; when to use a status line for the last window
 151
 152 set previewheight=20            " default height for the preview window
 153
 154 set hidden
 155
 156 " set splitbelow                  " a new window is put below of the current one
 157 set splitright                  " a new window is put right of the current one
 158
 159 " terminal {{{2
 160 set ttyfast
 161
 162 " using the mouse {{{2
 163 set mouse=rnv                   " list of flags for using the mouse
 164 set ttymouse=xterm              " type of mouse
 165
 166 " messages and info {{{2
 167 set showcmd         " Show (partial) command in status line.
 168 set ruler           " show the cursor position all the time
 169 set confirm         " Ask what to do when closing unsaved documents
 170 set shortmess=      " reset option
 171 set shortmess+=a    " all abbreviations
 172 set shortmess+=o    " overwrite file-written message
 173 set shortmess+=O    " file-read message overrides previous
 174 set shortmess+=t    " truncate file message at start
 175 set shortmess+=T    " truncate other messages in the middle
 176 set shortmess+=W    " don't give 'written' or '[w]' when writing a file
 177 set shortmess+=A    " ignore swapfile warning
 178 set shortmess+=I    " no splash screen
 179
 180 " editing text {{{2
 181 set backspace=indent,eol,start  " allow backspacing over everything in insert mode
 182
 183 set showmatch                   " Show matching brackets.
 184
 185 set nojoinspaces                " don't use two spaces after '.' when joining a line
 186 set formatoptions+=j    " Delete comment leader when joining lines
 187 set formatoptions+=c    " Autowrap comments using textwidth
 188 set formatoptions+=r    " Insert comment leader after hitting <Enter>
 189 set formatoptions+=n    " Recognize numbered lists
 190 set formatoptions+=q    " Allow formatting of comments with "gq".
 191 set formatoptions+=l    " do not wrap lines that have been longer when starting insert mode already
 192 set formatoptions+=t    " Auto-wrap text using textwidth
 193 set formatoptions-=o    " Do not insert comment leader after hitting o or O in normal mode
 194
 195 set nrformats=hex               " number formats recognized for CTRL-A and CTRL-X commands
 196
 197 set complete=.       " scan the current buffer ( 'wrapscan' is ignored)
 198 set complete+=w      " scan buffers from other windows
 199 set complete+=b      " scan other loaded buffers that are in the buffer list
 200 set complete+=u      " scan the unloaded buffers that are in the buffer list
 201 set complete+=t      " scan tags
 202 set complete+=i      " scan current and included files
 203 set complete+=kspell " use the currently active spell checking |spell|
 204
 205 " whether to use a popup menu for Insert mode completion
 206 set completeopt=longest,menuone,preview
 207
 208 " tabs and indent {{{2
 209 set shiftwidth=4                " number of spaces used for each step of (auto)indent
 210 set smarttab                    " a <Tab> in an indent inserts 'shiftwidth' spaces
 211 set softtabstop=4               " if non-zero, number of spaces to insert for a <Tab>
 212 set shiftround                  " round to 'shiftwidth' for "<<" and ">>"
 213 set expandtab                   " expand <Tab> to spaces in Insert mode
 214 set autoindent
 215
 216 set pastetoggle=<F11>           " key sequence to toggle paste mode
 217
 218 " folding {{{2
 219 set foldmethod=marker           " folding type
 220 set foldlevelstart=0            " value for 'foldlevel' when starting to edit a file
 221
 222 " open folds when jumping to line
 223 set foldopen+=jump
 224
 225 set viewoptions=cursor          " save cursor position
 226 set viewoptions+=folds          " save folds
 227
 228 " diff mode {{{2
 229 set diffopt+=filler         " show filler lines
 230 set diffopt+=vertical       " always vertical split
 231 set diffopt+=context:10     " 10 lines context between changes
 232
 233 " reading and writing files {{{2
 234 set modeline                    " read modelines
 235 set modelines=2                 " only check first/last 2 lines
 236
 237 set writebackup                 " write a backup file before overwriting a file
 238 set backup                      " keep a backup after owerwriting a file
 239 set backupdir=$XDG_CACHE_HOME/vim/backup//
 240
 241 set backupskip+=.netrc          " skip netrc
 242 set backupskip+=/dev/shm/pass*  " skip passwordstore files
 243
 244 set undofile                    " persistent undo history
 245 set undodir=$XDG_CACHE_HOME/vim/undo//
 246
 247 augroup undoskip
 248     au!
 249     au BufWritePre .netrc         setlocal noundofile
 250     au BufWritePre /dev/shm/pass* setlocal noundofile
 251     au BufWritePre /tmp/*         setlocal noundofile
 252 augroup END
 253
 254 set autowrite                   " automatically write a file when leaving a modified buffer
 255 set autoread                    " automatically read a file that has been modified
 256
 257 " the swap file {{{2
 258 set noswapfile
 259 set directory=$XDG_CACHE_HOME/vim/swap//
 260
 261 " command line editing {{{2
 262 set history=5000                " how many command lines are remembered
 263 set wildmenu                    " command-line completion shows a list of matches
 264 set wildmode=longest:full,full  " specifies how command line completion works
 265 set wildignorecase              " ignore case when completing file names
 266
 267 set wildignore+=.hg,.git,.svn                    " Version control
 268 set wildignore+=*.aux,*.out,*.toc                " LaTeX intermediate files
 269 set wildignore+=*.jpg,*.bmp,*.gif,*.png,*.jpeg   " binary images
 270 set wildignore+=*.o,*.obj,*.exe,*.dll,*.manifest " compiled object files
 271 set wildignore+=*.spl                            " compiled spelling word lists
 272 set wildignore+=*.sw?                            " Vim swap files
 273 set wildignore+=*.luac                           " Lua byte code
 274 set wildignore+=*.pyc                            " Python byte code
 275 set wildignore+=*.orig                           " Merge resolution files
 276
 277 " running make and jumping to errors {{{2
 278 set makeprg=make\ -w     " print changing directories
 279
 280 set grepprg=ag\ --vimgrep\ $*
 281
 282 " language specific {{{2
 283 set isfname-==    " don't treat `=` as being part of filenames
 284
 285 " various {{{2
 286 set virtualedit+=block     " let cursor move past last char in <C-V> mode
 287 set virtualedit+=onemore   " allow the cursor to move just past the end of the line
 288 set viminfo='100,<50,s10,h,n$XDG_CACHE_HOME/vim/viminfo " viminfo defaults but save file in .cache
 289
 290 set viewdir=$XDG_CACHE_HOME/vim/view//
 291
 292 set sessionoptions+=unix,slash  " damn windows and it's silly ways
 293
 294 " autocmds {{{1
 295 " Resize splits when the window is resized {{{2
 296 augroup resize
 297     au!
 298     autocmd VimResized * :wincmd =
 299 augroup END
 300
 301 " Only show cursorline in the current window and in normal mode {{{2
 302 augroup cline
 303     au!
 304     au WinLeave,InsertEnter * set nocursorline
 305     au WinEnter,InsertLeave * set cursorline
 306 augroup END
 307
 308 " Treat buffers from stdin (e.g.: echo foo | vim -) as scratch {{{2
 309 augroup ft_stdin
 310     au!
 311     au StdinReadPost * :set buftype=nofile
 312 augroup END
 313
 314 " Jump to last known cursor position {{{2
 315 augroup cursor_pos
 316     au!
 317     " blacklist certain filetype
 318     let blacklist = ['gitcommit']
 319     autocmd BufReadPost *
 320                 \ if index(blacklist, &ft) < 0 && line("'\"") > 1 && line("'\"") <= line("$") |
 321                 \   exe "normal! g`\"" |
 322                 \ endif
 323 augroup END
 324
 325 " Check for file modifications automatically {{{2
 326 " (current buffer only)
 327 " Use :NoAutoChecktime to disable it (uses b:autochecktime)
 328 fun! MyAutoCheckTime()
 329   " only check timestamp for normal files
 330   if &buftype != '' | return | endif
 331   if ! exists('b:autochecktime') || b:autochecktime
 332     checktime %
 333     let b:autochecktime = 1
 334   endif
 335 endfun
 336 augroup MyAutoChecktime
 337   au!
 338   au FocusGained,BufEnter,CursorHold,InsertEnter * call MyAutoCheckTime()
 339 augroup END
 340 command! NoAutoChecktime let b:autochecktime=0
 341 command! ToggleAutoChecktime let b:autochecktime=!get(b:, 'autochecktime', 0) | echom "b:autochecktime:" b:autochecktime
 342
 343 augroup terminal
 344   au!
 345   au TerminalOpen * if &buftype == 'terminal' | setlocal bufhidden=hide | endif
 346 augroup END
 347
 348 " bindings {{{1
 349
 350 " allow both <space> and \ to be <leader>
 351 map <space> <leader>
 352
 353 " make
 354 function! Make()
 355   let l:make_dir = ""
 356   if exists("b:make_dir")
 357     let l:make_dir = "-C ".b:make_dir
 358   elseif exists("g:make_dir")
 359     let l:make_dir = "-C ".g:make_dir
 360   endif
 361
 362   let l:make_targets = ""
 363   if exists("g:make_targets")
 364     let l:make_targets = g:make_targets
 365   endif
 366   execute "make! ".l:make_dir." ".l:make_targets
 367 endf
 368 nnoremap <leader>r :call Make()<cr>
 369
 370 " unhighlight search
 371 nnoremap <silent> <Leader>/ :silent nohl<CR>
 372
 373 " Tabs
 374 nnoremap <leader>[ :tabprev<cr>
 375 nnoremap <leader>] :tabnext<cr>
 376
 377 " paste from selection
 378 nnoremap <leader>p* :silent! set paste<CR>"*p:set nopaste<CR>
 379 " paste from clipboard
 380 nnoremap <leader>p+ :silent! set paste<CR>"+p:set nopaste<CR>
 381
 382 " strip trailing whitespace
 383 function! StripWhitespace(line1, line2, ...)  " {{{2
 384   let s_report = &report
 385   let &report=0
 386   let pattern = a:0 ? a:1 : '\s\+$'
 387   let oldview = winsaveview()
 388   exe 'keepjumps keeppatterns '.a:line1.','.a:line2.'substitute/'.pattern.'//e'
 389   if oldview != winsaveview()
 390     redraw
 391   endif
 392   call winrestview(oldview)
 393   let &report = s_report
 394 endfunction  " }}}2
 395 command! -range=% -nargs=0 -bar Untrail keepjumps call StripWhitespace(<line1>,<line2>)
 396 nnoremap <silent> <leader>ww :Untrail<CR>
 397
 398 " Source
 399 vnoremap <leader>S y:execute @@<cr>:echo 'Sourced selection.'<cr>
 400 nnoremap <leader>S ^vg_y:execute @@<cr>:echo 'Sourced line.'<cr>
 401
 402 " jump to last cursor position
 403 noremap ' `
 404
 405 " Select (charwise) the contents of the current line, excluding indentation.
 406 nnoremap vv ^vg_
 407
 408 " Unfuck my screen
 409 nnoremap U :syntax sync fromstart<cr>:AirlineRefresh<cr>:redraw!<cr>
 410
 411 " Ranger
 412 " nnoremap <leader>r :silent !ranger %:h<cr>:redraw!<cr>
 413 " nnoremap <leader>R :silent !ranger<cr>:redraw!<cr>
 414
 415 " Use sane regexes.
 416 nnoremap / /\v
 417 vnoremap / /\v
 418 cnoremap s/ s/\v
 419
 420 " display the number of matches for the last search
 421 nmap <Leader># :%s:<C-R>/::gn<CR>
 422
 423 " center cursor after search and open folds
 424 nnoremap n nzzzv
 425 nnoremap N Nzzzv
 426
 427 " same when jumping around
 428 nnoremap g; g;zzzv
 429 nnoremap g, g,zzzv
 430 nnoremap <c-o> <c-o>zzzv
 431 nnoremap <c-i> <c-i>zzzv
 432
 433 " Not using the default mappings of 'To line from top/bottom'
 434 noremap H ^
 435 noremap L $
 436 vnoremap H ^
 437 vnoremap L g_
 438
 439 " Heresy, emacs insert bindings
 440 inoremap <C-A> <Esc>I
 441 inoremap <C-E> <Esc>A
 442 cnoremap <C-A> <Home>
 443 cnoremap <C-E> <End>
 444
 445 " proper movement when lines are wrapped
 446 noremap <silent><expr> j (v:count == 0 ? 'gj' : 'j')
 447 noremap <silent><expr> k (v:count == 0 ? 'gk' : 'k')
 448
 449 " disable arrows
 450 noremap  <Up>    <NOP>
 451 noremap  <Down>  <NOP>
 452 noremap  <Left>  <NOP>
 453 noremap  <Right> <NOP>
 454 inoremap <Up>    <NOP>
 455 inoremap <Down>  <NOP>
 456 inoremap <Left>  <NOP>
 457 inoremap <Right> <NOP>
 458 cnoremap <Up>    <NOP>
 459 cnoremap <Down>  <NOP>
 460 cnoremap <Left>  <NOP>
 461 cnoremap <Right> <NOP>
 462 cnoremap <C-K>   <Up>
 463 cnoremap <C-J>   <Down>
 464 cnoremap <C-H>   <Left>
 465 cnoremap <C-L>   <Right>
 466
 467 " close all folds open fold in cursor
 468 nnoremap zx zMzxzt
 469
 470 map <F1> :ls<CR>:b<space>
 471
 472 " move between windows (skip previewwindow)
 473 nnoremap <silent> <C-L> <C-W>w<C-W>:if &previewwindow \| wincmd w \| endif<CR>
 474 nnoremap <silent> <C-H> <C-W>W<C-W>:if &previewwindow \| wincmd W \| endif<CR>
 475 tnoremap <silent> <C-L> <C-W>w<C-W>:if &previewwindow \| wincmd w \| endif<CR>
 476 tnoremap <silent> <C-H> <C-W>W<C-W>:if &previewwindow \| wincmd W \| endif<CR>
 477
 478 "xterm mouse with middleclick paste
 479 nnoremap <MiddleMouse> i<MiddleMouse>
 480 vnoremap <MiddleMouse> s<MiddleMouse>
 481
 482 " fix legacy vi inconsistency
 483 nnoremap Y y$
 484 " copy to clipboard
 485 xnoremap Y "+y
 486
 487 " allow repeat operator on visual
 488 vnoremap . :normal .<CR>
 489
 490 " add line without changing position or leaving mode
 491 noremap <silent> <Leader>o :set paste<CR>m`o<ESC>``:set nopaste<CR>
 492 noremap <silent> <Leader>O :set paste<CR>m`O<ESC>``:set nopaste<CR>
 493
 494 " Don't use Ex mode, use Q for formatting
 495 map Q gq
 496
 497 " break undo sequence before removing word
 498 inoremap <C-W> <C-G>u<C-W>
 499
 500 nnoremap coe :set <C-R>=&expandtab ? 'noexpandtab' : 'expandtab'<CR><CR>
 501 nnoremap [oe :set expandtab<CR>
 502 nnoremap ]oe :set noexpandtab<CR>
 503
 504 for idt in range(1,8)
 505   exe 'nnoremap co'.idt.' :setlocal tabstop='.idt.' shiftwidth='.idt.' softtabstop='.idt.'<CR>'
 506 endfor
 507
 508 " toggle auto format of text
 509 nnoremap coa :set <C-R>=&formatoptions =~ "a" ? 'formatoptions-=a' : 'formatoptions+=a'<CR><CR>
 510 nnoremap [oa :set formatoptions+=a<CR>
 511 nnoremap ]oa :set formatoptions-=a<CR>
 512
 513 " space will toggle current fold in normal mode
 514 nnoremap <leader><Space> za
 515 " create folds around visual selection
 516 vnoremap <leader><Space> zf
 517
 518 " save with sudo
 519 cabbrev w!! SudoWrite
 520
 521 " uppercase previous word
 522 inoremap <C-C> <Esc>gUiwgi
 523
 524 " http://git.io/v3ZeU
 525 nmap <silent> <leader>qq :echo "hi<" . synIDattr(synID(line("."),col("."),1),"name") . '> trans<' . synIDattr(synID(line("."),col("."),0),"name") . "> lo<" . synIDattr(synIDtrans(synID(line("."),col("."),1)),"name") . ">"<CR>
 526
 527 " plugins options {{{1
 528 " airline {{{2
 529 let g:airline#extensions#whitespace#enabled = 1
 530 let g:airline#extensions#tabline#enabled = 1
 531 let g:airline_powerline_fonts = 1
 532
 533 " checkattach {{{2
 534 let g:checkattach_filebrowser = 'ranger'
 535 let g:checkattach_once = 'y'
 536
 537 " delimitmate {{{2
 538 let delimitMate_expand_cr = 2
 539 let g:delimitMate_expand_space = 1
 540
 541 " fswitch {{{2
 542 nnoremap <silent> <Leader>ff :FSHere<CR>
 543 nnoremap <silent> <Leader>fl :FSRight<CR>
 544 nnoremap <silent> <Leader>fh :FSLeft<CR>
 545 nnoremap <silent> <Leader>fj :FSBelow<CR>
 546 nnoremap <silent> <Leader>fk :FSAbove<CR>
 547 nnoremap <silent> <Leader>fL :FSSplitRight<CR>
 548 nnoremap <silent> <Leader>fH :FSSplitLeft<CR>
 549 nnoremap <silent> <Leader>fJ :FSSplitBelow<CR>
 550 nnoremap <silent> <Leader>fK :FSSplitAbove<CR>
 551
 552 " fugitive {{{2
 553 nmap <silent> <leader>dd :tab split \| Gdiff \| wincmd h<CR>
 554 " delete fugitive buffers when closed
 555 autocmd BufReadPost fugitive://* set bufhidden=delete
 556
 557 nnoremap <silent> <leader>gs :Gstatus<CR>
 558 nnoremap <silent> <leader>gd :Gdiff<CR>
 559 nnoremap <silent> <leader>gc :Gcommit -v<CR>
 560 nnoremap <silent> <leader>ga :Gwrite<cr>
 561 nnoremap <silent> <leader>gb :Gblame<cr>
 562
 563 augroup fugitive_gstatus
 564     au!
 565     autocmd BufWinEnter */.git/index resize 16
 566 augroup end
 567
 568 " Gundo {{{2
 569 nnoremap <F7> :GundoToggle<CR>
 570
 571 " indent-guides {{{2
 572 let g:indent_guides_default_mapping = 0
 573 let g:indent_guides_guide_size = 1
 574 nmap <silent> cog <Plug>IndentGuidesToggle
 575 nmap <silent> [og <Plug>IndentGuidesEnable
 576 nmap <silent> ]og <Plug>IndentGuidesDisable
 577
 578 " close-another-window {{{2
 579 nnoremap <silent> <C-W>c  <NOP>
 580 nnoremap <silent> <C-W>cc <C-W>c
 581 nnoremap <silent> <C-W>ch :CloseLeftWindow<CR>
 582 nnoremap <silent> <C-W>cl :CloseRightWindow<CR>
 583 nnoremap <silent> <C-W>cj :CloseBelowWindow<CR>
 584 nnoremap <silent> <C-W>ck :CloseAboveWindow<CR>
 585
 586 " python-mode {{{2
 587
 588 let g:pymode_rope_completion = 0
 589 let g:pymode_rope = 0
 590 let g:pymode_run = 0
 591 let g:pymode_folding = 1
 592 let g:pymode_lint_ignore = "E221,E266,E501"
 593 let g:pymode_lint_cwindow = 0           " don't open cwindow when linting
 594 let g:pymode_syntax_space_errors = 0    " don't bother me when I'm typing
 595
 596 " signature {{{2
 597 " disable '[ mappings
 598
 599 let g:SignatureMap = {
 600   \ 'GotoNextLineAlpha'  :  "",
 601   \ 'GotoPrevLineAlpha'  :  "",
 602   \ 'GotoNextSpotAlpha'  :  "",
 603   \ 'GotoPrevSpotAlpha'  :  "",
 604   \ }
 605
 606 " switch
 607 let g:switch_mapping = "<Leader>s"
 608
 609 " spellrotate
 610 nmap <silent> z] <Plug>(SpellRotateForward)
 611 nmap <silent> z[ <Plug>(SpellRotateBackward)
 612 vmap <silent> z] <Plug>(SpellRotateForwardV)
 613 vmap <silent> z[ <Plug>(SpellRotateBackwardV)
 614
 615 " synastic {{{2
 616 let g:syntastic_enable_highlighting = 0
 617 let g:syntastic_error_symbol='E'
 618 let g:syntastic_style_error_symbol='S'
 619 let g:syntastic_warning_symbol='W'
 620 let g:syntastic_style_warning_symbol='S'
 621 let g:syntastic_always_populate_loc_list=1
 622 nmap <silent> <leader>y :SyntasticCheck<cr>
 623
 624 let g:syntastic_cpp_clang_tidy_post_args = "-p build*"
 625
 626 if ! &diff
 627   let g:syntastic_check_on_open=1
 628 endif
 629
 630 " tagbar {{{2
 631 map <F5> :TagbarToggle<cr>
 632 let g:tagbar_sort = 0
 633 let g:tagbar_compact = 1
 634 let g:tagbar_autoshowtag = 1
 635 let g:tagbar_width = 25
 636 let g:tagbar_iconchars = ['+', '-']
 637
 638 " tcomments {{{2
 639 let g:tcomment_textobject_inlinecomment = 'gic'
 640 let g:tcomment#filetype#guess = 0
 641
 642 " ultisnips {{{2
 643 let g:UltiSnipsEditSplit = 'vertical'
 644 let g:UltiSnipsSnippetsDir = expand("$XDG_CONFIG_HOME/vim/ultisnips")
 645 if has('fname_case')
 646   let g:UltiSnipsSnippetDirectories = ["UltiSnips", "ultisnips"]
 647 endif
 648 let g:UltiSnipsExpandTrigger       = "<tab>"
 649 let g:UltiSnipsJumpForwardTrigger  = "<tab>"
 650 let g:UltiSnipsJumpBackwardTrigger = "<s-tab>"
 651
 652 " UltiSnips completion function that tries to expand a snippet. If there's no
 653 " snippet for expanding, it checks for completion window and if it's shown,
 654 " selects first element. If there's no completion window it tries to jump to
 655 " next placeholder. If there's no placeholder it just returns TAB key
 656 " https://github.com/Valloric/YouCompleteMe/issues/36#issuecomment-15451411
 657 function! g:UltiSnips_Complete()
 658     call UltiSnips#ExpandSnippet()
 659     if g:ulti_expand_res == 0
 660         if pumvisible()
 661             return "\<C-n>"
 662         else
 663             call UltiSnips#JumpForwards()
 664             if g:ulti_jump_forwards_res == 0
 665                return "\<TAB>"
 666             endif
 667         endif
 668     endif
 669     return ""
 670 endfunction
 671 au InsertEnter * exec "inoremap <silent> " . g:UltiSnipsExpandTrigger . " <C-R>=g:UltiSnips_Complete()<cr>"
 672 let g:UltiSnipsListSnippets="<c-e>"
 673
 674 " unite {{{2
 675 call unite#filters#matcher_default#use(['matcher_fuzzy'])
 676 call unite#custom#profile('default', 'context', {
 677             \ 'winheight': 20,
 678             \ 'direction': 'botright'
 679             \ })
 680
 681 nnoremap [unite] <Nop>
 682 nmap <leader>u [unite]
 683 nnoremap [unite]u :UniteResume<CR>
 684 nnoremap <silent> [u :UnitePrevious<CR>
 685 nnoremap <silent> ]u :UniteNext<CR>
 686
 687 " unite-grep {{{3
 688 " seems not respected
 689 let g:unite_source_grep_max_candidates = 2000
 690 if executable('ag')
 691     " Use ag in unite grep source.
 692     let g:unite_source_grep_command = 'ag'
 693     let g:unite_source_grep_default_opts = '--smart-case --vimgrep --ignore ''.hg'' --ignore ''.svn'' --ignore ''.git'' --ignore ''.bzr'''
 694     let g:unite_source_grep_recursive_opt = ''
 695 end
 696 nnoremap <silent> [unite]a :<C-u>Unite grep:.::\12\17<CR>
 697 nnoremap <silent> [unite]A :<C-u>Unite grep:.:-w:\12\17<CR>
 698 command! -nargs=1 Ag Unite grep:.::<args>
 699
 700 " unite-file_rec {{{3
 701 if executable('ag')
 702     " Use ag in unite rec source
 703     let g:unite_source_rec_async_command = ['ag', '--follow', '--nocolor', '--nogroup', '-g', '']
 704 end
 705 nnoremap <silent> [unite]f :<C-u>Unite -start-insert file_rec/async<CR>
 706 call unite#custom#source('file_rec/async', 'sorters', 'sorter_selecta')
 707
 708 " unite-buffer {{{3
 709 call unite#custom#default_action('buffer', 'open')
 710 nnoremap <silent> [unite]b :<C-u>Unite buffer:-<CR>
 711
 712 " unite-menu {{{3
 713 let g:unite_source_menu_menus = {}
 714 let g:unite_source_menu_menus.fugitive = { 'description' : 'fugitive menu'}
 715 let g:unite_source_menu_menus.fugitive.command_candidates = {
 716             \ 'Gstatus <Leader>gs' : 'Gstatus',
 717             \ 'Gcommit -v <Leader>gc' : 'Gcommit -v',
 718             \ 'Glog' : 'Glog',
 719             \}
 720
 721 nnoremap <silent> <leader>gg :<C-u>Unite menu:fugitive<CR>
 722
 723 let g:unite_source_history_yank_enable = 1
 724 nnoremap <silent> [unite]p :<C-u>Unite history/yank<CR>
 725
 726 " yankring {{{2
 727 nnoremap <silent> <leader>p :YRShow<cr>
 728 let g:yankring_history_dir = expand('$XDG_CACHE_HOME/vim')
 729 let g:yankring_replace_n_pkey = ''
 730 let g:yankring_replace_n_nkey = ''
 731
 732 " map Y to y$ for the yank ring
 733 function! YRRunAfterMaps()
 734     nnoremap Y   :<C-U>YRYankCount 'y$'<CR>
 735 endfunction
 736
 737 " youcompleteme {{{2
 738 let g:ycm_extra_conf_globlist = ['~/src/*','/mnt/data/src/*']
 739 " ycm-clangd requires you to symlink the compile_db to the root of the project
 740 " let g:ycm_global_ycm_extra_conf = expand('$XDG_CONFIG_HOME/vim/ycm_extra_conf.py')
 741 let g:ycm_clangd_binary_path = 'clangd'   " use clangd in path
 742 let g:ycm_extra_conf_vim_data = ['getcwd()']
 743 let g:ycm_add_preview_to_completeopt = 1
 744 let g:ycm_complete_in_comments = 1
 745 let g:ycm_complete_in_strings  = 1
 746 let g:ycm_autoclose_preview_window_after_insertion = 0
 747
 748 " vim-easy-align {{{2
 749 " start interactive EasyAlign in visual mode
 750 vmap <Enter> <Plug>(EasyAlign)
 751 nmap ga <Plug>(EasyAlign)
 752
 753 " vim-gtest {{{2
 754 let g:gtest#highlight_failing_tests = 0
 755
 756 nnoremap <Leader>tt :GTestRun<CR>
 757 nnoremap <Leader>ta :GTestCase *<CR>:GTestName *<CR>:GTestRun<CR>
 758 nnoremap <Leader>tu :GTestRunUnderCursor<CR>
 759
 760 " vim-json {{{2
 761 let g:vim_json_syntax_conceal = 0
 762
 763 " vim-sneak {{{2
 764 let g:sneak#streak = 1
 765 let g:sneak#target_labels = "aoeuisnthdpylrcgfqjkxzmwvz" " dvorak
 766 let g:sneak#use_ic_scs = 1  " follow 'ignorecase' and 'smartcase'
 767
 768 " sneaky f and t
 769 nmap f <Plug>Sneak_f
 770 nmap F <Plug>Sneak_F
 771 xmap f <Plug>Sneak_f
 772 xmap F <Plug>Sneak_F
 773 omap f <Plug>Sneak_f
 774 omap F <Plug>Sneak_F
 775 nmap t <Plug>Sneak_t
 776 nmap T <Plug>Sneak_T
 777 xmap t <Plug>Sneak_t
 778 xmap T <Plug>Sneak_T
 779 omap t <Plug>Sneak_t
 780 omap T <Plug>Sneak_T
 781
 782 " vimviki {{{2
 783 let g:vimwiki_list = [{'path': '$XDG_DATA_HOME/vimwiki'}]
 784 let g:vimwiki_auto_chdir = 1
 785 augroup myvimwiki
 786   au! BufRead            $XDG_DATA_HOME/vimwiki/index.wiki   !git -C "%:p:h" pull -q
 787   au! BufRead,BufNewFile $XDG_DATA_HOME/vimwiki/diary/*.wiki !git -C "%:p:h" pull -q
 788   au! BufWritePost       $XDG_DATA_HOME/vimwiki/*.wiki       exe '!git add "<afile>";git commit -qm"' . strftime("%FT%R") . '";git push -q'
 789 augroup END
 790
 791 " functions {{{1
 792
 793 " Convenient command to see the difference between the current buffer and the
 794 " file it was loaded from, thus the changes you made.
 795 " Only define it when not defined already.
 796 if !exists(":DiffOrig")
 797   command DiffOrig vert new | set bt=nofile | r # | 0d_ | diffthis
 798                   \ | wincmd p | diffthis
 799 endif
 800
 801 " sort operator {{{2
 802 function! SortLinesOpFunc(...)
 803   '[,']sort
 804 endfunction
 805 nnoremap <silent> gs :<C-U>set operatorfunc=SortLinesOpFunc<CR>g@
 806 vnoremap <silent> gs :sort<cr>
 807
 808 " edit configs  {{{2
 809 function! EditConfig(what, ext = '.vim')
 810     let l:dir = split(&runtimepath,',')[0]
 811     if a:what == 'vimrc'
 812         let l:file = expand($MYVIMRC)
 813     elseif ! isdirectory(globpath(l:dir, a:what))
 814         echoe a:what." is not valid!"
 815     elseif empty(&filetype)
 816         echoe 'filetype is empty!'
 817     else
 818         let l:file = l:dir.'/'.a:what.'/'.&filetype.a:ext
 819     endif
 820
 821     execute ':vsplit '.file
 822     execute ':lcd %:p:h'
 823 endf
 824 nmap <leader>ev :call EditConfig('vimrc')<CR>
 825 nmap <leader>ef :call EditConfig('ftplugin')<CR>
 826 nmap <leader>es :call EditConfig('syntax')<CR>
 827 nmap <leader>ei :call EditConfig('indent')<CR>
 828 nmap <leader>eu :call EditConfig('ultisnips', '.snippets')<CR>
 829
 830 " spell check {{{2
 831 " http://tex.stackexchange.com/a/52932
 832 let g:myLangList=["en_gb","en_us","de","fr"]
 833
 834 function! ToggleSpell()
 835   if !exists("b:myLang")
 836     let b:myLang=0
 837   endif
 838   execute "setlocal spell!"
 839   if (&spell)
 840     echo "setlocal spelllang=" g:myLangList[b:myLang]
 841   endif
 842 endfunction
 843
 844 function! SwitchSpell()
 845   if !exists("b:myLang")
 846     let b:myLang=0
 847   endif
 848   if (&spell)
 849     let b:myLang=b:myLang+1
 850     if b:myLang>=len(g:myLangList) | let b:myLang=0 | endif
 851   endif
 852   execute "setlocal spell spelllang=".get(g:myLangList, b:myLang)
 853   echo "setlocal spelllang=" g:myLangList[b:myLang]
 854 endfunction
 855
 856 nnoremap <silent> coS :call SwitchSpell()<CR>
 857 " fix spelling with first choice
 858 nnoremap <Leader>f 1z=
 859
 860 " gitdir or home {{{2
 861 " from derek wyatt:
 862 " http://git.io/v3GAV
 863 function! FindGitDirOrHome()
 864   let filedir = expand('%:p:h')
 865   if isdirectory(filedir)
 866     let cmd = 'bash -c "(cd ' . filedir . '; git rev-parse --show-toplevel 2>/dev/null)"'
 867     let gitdir = system(cmd)
 868     if strlen(gitdir) == 0
 869       return '~'
 870     else
 871       return gitdir[:-2]
 872     endif
 873   else
 874     return '~'
 875   endif
 876 endfunction
 877 command! Cd cd %:h
 878 command! Cdr execute('cd ' . FindGitDirOrHome())
 879 command! LCd lcd %:h
 880 command! LCdr execute('lcd ' . FindGitDirOrHome())
 881
 882 " vim:set et sw=2 ts=2 tw=78: